R_WBSElementTP_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'TP view for I WBSElementData 2'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType: {
    sizeCategory: #XL,
    dataClass:  #TRANSACTIONAL,
    serviceQuality: #C
}
define view entity R_WBSElementTP_2
  as select from I_WBSElementData_2
  association        to parent R_ProjectTP_2      as _Project                 on  $projection.ProjectInternalID = _Project.ProjectInternalID

  association [0..1] to I_WBSElementShortText     as _WBSElementShortText     on  $projection.WBSElementObject  = _WBSElementShortText.WBSElementObject
                                                                              and _WBSElementShortText.Language = $session.system_language

  association [0..1] to I_WBSElementHierarchyData as _WBSElementHierarchyData on  $projection.WBSElementInternalID = _WBSElementHierarchyData.WBSElementInternalID
  ---Extension Association
  association [1..1] to E_WBSElement_2            as _Extension               on  $projection.WBSElementInternalID = _Extension.WBSElementInternalID
  ---Self Association with Child parent of WBS.
  association [0..1] to R_WBSElementTP_2          as _ParentWBSElement        on  $projection.wbselementparentinternalid = _ParentWBSElement.WBSElementInternalID
  association [1..*] to R_WBSElementTP_2          as _SubWBSElement           on  $projection.WBSElementInternalID = _SubWBSElement.WBSElementParentInternalID
  ---Association to get the Converted value for Functional Location
association [1..1] to I_FunctionalLocationLabel  as _FunctionalLocationLabel on  $projection.FunctionalLocation = _FunctionalLocationLabel.FunctionalLocation
{
  key WBSElementInternalID,
      @ObjectModel.text.element: ['WBSDescription']
      case WBSElementExternalID
      when ''
      then cast( WBSElement as ps_posid_edit preserving type )
      else WBSElementExternalID
      end                                                             as WBSElementExternalID,
      WBSElementShortID,
      @Semantics.text: true
      WBSDescription,
      @Semantics.text: true
      _WBSElementShortText.WBSElementLangBsdDescription,
      ResponsiblePerson,
      ResponsiblePersonName,
      ApplicantCode,
      ApplicantName,
      cast( CompanyCode as bukrs preserving type )                    as CompanyCode,
      BusinessArea,
      cast( ControllingArea as ps_s4_kokrs preserving type )          as ControllingArea,
      FunctionalArea,
      ProfitCenter,
      ResponsibleCostCenter,
      Plant,
      FreeDefinedTableFieldSemantic,
      FactoryCalendar,
      PriorityCode,
      Currency,
      CostingSheet,
      CostCenter,
      RequestingCostCenter,
      ProjectInternalID,
      WBSElementIsBillingElement,
      WBSElementObject,
      InvestmentProfile,
      WBSIsStatisticalWBSElement,
      WBSIsAccountAssignmentElement,
      ProjectType,
      WBSElementIsPlanningElement,
      WorkCenterLocation,
      ResultAnalysisInternalID,
      TaxJurisdiction,
      cast( FunctionalLocation as tplnr_unconverted preserving type ) as FunctionalLocation,
      _FunctionalLocationLabel.FunctionalLocationLabelName,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      RespCostCenterControllingArea,
      WBSIsMarkedForIntegratedPlng,
      Equipment,
      ProjectObjectChangeNumber,
      WBSElementHierarchyLevel,
      OverheadCode,
      ReferenceElement,
      ProjInterestCalcProfile,
      ProgressAnlysAggregationWeight,
      ReqgCostCenterControllingArea,
      Language,
      IsMarkedForDeletion,
      WBSElementIsGroupingWBSElement,
      WBSElementIsUsedInProjSmmry,
      CostingVariant,
      BasicStartDate,
      ForecastedStartDate,
      ActualStartDate,
      BasicEndDate,
      ForecastedEndDate,
      ActualEndDate,
      TechnicalCompletionDate,
      BasicDuration,
      BasicDurationUnit,
      ForecastedDuration,
      ForecastedDurationUnit,
      ActualDuration,
      ActualDurationUnit,
      SchedldBasicEarliestStartDate,
      ScheduledBasicLatestEndDate,
      SchedldFcstdEarliestStartDate,
      LatestSchedldFcstdEndDate,
      TentativeActualStartDate,
      TentativeActualEndDate,
      JointVenture,
      JointVentureCostRecoveryCode,
      JointVentureEquityType,
      JntVntrProjectType,
      JntIntrstBillgClass,
      JntIntrstBillgSubClass,
      SubProject,
      InvestmentReason,
      InvestmentScale,
      EnvironmentalInvestmentReason,
      RequestingCompanyCode,
      NetworkAssignmentType,
      CostObject,
      BillingPlan,
      ControllingObjectClass,

      _WBSElementHierarchyData.WBSElementParentInternalID,
      _WBSElementHierarchyData.WBSElementChildInternalID,
      _WBSElementHierarchyData.LeftSiblingWBSElmntInternalID,
      _WBSElementHierarchyData.RightSiblingWBSElmntInternalID,

      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,

      FreeDefinedQuantity1,
      FreeDefinedQuantity1Unit,

      FreeDefinedQuantity2,
      FreeDefinedQuantity2Unit,

      FreeDefinedAmount1,
      FreeDefinedAmount1Currency,

      FreeDefinedAmount2,
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,
      StatusProfile,
      DistributionProfile,
      SchedldBasicEarliestEndDate,
      SchedldBasicLatestStartDate,
      SchedldFcstdEarliestEndDate,
      LatestSchedldFcstdStartDate,
      StatusCombinationCode,
      
      /* Associations */
      _Project,
      @Consumption.hidden: true
      _ResponsiblePerson,
      @Consumption.hidden: true
      _ProjectApplicant,
      _ParentWBSElement,
      _SubWBSElement,
      @Consumption.hidden: true
      _FunctionalLocationLabel
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FUNCTIONALLOCATIONLABEL",
"I_WBSELEMENTDATA_2",
"I_WBSELEMENTHIERARCHYDATA",
"I_WBSELEMENTSHORTTEXT"
],
"ASSOCIATED":
[
"I_FUNCTIONALLOCATIONLABEL",
"I_PROJECTAPPLICANT",
"I_PROJECTRESPONSIBLEPERSON",
"R_PROJECTTP_2",
"R_WBSELEMENTTP_2"
],
"BASE":
[
"I_WBSELEMENTDATA_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/