I_CustomerReturnProcessStep

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.representativeKey: 'RetsMgmtProcessStep'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'Returns Order Item Process Step'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck:#NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ICRITMPROCSTEP'

define view I_CustomerReturnProcessStep 
  as select from I_AdvncdReturnsMgmtProcessStep 
{
      //Key

  key RetsMgmtProcess,
  key RetsMgmtProcessItem,
  
  key RetsMgmtProcItmQtySplit,
  key RetsMgmtProcessStep, 
  
  key ReturnsDocumentType,
  key ReturnsDocument,
  key ReturnsDocumentItem,
    
      //Returns Document Status

      ReturnsDocumentStatus,
      ReturnsDocumentApprovalStatus,
    
      //Reference Document

      ReturnsReferenceDocumentType,
      ReturnsReferenceDocument,
      ReturnsReferenceDocumentItem,
      
      RetsMgmtProcStepExecStatus    
}

union
  select from I_AdvncdRetsMgmtProcExecStatus       
{
      //Key

  key RetsMgmtProcess,
  key RetsMgmtProcessItem,
  
  key RetsMgmtProcItmQtySplit,
  key RetsMgmtProcessStep, 
  
  key cast ( '' as msr_doc_type ) as ReturnsDocumentType,
  key cast ( '' as msr_doc_nr )   as ReturnsDocument,
  key cast ( '' as msr_doc_item ) as ReturnsDocumentItem,
    
      //Returns Document Status

      cast ( '' as msr_doc_status )      as ReturnsDocumentStatus,
      cast ( '' as msr_approval_status ) as ReturnsDocumentApprovalStatus,
    
      //Reference Document

      ReturnsReferenceDocumentType,
      ReturnsReferenceDocument,
      ReturnsReferenceDocumentItem,
      
      cast ( case when RetsMgmtProcStepExecStatus = '2' 
         then
          '2' -- ->'with errors'
         else
          '' -- ->'not yet created'
        end as msr_exec_step_status ) as RetsMgmtProcStepExecStatus    
} 
where RetsMgmtProcStepIsExecuted <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADVNCDRETSMGMTPROCEXECSTATUS",
"I_ADVNCDRETURNSMGMTPROCESSSTEP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/