I_VMSVehicleCharacteristic

@AbapCatalog.sqlViewName: 'IVMSVCHAR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'View for vehicle Characteristics'
@ObjectModel.usageType.serviceQuality : #C
@ObjectModel.usageType.sizeCategory : #XXL
@ObjectModel.usageType.dataClass : #TRANSACTIONAL
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
define view I_VMSVehicleCharacteristic
  as select from I_ClfnInternalIdObjectMapping as _ClfnInternalIdObjectMapping
    inner join   I_ClfnObjectClassBasic        as _ClfnObjectClassBasic on _ClfnObjectClassBasic.ClfnObjectID = _ClfnInternalIdObjectMapping.ClfnObjectInternalID
    inner join I_ClfnClassHierarchy  as _ClfnClassHierarchy on _ClfnObjectClassBasic.ClassInternalID =  _ClfnClassHierarchy.DescendantClassInternalID
    inner join   I_ClfnClass                   as _ClassHeader          on   _ClfnClassHierarchy.AncestorClassInternalID = _ClassHeader.ClassInternalID
                                                                        and _ClassHeader.ClassType                = '300'
    inner join   I_ClfnClassCharcBasic         as _ClfnClassCharcBasic  on _ClfnClassCharcBasic.ClassInternalID = _ClassHeader.ClassInternalID
    inner join   I_ClfnCharcBasic              as _ClfnCharcBasic       on _ClfnCharcBasic.CharcInternalID = _ClfnClassCharcBasic.CharcInternalID
    inner join   P_IBaseSymbol                 as _IBaseSymbol          on _IBaseSymbol.CharcInternalID = _ClfnCharcBasic.CharcInternalID
    inner join   P_IBaseValue                  as _IBaseValue           on _IBaseValue.symbol_id = _IBaseSymbol.symbol_id
    association to  P_IBaseInstance               as _IBaseInstance        on _IBaseInstance.InstalledBaseComponentRecordNo = _IBaseValue.InstalledBaseComponentRecordNo

{
  key _ClfnInternalIdObjectMapping.ClfnObjectInternalID,
  key _ClfnInternalIdObjectMapping.ClfnObjectID,
  key _IBaseInstance.InstalledBaseComponent,
  key _ClfnCharcBasic.Characteristic,
  key _IBaseSymbol.CharcValue,
  key _IBaseInstance.InstalledBaseComponentRecordNo,
  key _IBaseSymbol.CharcInternalID,
  key _ClfnCharcBasic.TimeIntervalNumber,
  key _IBaseSymbol.CharcFromNumericValue,
      _ClassHeader.Class,
      _ClassHeader.ClassType,
      _ClfnCharcBasic.Currency,
       _ClfnCharcBasic.CharcLength,
       _ClfnCharcBasic.CharcDataType,
       _ClfnCharcBasic.CharcDecimals,
      _ClfnCharcBasic.CharcValueUnit
} 
where
  (
        _ClfnCharcBasic.CharcReferenceTable      <> 'MMCOM'
    and _ClfnCharcBasic.CharcReferenceTableField <> 'VKOND'
  )
  or(
        _ClfnCharcBasic.CharcReferenceTable      <> 'SDCOM'
    and _ClfnCharcBasic.CharcReferenceTableField <> 'VKOND'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCHARCBASIC",
"I_CLFNCLASS",
"I_CLFNCLASSCHARCBASIC",
"I_CLFNCLASSHIERARCHY",
"I_CLFNINTERNALIDOBJECTMAPPING",
"I_CLFNOBJECTCLASSBASIC",
"P_IBASEINSTANCE",
"P_IBASESYMBOL",
"P_IBASEVALUE"
],
"ASSOCIATED":
[
"P_IBASEINSTANCE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/