R_SourcingProjectItem

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog: { sqlViewName: 'RSRCGPROJITM',
                compiler.compareFilter: true,
                preserveKey: true
}

@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel:{
               representativeKey: 'SourcingProjectItemUUID',
               semanticKey: ['SourcingProjectItem'],

               usageType: {
                 dataClass: #TRANSACTIONAL,
//               Service Quality A/B needed

                 serviceQuality: #A,
                 sizeCategory: #M
              }
}

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Item in Sourcing Project'
define view R_SourcingProjectItem
  as select from mmsrcgpitem

  association [1..1] to R_SourcingProject            as _SourcingProject            on  $projection.SourcingProjectUUID = _SourcingProject.SourcingProjectUUID

  //foreign key associations

  association [0..1] to I_Currency                   as _ItemDocumentCurrency       on  $projection.DocumentCurrency = _ItemDocumentCurrency.Currency
  association [0..1] to I_UnitOfMeasure              as _RequestedQuantityUnit      on  $projection.RequestedQuantityUnit = _RequestedQuantityUnit.UnitOfMeasure
  association [0..1] to I_SourcingProjectItemType    as _SourcingProjectItemType    on  $projection.SourcingProjectItemType = _SourcingProjectItemType.SourcingProjectItemType
  association [0..1] to I_SrcgProjItemClassification as _SrcgProjItemClassification on  $projection.SourcingProjectItemType    = _SrcgProjItemClassification.SourcingProjectItemType
                                                                                    and $projection.SrcgProjItemClassification = _SrcgProjItemClassification.SrcgProjItemClassification
  association [0..1] to R_SourcingProjectItem        as _SourceSourcingProjectItem  on  $projection.SourceSourcingProjectItemUUID = _SourceSourcingProjectItem.SourcingProjectItemUUID

  association [0..1] to I_SrcgProjItemDemandConfCode as _SrcgProjItemDemandConfCode on  $projection.SrcgProjItemDemandConfCode = _SrcgProjItemDemandConfCode.SrcgProjItemDemandConfCode
  association [0..1] to I_ProductSourcingReason      as _SourcingProjectReason      on  $projection.SrcgProjItemUnconfdDemandRsn = _SourcingProjectReason.ProductSourcingReason
  association [0..1] to I_SourcingProjectType        as _SourcingProjectType        on  $projection.sourcingprojecttype = _SourcingProjectType.SourcingProjectType

  //Extension

  association [1..1] to E_SourcingProjectItem        as _Extension                  on  $projection.SourcingProjectItemUUID = _Extension.SourcingProjectItemUUID


