P_IBASEVALUE

@AbapCatalog.sqlViewName: 'PIBASEVALUE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER
@VDM.private:true
@VDM.viewType: #BASIC

define view P_IBaseValue
  as select from ibinvalues
{
  key in_recno                                        as InstalledBaseComponentRecordNo,
  key in_segmcnt,
      symbol_id,
      asstyp,
    
      // Map IBASE cstic value author (assignment type) to VCH_HL_ASSIGNMENT_TYPE domain

      cast(case ataut
          // Taken from CL_VCH_HL_UTILITY=>author_to_assignment_type.      

          when ' ' then 4  // User

          when '4' then 3  // Constraint

          when '7' then 2  // Procedure

          when '8' then 1  // Defaults

          when 'R' then 11 // Engine Stable Default / (Called Transferred value in given method)

          when 'X' then 5  // External System -> External component

          when '3' then 5  // Classification -> External component

          when 'T' then 10 // Info Record (not in the ataut domain listing, but in given method)

          else 4
      end as vch_hl_assignment_type) as VarConfignValueAssignmentType,

      msehi_low                                       as CharacteristicMinimumValueUnit,
      msehi_high                                      as CharacteristicMaximumValueUnit,
      atsrt,
      atzis,
      cast ( atimb as atinn_no_conv preserving type ) as atimb,
      dec_value_from                                  as CharcFromDecimalValue,
      dec_value_to                                    as CharcToDecimalValue,
      date_from                                       as CharcFromDate,
      date_to                                         as CharcToDate,
      time_from                                       as CharcFromTime,
      time_to                                         as CharcToTime,
      currency,
      @Semantics.amount.currencyCode: 'CharacteristicCurrency'
      curr_value_from                                 as CharcFromAmount,
      @Semantics.amount.currencyCode: 'CharacteristicCurrency'
      curr_value_to                                   as CharcToAmount,
      @Semantics.currencyCode:true
      currency                                        as CharacteristicCurrency,
      _dataaging
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"IBINVALUES"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/