R_ProjectNetworkTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Project Network Data - TP'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
//@ObjectModel.sapObjectNodeType.name: 'ProjectNetwork'

//@ObjectModel.usageType: {

//    sizeCategory: #XL,

//    dataClass:  #TRANSACTIONAL,

//    serviceQuality: #C

//}

@ObjectModel: {
  representativeKey: 'ProjectNetwork',
  semanticKey:  [ 'ProjectNetwork' ],
  sapObjectNodeType.name: 'ProjectNetwork',
  usageType: {
    sizeCategory: #XL,
    dataClass:  #TRANSACTIONAL,
    serviceQuality: #C
}

}

define root view entity R_ProjectNetworkTP
  as select from I_ProjectNetworkBasicData
  association [1..1] to E_LogisticsOrder           as _Extension on $projection.ProjectNetwork = _Extension.OrderID
  composition [0..*] of R_ProjectNetworkActivityTP as _ProjectNetworkActivity
{
      @ObjectModel.text.element: ['ProjectNetworkDescription']
  key ProjectNetwork,
      ProjectNetworkInternalID,
      ProjectNetworkObject,
      @Semantics.text: true
      ProjectNetworkDescription,
      ProjectNetworkType,
      @EndUserText.label: 'Network Description'
      @Semantics.text: true
      _NetworkShortText.LanguageBasedShortText      as ProjNtwkLangBsdDescription,

      PlannedStartDate,
      PlannedEndDate,
      ScheduledReleaseDate,
      ScheduledBasicStartDate,
      ScheduledBasicEndDate,
      ForecastedStartDate,
      ForecastedEndDate,
      ScheduledFcstdReleaseDate,
      ScheduledForecastedStartDate,
      ScheduledForecastedEndDate,
      ActualReleasedDate,
      ActualStartDate,
      ActualEndDate,

      BasicSchedulingType,
      BasicSchedulingReductionLevel,
      ForecastSchedulingType,
      FcstSchedulingReductionLevel,
      @Semantics.booleanIndicator: true
      OrdIsNotSchedldAutomatically,
      CapacityRqmtHasNotToBeCreated,
      SchedulingIsAllowingForBreaks,

      ProjectInternalID,
      case _ProjectData.ProjectExternalID
      when ''
      then cast( _ProjectData.Project as ps_pspid_edit preserving type )
      else
      _ProjectData.ProjectExternalID
      end                                           as ProjectExternalID,
      WBSElementInternalID,
      case _WBSElementData.WBSElementExternalID
        when ''
          then cast( _WBSElementData.WBSElement as ps_posid_edit preserving type )
        else _WBSElementData.WBSElementExternalID
      end                                           as WBSElementExternalID,

      SalesOrder,
      SalesOrderItem,
      SuperiorProjectNetwork,
      SuperiorProjectNetworkIntID,
      SuperiorNtwkActivityInternalID,
      _NetworkActivityByInternalKey.NetworkActivity as SuperiorNtwkActivityExternalID,

      ControllingArea,
      CompanyCode,
      BusinessArea,
      ProfitCenter,
      FunctionalArea,
      ControllingObjectClass,
      TaxJurisdiction,
      ResponsibleCostCenter,
      Currency,
      ResponsiblePlannerGroup,
      ChangeNumber,

      JointVenture,
      JointVentureRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,
      JointVentureOriginalCostObject,

      NetworkProfile,
      Plant,
      MRPController,
      PriorityCode,
      BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      PlannedTotalQty,
      CostingSheet,

      PlannedCostsCostingVariant,
      ActualCostsCostingVariant,
      OverheadCode,

      case
        when not PlannedCostsAreNotCalculated is initial
          then '0'

        when PlannedCostsAreNotCalculated is initial
         and not OrderIsNotCostedAutomatically is initial
         and OrderCostsAreUpdated is initial
          then '1'

        when PlannedCostsAreNotCalculated is initial
         and not OrderIsNotCostedAutomatically is initial
         and not OrderCostsAreUpdated is initial
          then '3'

        when PlannedCostsAreNotCalculated is initial
         and OrderIsNotCostedAutomatically is initial
         and OrderCostsAreUpdated is initial
          then '2'

        when PlannedCostsAreNotCalculated is initial
         and OrderIsNotCostedAutomatically is initial
         and not OrderCostsAreUpdated is initial
          then '4'
        else ' '
      end                                           as PlannedCostCalculation,
      case
        when ProjNtwkIsRlvtForMatlPlng = '1'
          then '1'

        when ProjNtwkIsRlvtForMatlPlng = 'X'
          then '2'

        when ProjNtwkIsRlvtForMatlPlng = ' '
          then '3'

        when ProjNtwkIsRlvtForMatlPlng = 'B'
          then '4'
        else ' '
      end                                           as PurReqnOrResvnGeneration,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      IsMarkedForDeletion,
      NetworkIsAccountAssigned,
      ProcurementMode,

      //case

      //when PlannedTotalQty < 999

      //then cast( PlannedTotalQty as abap.dec( 3, 0 ) )

      //else

      // cast( 1 as  abap.dec( 3, 0 ) )

      //end                                           as ProjectNetworkExecutionRate,


      case
      when PlannedTotalQty <= 999
      then cast( PlannedTotalQty as afakt)
      else
       cast( 1 as afakt )
      end                                           as ProjectNetworkExecutionRate,
      StatusCombinationCode,

      /* Associations */
      _BusinessArea,
      _CompanyCode,
      _ControllingArea,
      _MRPController,
      _NetworkActivityByInternalKey,
      _OrderType,
      _Plant,
      _PriorityCode,
      _ProfitCenter,
      _ProjectData,
      _WBSElementData,
      _ProjectNetworkActivity,
      _NetworkShortText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_PROJECTDATA_2",
"I_PROJECTNETWORKBASICDATA",
"I_PROJECTOBJECTSHORTTEXT",
"I_WBSELEMENTDATA_2"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_MRPCONTROLLER",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_ORDERTYPE",
"I_PLANT",
"I_PRIORITYCODE",
"I_PROFITCENTER",
"I_PROJECTDATA_2",
"I_PROJECTOBJECTSHORTTEXT",
"I_WBSELEMENTDATA_2",
"R_PROJECTNETWORKACTIVITYTP"
],
"BASE":
[
"I_PROJECTNETWORKBASICDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/