{
  key sourcingprojectitemuuid           as SourcingProjectItemUUID,
      sourcingprojectitem               as SourcingProjectItem,
      sourcingprojectuuid               as SourcingProjectUUID,

      sourcingprojectitemtype           as SourcingProjectItemType,

      srcgprojitemclassification        as SrcgProjItemClassification,

      sourcingprojectitemstableuuid     as SourcingProjectItemStableUUID,

      srcgprojitemdescription           as SrcgProjItemDescription,

      material                          as Material,
      producttype                       as ProductType,
      materialgroup                     as MaterialGroup,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      srcgprojitemtargetamount          as SrcgProjItemTargetAmount,
      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      srcgprojitmtgtamtquantity         as SrcgProjItmTgtAmtQuantity,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      srcgprojitemtotaltargetamount     as SrcgProjItemTotalTargetAmount,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      //      @Semantics.quantity.unitOfMeasureIsoCode: 'RequestedQuantityISOUnit'

      //      @Semantics.quantity.unitOfMeasureSapCode: 'RequestedQuantitySAPUnit'

      requestedquantity                 as RequestedQuantity,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      //      @Semantics.quantity.unitOfMeasureIsoCode: 'RequestedQuantityISOUnit'

      //      @Semantics.quantity.unitOfMeasureSapCode: 'RequestedQuantitySAPUnit'

      maximumrequestedquantity          as MaximumRequestedQuantity,

      //      @Semantics.unitOfMeasure: true

      @ObjectModel: { foreignKey.association: '_RequestedQuantityUnit' }
      requestedquantityunit             as RequestedQuantityUnit,
      //      _RequestedQuantityUnit.UnitOfMeasureISOCode as RequestedQuantityISOUnit,

      //      _RequestedQuantityUnit.UnitOfMeasureSAPCode as RequestedQuantitySAPUnit,

      requesteddeliverydate             as RequestedDeliveryDate,
      performanceperiodstartdate        as PerformancePeriodStartDate,
      performanceperiodenddate          as PerformancePeriodEndDate,

      orderitemqtytobaseqtynmrtr        as OrderItemQtyToBaseQtyNmrtr,
      orderitemqtytobaseqtydnmntr       as OrderItemQtyToBaseQtyDnmntr,

      plant                             as Plant,
      companycode                       as CompanyCode,
      purchasinggroup                   as PurchasingGroup,
      purchasingorganization            as PurchasingOrganization,
      procurementhubsourcesystem        as ProcurementHubSourceSystem,
      storagelocation                   as StorageLocation,
      procmthubplantuniqueid            as ProcmtHubPlantUniqueID,

      //hierarchyparentnode      as HierarchyParentNode,

      sourcingprojectitemparent         as SourcingProjectItemParent,
      hierarchynodelevel                as HierarchyNodeLevel,
      alternativeitemid                 as AlternativeItemID,
      formatteditemid                   as FormattedItemID,
      hierarchynodesubtreesize          as HierarchyNodeSubTreeSize,

      purchaserequisition               as PurchaseRequisition,
      purchaserequisitionitem           as PurchaseRequisitionItem,

      srcgprojfollowondocumentcat       as SrcgProjFollowOnDocumentCat,
      srcgprojfollowondocumenttype      as SrcgProjFollowOnDocumentType,

      centralpurchasecontract           as CentralPurchaseContract,
      centralpurchasecontractitem       as CentralPurchaseContractItem,

      sourcesourcingprojectitemuuid     as SourceSourcingProjectItemUUID,
      //      @Semantics.currencyCode: true

      @ObjectModel.foreignKey.association: '_ItemDocumentCurrency'
      _SourcingProject.DocumentCurrency as DocumentCurrency,
      @ObjectModel.foreignKey.association: '_SourcingProjectType'
      _SourcingProject.SourcingProjectType,

      srcgprojitemdemandconfcode        as SrcgProjItemDemandConfCode,
      srcgprojitemunconfddemandrsn      as SrcgProjItemUnconfdDemandRsn,

      procmtplanningbundleitemuuid      as ProcmtPlanningBundleItemUUID,
      sourcingorigin                    as SourcingOrigin,
      sourcingscenario                  as SourcingScenario,
      srcgprojectitemsettledstatus      as SrcgProjectItemSettledStatus,
      srcgprojattchsareforbidden        as SrcgProjAttchsAreForbidden,
      requesteddeliverydateischanged    as RequestedDeliveryDateIsChanged,
      suplrcostbreakdowntemplateuuid    as SuplrCostBreakdownTemplateUUID,
      suppliercostbreakdownisenabled    as SupplierCostBreakdownIsEnabled,
      costbrkdwnattchcrtnisrequired     as CostBrkdwnAttchCrtnIsRequired,

      srcgprojitmtargetamountisfixed    as SrcgProjItmTargetAmountIsFixed,
      srcgprojitmtgtamtqtyisfixed       as SrcgProjItmTgtAmtQtyIsFixed,

      /* Associations */
      _SourcingProject,
      //foreign key associations

      _RequestedQuantityUnit,
      _SourcingProjectItemType,
      _SrcgProjItemClassification,
      _SrcgProjItemDemandConfCode,
      _SourcingProjectReason,
      _SourceSourcingProjectItem,
      _ItemDocumentCurrency,
      _SourcingProjectType
      //      _Extension



}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_SOURCINGPROJECT",
"MMSRCGPITEM"
],
"ASSOCIATED":
[
"E_SOURCINGPROJECTITEM",
"I_CURRENCY",
"I_PRODUCTSOURCINGREASON",
"I_SOURCINGPROJECTITEMTYPE",
"I_SOURCINGPROJECTTYPE",
"I_SRCGPROJITEMCLASSIFICATION",
"I_SRCGPROJITEMDEMANDCONFCODE",
"I_UNITOFMEASURE",
"R_SOURCINGPROJECT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/