I_SourcingProjectItem

@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel:{ representativeKey: 'SourcingProjectItemUUID',
               semanticKey: ['SourcingProjectItem'],
               usageType.dataClass: #TRANSACTIONAL,
               usageType.serviceQuality: #A,
               usageType.sizeCategory: #M }

@VDM.viewType: #BASIC

@EndUserText.label: 'Item in Sourcing Project'

define view entity I_SourcingProjectItem
  as select from R_SourcingProjectItem

  association [1..1] to I_SourcingProject            as _SourcingProject            on  $projection.SourcingProjectUUID = _SourcingProject.SourcingProjectUUID

  association [1..*] to I_SrcgProjItmDemandDistr     as _SrcgProjDemandDistribution on  $projection.SourcingProjectItemUUID = _SrcgProjDemandDistribution.SourcingProjectItemUUID

  //foreign key associations

  association [1..1] to I_Material                   as _Material                   on  $projection.Material = _Material.Material
  association [1..1] to I_MaterialGroup              as _MaterialGroup              on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_ProductTypeCode            as _ProductType                on  $projection.ProductType = _ProductType.ProductTypeCode
  association [0..1] to I_SourcingProjectItemType    as _SourcingProjectItemType    on  $projection.SourcingProjectItemType = _SourcingProjectItemType.SourcingProjectItemType
  association [0..1] to I_SrcgProjItemClassification as _SrcgProjItemClassification on  $projection.SourcingProjectItemType    = _SrcgProjItemClassification.SourcingProjectItemType
                                                                                    and $projection.SrcgProjItemClassification = _SrcgProjItemClassification.SrcgProjItemClassification
  association [0..1] to I_UnitOfMeasure              as _RequestedQuantityUnit      on  $projection.RequestedQuantityUnit = _RequestedQuantityUnit.UnitOfMeasure
  association [0..1] to I_PurchasingDocumentType     as _PurchasingDocumentType     on  $projection.SrcgProjFollowOnDocumentCat  = _PurchasingDocumentType.PurchasingDocumentCategory
                                                                                    and $projection.SrcgProjFollowOnDocumentType = _PurchasingDocumentType.PurchasingDocumentType
  association [0..1] to I_PurchasingDocumentCategory as _PurchasingDocumentCategory on  $projection.SrcgProjFollowOnDocumentCat = _PurchasingDocumentCategory.PurchasingDocumentCategory

  association [0..1] to I_SrcgProjItemDemandConfCode as _SrcgProjItemDemandConfCode on  $projection.SrcgProjItemDemandConfCode = _SrcgProjItemDemandConfCode.SrcgProjItemDemandConfCode
  association [0..1] to I_ProductSourcingReason      as _SourcingProjectReason      on  $projection.SrcgProjItemUnconfdDemandRsn = _SourcingProjectReason.ProductSourcingReason

  //Extension

  association [1..1] to E_SourcingProjectItem        as _Extension                  on  $projection.SourcingProjectItemUUID = _Extension.SourcingProjectItemUUID

{

  key SourcingProjectItemUUID           as SourcingProjectItemUUID,
      SourcingProjectItem               as SourcingProjectItem,
      SourcingProjectUUID               as SourcingProjectUUID,

      @ObjectModel: {  foreignKey.association: '_SourcingProjectItemType'}
      SourcingProjectItemType           as SourcingProjectItemType,

      @ObjectModel: {  foreignKey.association: '_SrcgProjItemClassification'}
      SrcgProjItemClassification        as SrcgProjItemClassification,

      SourcingProjectItemStableUUID     as SourcingProjectItemStableUUID,

      SrcgProjItemDescription           as SrcgProjItemDescription,

      Material                          as Material,
      @ObjectModel: { foreignKey.association: '_ProductType' }
      ProductType                       as ProductType,
      MaterialGroup                     as MaterialGroup,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      SrcgProjItemTargetAmount          as SrcgProjItemTargetAmount,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      SrcgProjItemTotalTargetAmount     as SrcgProjItemTotalTargetAmount,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      RequestedQuantity                 as RequestedQuantity,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      MaximumRequestedQuantity          as MaximumRequestedQuantity,

      //      @Semantics.unitOfMeasure: true

      @ObjectModel: { foreignKey.association: '_RequestedQuantityUnit' }
      RequestedQuantityUnit             as RequestedQuantityUnit,
      RequestedDeliveryDate             as RequestedDeliveryDate,
      PerformancePeriodStartDate        as PerformancePeriodStartDate,
      PerformancePeriodEndDate          as PerformancePeriodEndDate,

      OrderItemQtyToBaseQtyNmrtr        as OrderItemQtyToBaseQtyNmrtr,
      OrderItemQtyToBaseQtyDnmntr       as OrderItemQtyToBaseQtyDnmntr,

      Plant                             as Plant,
      CompanyCode                       as CompanyCode,
      PurchasingGroup                   as PurchasingGroup,
      PurchasingOrganization            as PurchasingOrganization,
      ProcurementHubSourceSystem        as ProcurementHubSourceSystem,
      StorageLocation                   as StorageLocation,

      //hierarchyparentnode      as HierarchyParentNode,

      SourcingProjectItemParent         as SourcingProjectItemParent,
      HierarchyNodeLevel                as HierarchyNodeLevel,
      AlternativeItemID                 as AlternativeItemID,
      FormattedItemID                   as FormattedItemID,
      HierarchyNodeSubTreeSize          as HierarchyNodeSubTreeSize,

      PurchaseRequisition               as PurchaseRequisition,
      PurchaseRequisitionItem           as PurchaseRequisitionItem,
      SourcingOrigin                    as SourcingOrigin,
      SourcingScenario                  as SourcingScenario,

      SrcgProjItemDemandConfCode        as SrcgProjItemDemandConfCode,
      SrcgProjItemUnconfdDemandRsn      as SrcgProjItemUnconfdDemandRsn,
       
      @ObjectModel: { foreignKey.association: '_PurchasingDocumentCategory' }
      SrcgProjFollowOnDocumentCat       as SrcgProjFollowOnDocumentCat,
      @ObjectModel: { foreignKey.association: '_PurchasingDocumentType' }
      SrcgProjFollowOnDocumentType      as SrcgProjFollowOnDocumentType,

      //      @Semantics.currencyCode: true

      _SourcingProject.DocumentCurrency as DocumentCurrency,

      /* Associations */
      _SourcingProject,
      _SrcgProjDemandDistribution,
      //foreign key associations

      _Material,
      _ProductType,
      _MaterialGroup,
      _SourcingProjectItemType,
      _SrcgProjItemClassification,
      _RequestedQuantityUnit,
      _PurchasingDocumentCategory,
      _PurchasingDocumentType,
      _SrcgProjItemDemandConfCode,
      _SourcingProjectReason

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SOURCINGPROJECT",
"R_SOURCINGPROJECTITEM"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PRODUCTSOURCINGREASON",
"I_PRODUCTTYPECODE",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTTYPE",
"I_SOURCINGPROJECT",
"I_SOURCINGPROJECTITEMTYPE",
"I_SRCGPROJITEMCLASSIFICATION",
"I_SRCGPROJITEMDEMANDCONFCODE",
"I_SRCGPROJITMDEMANDDISTR",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/