C_SrcgProjectItemProcessFlow

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
                usageType.dataClass: #MIXED,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #L
              }

@EndUserText.label: 'Sourcing Project Item Process Flow'
define view entity C_SrcgProjectItemProcessFlow
  as select from R_SourcingProjectItem
{
      //Sourcing Project Item

  key _SourcingProject.SourcingProject                                                                                                           as SrcgProjItemProcFlowDocument,
  key FormattedItemID                                                                                                                            as SrcgProjItemProcessFlowItem,
  key 'S'                                                                                                                                        as SrcgProjItemProcFlowDocCat,
  key cast(_SourcingProject.SourcingProjectVersion as vdm_srcgprojitmprocflowdocvers)                                                            as SrcgProjItmProcFlowDocVersion,
  key cast('' as mmpur_extreferencesystemid)                                                                                                     as PurgDocExternalSystem,

      SourcingProjectItemUUID,
      SourcingProjectUUID,

      SourcingProjectItem                                                                                                                        as SourcingProjectQuotationItem,
      hextobin( '                                ' )                                                                                             as SrcgProjQtnItemUUID,
      hextobin( '                                ' )                                                                                             as SourcingProjectQuotationUUID,

      cast(' ' as is_cloud_system )                                                                                                              as IsCloudSystem,
      ''                                                                                                                                         as PurchasingDocumentSubtype,

      //DCL Stuff

      PurchasingGroup,
      PurchasingOrganization,
      CompanyCode,
      _SourcingProject.SourcingProjectType                                                                                                       as SourcingProjectType,
      MaterialGroup,

      //Status

      _SourcingProject.SrcgProjLifecycleStatus                                                                                                   as PurchasingDocumentStatus,
      _SourcingProject._SrcgProjLifecycleStatus._SrcgProjLifecycleStatusText[1:Language = $session.system_language ].SrcgProjLifecycleStatusName as PurchasingDocumentStatusName,
      _SourcingProject
}
where
      _SourcingProject.SourcingProject        is not initial
  and FormattedItemID                         is not initial
  and _SourcingProject.SourcingProjectVersion is not initial

union all select from R_SourcingProjectItem as SourcingProjectItem
  inner join          R_SrcgProjQtnItem     as SrcgProjQtnItem on SourcingProjectItem.SourcingProjectItemUUID = SrcgProjQtnItem.SourcingProjectItemUUID
{

  key SrcgProjQtnItem.SourcingProjectQuotation                                                                                                        as SrcgProjItemProcFlowDocument,
  key SrcgProjQtnItem.FormattedItemID                                                                                                                 as SrcgProjItemProcessFlowItem,
  key 'Q'                                                                                                                                             as SrcgProjItemProcFlowDocCat,
  key cast(SrcgProjQtnItem.SrcgProjQuotationVersion as vdm_srcgprojitmprocflowdocvers)                                                                as SrcgProjItmProcFlowDocVersion,
  key cast('' as mmpur_extreferencesystemid)                                                                                                          as PurgDocExternalSystem,

      //Sourcing Project

      SourcingProjectItem.SourcingProjectItemUUID,
      SourcingProjectItem.SourcingProjectUUID,

      SrcgProjQtnItem.SourcingProjectQuotationItem                                                                                                    as SourcingProjectQuotationItem,
      SrcgProjQtnItem.SrcgProjQtnItemUUID                                                                                                             as SrcgProjQtnItemUUID,
      SrcgProjQtnItem.SourcingProjectQuotationUUID                                                                                                    as SourcingProjectQuotationUUID,

      cast(' ' as is_cloud_system )                                                                                                                   as IsCloudSystem,
      ''                                                                                                                                              as PurchasingDocumentSubtype,

      //DCL Stuff

      SrcgProjQtnItem.PurchasingGroup,
      SrcgProjQtnItem.PurchasingOrganization,
      SrcgProjQtnItem.CompanyCode,
      SrcgProjQtnItem._SourcingProject.SourcingProjectType                                                                                            as SourcingProjectType,
      SrcgProjQtnItem.MaterialGroup,

      //Status

      SrcgProjQtnItem._SourcingProjectQuotation.SrcgProjQtnLifecycleStatus                                                                            as PurchasingDocumentStatus,
      SrcgProjQtnItem._SourcingProjectQuotation._SrcgProjQtnLifecycleSts._Text[1:Language = $session.system_language ].SrcgProjQtnLifecycleStatusName as PurchasingDocumentStatusName,
      SourcingProjectItem._SourcingProject
}
where
      SrcgProjQtnItem.SourcingProjectQuotation is not initial
  and SrcgProjQtnItem.FormattedItemID          is not initial
  and SrcgProjQtnItem.SrcgProjQuotationVersion is not initial

