I_CLFNCLASS

CDS View

Classification Class

I_CLFNCLASS is a CDS View in S/4HANA. Classification Class. It contains 30 fields. 12 CDS views read from this table.

Used by 12 CDS view(s) 30 fields

CDS Views using this table (12)

ViewTypeJoinVDMDescription
C_ConfignCharacteristic view inner CONSUMPTION OBSOLETE: Configuration Characteristic
C_VarCnfCharcVH view inner CONSUMPTION Variant Confign Characteristic
C_VarCnfExclClassVH view_entity from CONSUMPTION Variant Classes and Desc
I_ClfnClassDEX view_entity from BASIC Classification Class DEX
I_ClfnClassForKeyDate view from COMPOSITE Classification Class for Key Date
I_ClfnClassSuperiorForKeyDate view from COMPOSITE Clfn Cl Superior Hierarchy for Key Date
I_ClfnClassSuperiorForKeyDate view inner COMPOSITE Clfn Cl Superior Hierarchy for Key Date
I_ClfnClassVH view from BASIC Classification Class
I_ConfignClassVH view from BASIC Configuration Class Value Help
I_ConfignOvwPgClass view from BASIC Overview - Class
I_VMSVehicleCharacteristic view inner BASIC View for vehicle Characteristics
P_StoreGroupFromClassification view from CONSUMPTION

Fields (30)

KeyField CDS FieldsUsed in Views
KEY Class AncestorClass,Class 9
KEY ClassInternalID AncestorClassInternalID,ClassInternalID 3
KEY ClassType ClassType 7
ClassBaseUnit ClassBaseUnit 2
ClassClassfctnAuthGrp ClassClassfctnAuthGrp 3
ClassGroup ClassGroup 2
ClassIsLocal ClassIsLocal 2
ClassIsUsableInBOM ClassIsUsableInBOM 2
ClassLastChangedDateTime ClassLastChangedDateTime 2
ClassMaintAuthGrp ClassMaintAuthGrp 2
ClassSearchAuthGrp ClassSearchAuthGrp 2
ClassStandardCharcTable ClassStandardCharcTable 2
ClassStandardNumber ClassStandardNumber 2
ClassStandardOrgName ClassStandardOrgName 2
ClassStandardStartDate ClassStandardStartDate 2
ClassStandardVersion ClassStandardVersion 2
ClassStandardVersionStartDate ClassStandardVersionStartDate 2
ClassStatus ClassStatus 2
ClfnOrganizationalArea ClfnOrganizationalArea 2
CreatedByUser CreatedByUser 2
CreationDate CreationDate 2
DocumentInfoRecordDocNumber DocumentInfoRecordDocNumber 2
DocumentInfoRecordDocPart DocumentInfoRecordDocPart 2
DocumentInfoRecordDocType DocumentInfoRecordDocType 2
DocumentInfoRecordDocVersion DocumentInfoRecordDocVersion 2
LastChangeDate LastChangeDate 2
LastChangedByUser LastChangedByUser 2
SameClassfctnReaction SameClassfctnReaction 1
ValidityEndDate ValidityEndDate 2
ValidityStartDate ValidityStartDate 2 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'INGCCLS1'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Classification Class'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'ClassInternalID'
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.supportedCapabilities:
  [  #CDS_MODELING_DATA_SOURCE,
     #CDS_MODELING_ASSOCIATION_TARGET,
     #SQL_DATA_SOURCE                  ]
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API     
define view I_ClfnClass
  as select from klah as Class
  
    association [0..*] to I_ClfnClassDescription          as _ClassDescription              
      on $projection.ClassInternalID = _ClassDescription.ClassInternalID 
                
    association [0..*] to I_ClfnClassKeyword              as _ClassKeyword
      on  $projection.ClassInternalID     = _ClassKeyword.ClassInternalID

    association [0..1] to I_ClfnClassStatus               as _ClassStatus                  
      on  $projection.ClassStatus    = _ClassStatus.ClassStatus
      and $projection.ClassType      = _ClassStatus.ClassType
     
    association [0..1] to I_ClfnClassGroup                as _ClassGroup 
      on  $projection.ClassGroup     = _ClassGroup.ClassGroup

    association [0..1] to I_ClfnClassTypeBasic            as _ClassType 
      on  _ClassType.ClassType       = $projection.ClassType 

    association [0..1] to I_User                         as _CreatedByUser
      on  $projection.CreatedByUser = _CreatedByUser.UserID
      
    association [0..1] to I_User                         as _LastChangedByUser
      on  $projection.LastChangedByUser = _LastChangedByUser.UserID
{
  key Class.clint           as ClassInternalID,
      Class.klart           as ClassType,
      Class.class           as Class,
      Class.statu           as ClassStatus,
      Class.klagr           as ClassGroup,      
      Class.bgrse           as ClassSearchAuthGrp,
      Class.bgrkl           as ClassClassfctnAuthGrp,
      Class.bgrkp           as ClassMaintAuthGrp,
      Class.aname           as CreatedByUser,
      Class.adatu           as CreationDate,
      Class.vname           as LastChangedByUser,
      Class.vdatu           as LastChangeDate,
      @Semantics.businessDate.from: true
      Class.vondt           as ValidityStartDate,
      @Semantics.businessDate.to: true
      Class.bisdt           as ValidityEndDate,      
//      Class.anzou,

      cast( Class.praus as char1 preserving type ) as SameClassfctnReaction,
      cast( Class.sicht as clfnorganizationalarea preserving type ) as ClfnOrganizationalArea,
      Class.doknr           as DocumentInfoRecordDocNumber,
      Class.dokar           as DocumentInfoRecordDocType,
      Class.doktl           as DocumentInfoRecordDocPart,
      Class.dokvr           as DocumentInfoRecordDocVersion,           
//      Class.dinkz           as ClassDINCode,

      Class.nnorm           as ClassStandardOrgName,
      Class.normn           as ClassStandardNumber,
      Class.ausgd           as ClassStandardStartDate,
      Class.versd           as ClassStandardVersionStartDate,
      Class.versi           as ClassStandardVersion,
      Class.leist           as ClassStandardCharcTable,
//      Class.verwe,

//      Class.spart,

      Class.meins           as ClassBaseUnit,
      Class.vwstl           as ClassIsUsableInBOM,
      Class.locla           as ClassIsLocal,
      Class.lastchangeddatetime as ClassLastChangedDateTime,
      
      _ClassDescription,
      _ClassKeyword,
      _ClassStatus,
      _ClassGroup,
      _ClassType,
      _CreatedByUser,
      _LastChangedByUser

}
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"KLAH"
],
"ASSOCIATED":
[
"I_CLFNCLASSDESCRIPTION",
"I_CLFNCLASSGROUP",
"I_CLFNCLASSKEYWORD",
"I_CLFNCLASSSTATUS",
"I_CLFNCLASSTYPEBASIC",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More