R_ProjectNetworkActivityTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Network Activity Data – TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}
define view entity R_ProjectNetworkActivityTP
  as select from I_NetworkActivityByInternalKey
  association        to parent R_ProjectNetworkTP      as _ProjectNetwork on  $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork
  composition [0..*] of R_ProjNtwkActivityMilestoneTP  as _ProjectMilestone
  composition [0..*] of R_ProjNtwkActyMatlCompTP       as _ProjNtwkActyMatlComp
  composition [0..*] of R_ProjNtwkActyRelationshipTP   as _ProjNtwkActyRelationship
  composition [0..*] of R_ProjNetworkActivityElementTP as _NetworkActivityElement
  association [0..1] to I_WBSElementData_2             as _WBSElement     on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID

  association [1..1] to E_NetworkActivity              as _Extension      on  $projection.ProjectNetworkInternalID      = _Extension.ProjectNetworkInternalID
                                                                          and $projection.ProjNetworkActivityInternalID = _Extension.NetworkActivityInternalID
{
  key ProjectNetworkInternalID,
  key NetworkActivityInternalID                      as ProjNetworkActivityInternalID,
      _ProjectNetworkBasicData[inner].ProjectNetwork as ProjectNetwork,
      NetworkActivity,
      @Semantics.text: true
      _ActivityShortText.LanguageBasedShortText      as NtwkActyLangBsdDescription,
      @Semantics.text: true
      NetworkActivityDescription,
      NetworkActivityObject,
      WBSElementInternalID,
      case _WBSElement.WBSElementExternalID
      when ''
      then cast( _WBSElement.WBSElement as ps_posid_edit preserving type )
      else _WBSElement.WBSElementExternalID
      end                                            as WBSElementExternalID,
      WorkCenterInternalID,
      _WorkCenter.WorkCenter,
      Plant,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      _NtwkActivityDatesQuantity.PlannedWorkQuantity,
      _NtwkActivityDatesQuantity.StandardWorkQuantityUnit1,
      OperationCalculationControl,
      CostCtrActivityType,
      OperationImportance,
      UsageCode,
      NetworkActivityControlProfile,
      ActyIsTakenAcctForProjSmmry,
      CapacityRequirementDistrKey,
      NumberOfCapacities,
      OperationWorkPercent,
      _NtwkActivityDatesQuantity.MaintOrdOperationExecutionRate,
      BusinessProcess,
      StandardTextInternalID,
      @Semantics.quantity.unitOfMeasure: 'StandardDurationUnit'
      _NtwkActivityDatesQuantity.StandardDuration,
      _NtwkActivityDatesQuantity.BasicDurationUnit,
      StandardDurationIsFlexible,
      @Semantics.quantity.unitOfMeasure: 'MinimumDurationUnit'
      _NtwkActivityDatesQuantity.MinimumDuration,
      _NtwkActivityDatesQuantity.MinimumDurationUnit,
      FactoryCalendar,
      LeadTimeReductionStrategy,
      @Semantics.booleanIndicator
      ExtProcgOperationHasSubcontrg,
      PurchasingInfoRecord,
      PurchasingOrganization,
      Supplier,
      PurchasingGroup,
      OpPurchaseOutlineAgreement,
      OpPurchaseOutlineAgreementItem,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      ExternalProcessingPrice,
      NetworkActivityCurrency,
      @Semantics.quantity.unitOfMeasure: 'OperationQuantityUnit'
      NetworkActivityPriceBaseQty,
      CostElement,
      PurgInfoRecdDataIsFixed,
      _NtwkActivityDatesQuantity.PlannedDeliveryDurationInDays,
      @Semantics.quantity.unitOfMeasure: 'OperationQuantityUnit'
      _NtwkActivityDatesQuantity.OperationQuantity,
      _NtwkActivityDatesQuantity.OperationQuantityUnit,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      MaterialGroup,
      PurchasingInfoRecdAddlGrpgName,
      RequisitionerUser,
      GoodsRecipientName,
      OperationTrackingNumber,
      UnloadingPointName,
      _NtwkActivityDatesQuantity.ActyBscStartDateConstraintType,
      _NtwkActivityDatesQuantity.ConstraintDateForBscStartDate,
      _NtwkActivityDatesQuantity.ConstraintTimeForBscStartTime,
      _NtwkActivityDatesQuantity.ActyBscEndDateConstraintType,
      _NtwkActivityDatesQuantity.ConstraintDateForBscEndDate,
      _NtwkActivityDatesQuantity.ConstraintTimeForBasicEndTime,
      _NtwkActivityDatesQuantity.TotalFloatForBasicDates,
      _NtwkActivityDatesQuantity.BasicDatesFreeFloat,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestStartDate,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestStartTime,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestEndDate,
      _NtwkActivityDatesQuantity.SchedldBasicEarliestEndTime,
      _NtwkActivityDatesQuantity.SchedldBasicLatestStartDate,
      _NtwkActivityDatesQuantity.SchedldBasicLatestStartTime,
      _NtwkActivityDatesQuantity.ScheduledBasicLatestEndDate,
      _NtwkActivityDatesQuantity.SchedldBasicLatestEndTime,
      _NtwkActivityDatesQuantity.ActualStartDate,
      _NtwkActivityDatesQuantity.ActualExecutionStartTime,
      _NtwkActivityDatesQuantity.ActualEndDate,
      _NtwkActivityDatesQuantity.ActualExecutionEndTime,
      _NtwkActivityDatesQuantity.ActyConfFcstdEndDate,
      _NtwkActivityDatesQuantity.ActyConfFcstdEndTime,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      _NtwkActivityDatesQuantity.ActualWorkQuantity,
      @Semantics.quantity.unitOfMeasure: 'ActivityConfFcstdDurationUnit'
      _NtwkActivityDatesQuantity.ActivityConfFcstdDuration,
      _NtwkActivityDatesQuantity.ActivityConfFcstdDurationUnit,

      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit1'
      _NtwkActivityDatesQuantity.ForecastedWorkQty,

      _NtwkActivityDatesQuantity.ActyFcstStartDteConstraintType,
      _NtwkActivityDatesQuantity.ActyFcstEndDateConstraintType,
      _NtwkActivityDatesQuantity.ForecastedStartDate,
      _NtwkActivityDatesQuantity.ForecastedStartTime,
      _NtwkActivityDatesQuantity.ForecastedEndDate,
      _NtwkActivityDatesQuantity.ForecastedEndTime,
      _NtwkActivityDatesQuantity.TotalFloatForForecastedDates,
      _NtwkActivityDatesQuantity.ForecastedDatesFreeFloat,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestStartDate,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestStartTime,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestEndDate,
      _NtwkActivityDatesQuantity.SchedldFcstdEarliestEndTime,
      _NtwkActivityDatesQuantity.LatestSchedldFcstdStartDate,
      _NtwkActivityDatesQuantity.SchedldFcstdLatestStartTime,
      _NtwkActivityDatesQuantity.LatestSchedldFcstdEndDate,
      _NtwkActivityDatesQuantity.SchedldFcstdLatestEndTime,
      @Semantics.quantity.unitOfMeasure: 'FcstdStandardDurationUnit'
      _NtwkActivityDatesQuantity.ForecastedStandardDuration,
      _NtwkActivityDatesQuantity.FcstdStandardDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'ForecastedMinimumDurationUnit'
      _NtwkActivityDatesQuantity.ForecastedMinimumDuration,
      _NtwkActivityDatesQuantity.ForecastedMinimumDurationUnit,
      CompanyCode,
      BusinessArea,
      NetworkActivityObjectCurrency,
      TaxJurisdictionCalcProcedure,
      ProfitCenter,
      OverheadCode,
      ChangeNumber,
      TaxJurisdiction,
      FunctionalArea,
      ControllingObjectClass,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      _NetworkActivityUserFields.FreeDefinedTableFieldSemantic,
      _NetworkActivityUserFields.FreeDefinedAttribute01,
      _NetworkActivityUserFields.FreeDefinedAttribute02,
      _NetworkActivityUserFields.FreeDefinedAttribute03,
      _NetworkActivityUserFields.FreeDefinedAttribute04,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      _NetworkActivityUserFields.FreeDefinedQuantity1,
      _NetworkActivityUserFields.FreeDefinedQuantity1Unit,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      _NetworkActivityUserFields.FreeDefinedQuantity2,
      _NetworkActivityUserFields.FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      _NetworkActivityUserFields.FreeDefinedAmount1,
      _NetworkActivityUserFields.FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      _NetworkActivityUserFields.FreeDefinedAmount2,
      _NetworkActivityUserFields.FreeDefinedAmount2Currency,
      _NetworkActivityUserFields.FreeDefinedDate1,
      _NetworkActivityUserFields.FreeDefinedDate2,
      _NetworkActivityUserFields.FreeDefinedIndicator1,
      _NetworkActivityUserFields.FreeDefinedIndicator2,
      ProgressAnlysAggregationWeight,
      @Semantics.amount.currencyCode: 'NetworkActivityCurrency'
      NetworkActivityCost,
      PartnerCostCenter,
      Language,
      NtwkAccountAssignmentCode,
      IsMarkedForDeletion,

      cast (case
        when ProjNtwkIsRlvtForMatlPlng = ' ' then '3'
        when ProjNtwkIsRlvtForMatlPlng = 'X' then '2'
        when ProjNtwkIsRlvtForMatlPlng = '1' then '1'
        when ProjNtwkIsRlvtForMatlPlng = 'B' then '4'
      end as abap.char( 1 ) )                        as PurReqnOrResvnGeneration,

      _NetworkActivityUserFields.JointVenture,
      _NetworkActivityUserFields.JointVentureRecoveryCode,
      _NetworkActivityUserFields.JointVentureEquityType,
      _NetworkActivityUserFields.JointVentureObjectType,
      _NetworkActivityUserFields.JointVentureClass,
      _NetworkActivityUserFields.JointVentureSubClass,
      _NetworkActivityUserFields.JntVentureOriglCostObjectType,
      _NtwkActivityDatesQuantity.StandardWorkQuantityUnit,
      _NtwkActivityDatesQuantity.StandardDurationUnit,

      @Semantics.amount.currencyCode: 'ControllingAreaCurrency'
      MatPlanningPrimaryCost,
      ReferencePoint,
      ReferenceElement,
      _ControllingArea.ControllingAreaCurrency       as ControllingAreaCurrency,
      StatusCombinationCode,
      // Associations

      _ProjectNetwork,
      _ProjectNetworkBasicData,
      _WBSElement,
      _WorkCenter,
      _OperationControlProfileText,
      _FactoryCalendarText,
      _ProjectMilestone,
      _NetworkActivityWorkCenter,
      _NtwkActivityDatesQuantity,
      _NetworkActivityUserFields,
      //Multi Language Short text

      _ProjNtwkActyMatlComp,
      _NetworkActivityElement,
      _ProjNtwkActyRelationship
}
where
  SuperiorNtwkActivityInternalID is initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONTROLLINGAREA",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_NETWORKACTIVITYDATESQUANTITY",
"I_NETWORKACTIVITYUSERFIELDS",
"I_PROJECTNETWORKBASICDATA",
"I_PROJECTOBJECTSHORTTEXT",
"I_WBSELEMENTDATA_2",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_FACTORYCALENDARTEXT",
"I_MAINTENANCEWORKCENTERORGUNIT",
"I_NETWORKACTIVITYDATESQUANTITY",
"I_NETWORKACTIVITYUSERFIELDS",
"I_OPERATIONCONTROLPROFILETEXT",
"I_PROJECTNETWORKBASICDATA",
"I_WBSELEMENTDATA_2",
"I_WORKCENTER",
"R_PROJECTNETWORKTP",
"R_PROJNETWORKACTIVITYELEMENTTP",
"R_PROJNTWKACTIVITYMILESTONETP",
"R_PROJNTWKACTYMATLCOMPTP",
"R_PROJNTWKACTYRELATIONSHIPTP"
],
"BASE":
[
"I_NETWORKACTIVITYBYINTERNALKEY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/