union all select from R_SourcingProjectItem       as SourcingProjectItem
  inner join          R_SrcgProjQtnItem           as SrcgProjQtnItem             on SourcingProjectItem.SourcingProjectItemUUID = SrcgProjQtnItem.SourcingProjectItemUUID
  inner join          R_CntrlPurContrDistribution as CntrlPurContrDistributionTP on  CntrlPurContrDistributionTP.ProcmtHubPrdcssrDocUUID     = SrcgProjQtnItem.SourcingProjectQuotationUUID
                                                                                 and CntrlPurContrDistributionTP.ProcmtHubPrdcssrDocItemUUID = SrcgProjQtnItem.SrcgProjQtnItemUUID
                                                                                 and CntrlPurContrDistributionTP.IsDeleted                   is initial
  inner join          t161                        as PurchasingDocumentType      on  SourcingProjectItem.SrcgProjFollowOnDocumentCat  = PurchasingDocumentType.bstyp
                                                                                 and SourcingProjectItem.SrcgProjFollowOnDocumentType = PurchasingDocumentType.bsart
{

  key CntrlPurContrDistributionTP.CentralPurchaseContract                                                                                      as SrcgProjItemProcFlowDocument,
  key cast(CntrlPurContrDistributionTP.CentralPurchaseContractItem as vdm_srcgprojitmprocflowitem)                                             as SrcgProjItemProcessFlowItem,
  key 'K'                                                                                                                                      as SrcgProjItemProcFlowDocCat,
  key cast('0'  as vdm_srcgprojitmprocflowdocvers)                                                                                             as SrcgProjItmProcFlowDocVersion,
  key cast('' as mmpur_extreferencesystemid)                                                                                                   as PurgDocExternalSystem,

      //Sourcing Project

      SrcgProjQtnItem.SourcingProjectItemUUID,
      SourcingProjectItem.SourcingProjectUUID,

      SrcgProjQtnItem.SourcingProjectQuotationItem                                                                                             as SourcingProjectQuotationItem,
      SrcgProjQtnItem.SrcgProjQtnItemUUID                                                                                                      as SrcgProjQtnItemUUID,
      SrcgProjQtnItem.SourcingProjectQuotationUUID                                                                                             as SourcingProjectQuotationUUID,

      cast(' ' as is_cloud_system )                                                                                                            as IsCloudSystem,
      PurchasingDocumentType.bsakz                                                                                                             as PurchasingDocumentSubtype,

      //DCL Stuff

      SrcgProjQtnItem.PurchasingGroup,
      SrcgProjQtnItem.PurchasingOrganization,
      SrcgProjQtnItem.CompanyCode,
      SrcgProjQtnItem._SourcingProject.SourcingProjectType                                                                                     as SourcingProjectType,
      SrcgProjQtnItem.MaterialGroup,

      //Status

      CntrlPurContrDistributionTP._CentralPurchaseContract.PurchasingProcessingStatus                                                          as PurchasingDocumentStatus,
      CntrlPurContrDistributionTP._CentralPurchaseContract._CntrlPurContrStatusText[1:Language = $session.system_language ].DocumentStatusName as PurchasingDocumentStatusName,
      SourcingProjectItem._SourcingProject
}
where
      CntrlPurContrDistributionTP.CentralPurchaseContract     is not initial
  and CntrlPurContrDistributionTP.CentralPurchaseContractItem is not initial
