I_ClfnClassCharcBasic

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'INGCCLS12'
@AccessControl.authorizationCheck: #NOT_ALLOWED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Clfn Class Characteristic Basic'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #BASIC
define view I_ClfnClassCharcBasic
  as select from ksml as ClassCharc

{     
  key ClassCharc.clint    as ClassInternalID,
  key ClassCharc.posnr    as CharcPositionNumber,
  key ClassCharc.adzhl    as TimeIntervalNumber,  
      cast ( ClassCharc.imerk as atinn_no_conv preserving type ) as CharcInternalID,
      cast ( ClassCharc.omerk as atinn_no_conv preserving type ) as OverwrittenCharcInternalID,
      cast ( ClassCharc.abtei as clfnorganizationalarea preserving type ) as ClfnOrganizationalArea,
      ClassCharc.klart    as ClassType,
      ClassCharc.aennr    as ChangeNumber,
      ClassCharc.datuv    as ValidityStartDate,
      ClassCharc.datub    as ValidityEndDate,
      ClassCharc.lkenz    as IsDeleted,
//      ClassCharc.dinkb  as CharcCodeLetter, 

      ClassCharc.herku    as CharcOriginText,
      ClassCharc.prop_rel as CharcIsProposalRelevant,
      ClassCharc.pprel    as CharcIsPrptnOrProdUnitRelevant,
//      ClassCharc.mkenn  as CharcStandardCodeLetter, 


      cast ( case ClassCharc.amerk 
      when '1000000000' then 'X'
      when '1200000000' then 'X'
      when '1300000000' then 'X'
      when '1400000000' then 'X'
      when '1230000000' then 'X'
      when '1240000000' then 'X'
      when '1340000000' then 'X'
      when '1234000000' then 'X'
      else ''
      end as charcisprintrelevant preserving type ) as CharcIsPrintRelevant, 
      
      cast ( case ClassCharc.amerk 
      when '2000000000' then 'X'
      when '1200000000' then 'X'
      when '2300000000' then 'X'
      when '2400000000' then 'X'
      when '1230000000' then 'X'
      when '1240000000' then 'X'
      when '2340000000' then 'X'
      when '1234000000' then 'X'
      else ''
      end as charcissearchrelevant preserving type ) as CharcIsSearchRelevant, 
      
      cast ( case ClassCharc.amerk  
      when '3000000000' then 'X'
      when '1300000000' then 'X'
      when '2300000000' then 'X'
      when '3400000000' then 'X'
      when '1230000000' then 'X'
      when '1340000000' then 'X'
      when '2340000000' then 'X'
      when '1234000000' then 'X'
      else ''
      end as charcisdisplayrelevant preserving type ) as CharcIsDisplayRelevant      
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"KSML"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/