I_BillOfOperations

@AbapCatalog.sqlViewName: 'IPPBILLOFOPER'
@ObjectModel.compositionRoot: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BillOfOperationsVariant'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Bill of Operations'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey:true

define view I_BillOfOperations
  as select from plkz

  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsVersionType as _BillOfOperationsVersionType on  $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType
  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  -- to child: Change State of Root
  association [1..*] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType    = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsChangeState.BillOfOperationsVariant
  -- to child: Sequences
  association [1..*] to I_BillOfOperationsSequence    as _BillOfOperationsSequence    on  $projection.BillOfOperationsType    = _BillOfOperationsSequence.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsSequence.BillOfOperationsVariant

  -- to child: Material to BOO assignment
  association [1..*] to I_BOOMaterialAssignment       as _BOOMaterialAssignment       on  $projection.BillOfOperationsType    = _BOOMaterialAssignment.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BOOMaterialAssignment.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BOOMaterialAssignment.BillOfOperationsVariant



{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plkz.plnty                                                  as BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plkz.plnnr                                                  as BillOfOperationsGroup,
  key plkz.plnal                                                  as BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsVersionType'
      plkz.subtype                                                as BillOfOperationsVersionType,

      plkz.subtype                                                as BillOfOperationsSubtype, //kept for compatibility reasons


      plkz.abdat                                                  as LastUsageDate,
      plkz.abanz                                                  as NumberOfUsages,

      plkz.flg_ecm                                                as HasChangeNumber,
      plkz.flg_ecm_par                                            as HasParameterEffectivity,

      -- Administrative Data
      @Semantics.systemDate.lastChangedAt: true
      plkz.aedat                                                  as LastChangeDate,
      plkz.aeuzeit                                                as LastChangeTime,
      @Semantics.user.lastChangedBy: true
      cast(plkz.aenam as vdm_lastchangedbyuserid preserving type) as LastChangedByUser,
      plkz.delkz                                                  as IsMarkedForDeletion,
      
      plkz.altext                                                 as BillOfOperationsVariantDesc,

      plkz.rework                                                 as RoutingIsReworkRouting,
      plkz.relaxed                                                as ProdnProcgIsFlexible,
      
      plkz.execution_in_me                                        as BillOfOperationIsExecutedInMES,
      plkz.erp_integration                                        as BillOfOperationsIsTrnsfdToERP,
      
      plkz.reference_template_category                            as ShopFloorRtgTemplateCategory,
      plkz.reference_template_type                                as ShopFloorRoutingTemplateType,
      plkz.reference_template_subtype                             as ShopFloorRtgTemplateSubType,
      plkz.reference_template_owner                               as ShopFloorRoutingTemplateOwner,

      // **************************** Associations *****************************


      _BOOMaterialAssignment,
      _BillOfOperationsChangeState,
      _BillOfOperationsGroup,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BillOfOperationsVersionType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PLKZ"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSCHANGESTATE",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSSEQUENCE",
"I_BILLOFOPERATIONSTYPE",
"I_BILLOFOPERATIONSVERSIONTYPE",
"I_BOOMATERIALASSIGNMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/