union all select from R_SourcingProjectItem   as SourcingProjectItem
  inner join          R_SrcgProjQtnItem       as SrcgProjQtnItem       on SourcingProjectItem.SourcingProjectItemUUID = SrcgProjQtnItem.SourcingProjectItemUUID

  inner join          R_SPQtnItemDocumentLink as SPQtnItemDocumentLink on  SrcgProjQtnItem.SourcingProjectQuotation     = SPQtnItemDocumentLink.SourcingProjectQuotation
                                                                       and SrcgProjQtnItem.SrcgProjQuotationVersion     = SPQtnItemDocumentLink.SrcgProjQuotationVersion
                                                                       and SrcgProjQtnItem.SourcingProjectQuotationItem = SPQtnItemDocumentLink.SourcingProjectQuotationItem
{
  key SPQtnItemDocumentLink.PurchaseOrder                                          as SrcgProjItemProcFlowDocument,
  key cast(SPQtnItemDocumentLink.PurchaseOrderItem as vdm_srcgprojitmprocflowitem) as SrcgProjItemProcessFlowItem,
  key 'F'                                                                          as SrcgProjItemProcFlowDocCat,
  key cast('0'  as vdm_srcgprojitmprocflowdocvers)                                 as SrcgProjItmProcFlowDocVersion,
  key SPQtnItemDocumentLink.PurgDocExternalSystem,

      //Sourcing Project

      SourcingProjectItem.SourcingProjectItemUUID,
      SourcingProjectItem.SourcingProjectUUID,

      SrcgProjQtnItem.SourcingProjectQuotationItem                                 as SourcingProjectQuotationItem,
      SrcgProjQtnItem.SrcgProjQtnItemUUID                                          as SrcgProjQtnItemUUID,
      SrcgProjQtnItem.SourcingProjectQuotationUUID                                 as SourcingProjectQuotationUUID,

      cast(' ' as is_cloud_system )                                                as IsCloudSystem,
      ''                                                                           as PurchasingDocumentSubtype,

      //DCL Stuff

      SrcgProjQtnItem.PurchasingGroup,
      SrcgProjQtnItem.PurchasingOrganization,
      SrcgProjQtnItem.CompanyCode,
      SrcgProjQtnItem._SourcingProject.SourcingProjectType                         as SourcingProjectType,
      SrcgProjQtnItem.MaterialGroup,

      //No Status information available...

      ''                                                                           as PurchasingDocumentStatus,
      ''                                                                           as PurchasingDocumentStatusName,
      SourcingProjectItem._SourcingProject
}
where
      SPQtnItemDocumentLink.PurchaseOrder     is not initial
  and SPQtnItemDocumentLink.PurchaseOrderItem is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNTRLPURCONTRDOCSTSTEXT",
"I_SRCGPROJLIFECYCLESTATUS",
"I_SRCGPROJLIFECYCLESTATUSTEXT",
"I_SRCGPROJQTNLIFECYCLESTS",
"I_SRCGPROJQTNLIFECYCLESTSTEXT",
"R_CENTRALPURCHASECONTRACT",
"R_CNTRLPURCONTRDISTRIBUTION",
"R_SOURCINGPROJECT",
"R_SOURCINGPROJECTITEM",
"R_SOURCINGPROJECTQUOTATION",
"R_SPQTNITEMDOCUMENTLINK",
"R_SRCGPROJQTNITEM",
"T161"
],
"ASSOCIATED":
[
"R_SOURCINGPROJECT"
],
"BASE":
[
"R_SOURCINGPROJECTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/