I_MfgBillOfOperations

@AbapCatalog.sqlViewName: 'IMFGBILLOFOPER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'BillOfOperationsVariant'
@ObjectModel.semanticKey: ['BillOfOperationsType', 'BillOfOperationsGroup', 'BillOfOperationsVariant']
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Manufacturing Bill of Operations'

define view I_MfgBillOfOperations
  as select from I_BillOfOperations as plkz
  
  -- to child: Change State of Root
  association [1..*] to I_MfgBillOfOperationsChgSt    as _BillOfOperationsChangeState on  $projection.BillOfOperationsType    = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsChangeState.BillOfOperationsVariant
  -- to child: Sequences
  association [1..*] to I_MfgBillOfOperationsSequence as _BillOfOperationsSequence    on  $projection.BillOfOperationsType    = _BillOfOperationsSequence.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsSequence.BillOfOperationsVariant
  -- to child: Material to BOO assignment
  association [1..*] to I_MfgBOOMaterialAssignment    as _BOOMaterialAssignment       on  $projection.BillOfOperationsType    = _BOOMaterialAssignment.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BOOMaterialAssignment.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BOOMaterialAssignment.BillOfOperationsVariant
{
      // Key

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plkz.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plkz.BillOfOperationsGroup,
      -- representative key
  key plkz.BillOfOperationsVariant,

      // Attributes

      plkz.LastUsageDate,
      plkz.NumberOfUsages,
      plkz.HasChangeNumber,
      plkz.HasParameterEffectivity,

      // Administrative Data

      @Semantics.systemDate.lastChangedAt: true
      plkz.LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      plkz.LastChangeTime,
      @Semantics.user.lastChangedBy: true
      plkz.LastChangedByUser, 

      // Associations 

      _BillOfOperationsChangeState,
      _BillOfOperationsGroup,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BOOMaterialAssignment
}
where plkz.BillOfOperationsType = '2'  // Recipe

   or plkz.BillOfOperationsType = 'N'  // Standard routing

   or plkz.BillOfOperationsType = 'S'; // Reference operation set

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_MFGBILLOFOPERATIONSCHGST",
"I_MFGBILLOFOPERATIONSSEQUENCE",
"I_MFGBOOMATERIALASSIGNMENT"
],
"BASE":
[
"I_BILLOFOPERATIONS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/