I_MfgBillOfOperationsSequence

@AbapCatalog.sqlViewName: 'IMFGBOOSEQUENCE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'BillOfOperationsSequence'
@ObjectModel.semanticKey: ['BillOfOperationsType', 'BillOfOperationsGroup', 'BillOfOperationsVariant', 'BillOfOperationsSequence']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER}
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Manufacturing Bill of Operations Sequence'

define view I_MfgBillOfOperationsSequence
  as select distinct from I_BillOfOperationsSequence as plfl

   -- to parent / root
  association [1..1] to I_MfgBillOfOperations         as _BillOfOperations           on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  -- to child
  association [1..*] to I_MfgBOOSequenceChangeState   as _BOOSequenceChangeState     on  $projection.BillOfOperationsType     = _BOOSequenceChangeState.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup    = _BOOSequenceChangeState.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant  = _BOOSequenceChangeState.BillOfOperationsVariant
                                                                                     and $projection.BillOfOperationsSequence = _BOOSequenceChangeState.BillOfOperationsSequence
  -- to child
  association [1..*] to I_MfgBillOfOperationsOperation as _BillOfOperationsOperation on  $projection.BillOfOperationsType     = _BillOfOperationsOperation.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup    = _BillOfOperationsOperation.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant  = _BillOfOperationsOperation.BillOfOperationsVariant
                                                                                     and $projection.BillOfOperationsSequence = _BillOfOperationsOperation.BillOfOperationsSequence
{
      // Key

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plfl.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plfl.BillOfOperationsGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgBillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plfl.BillOfOperationsVariant,
      // representative key BillOfOperationsSequence

  key plfl.BillOfOperationsSequence,

      // Associations

      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsType,
      _BillOfOperationsOperation,
      _BOOSequenceChangeState
}
where plfl.BillOfOperationsType = '2'  // Recipe

   or plfl.BillOfOperationsType = 'N'  // Standard routing

   or plfl.BillOfOperationsType = 'S'; // Reference operation set

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSSEQUENCE"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_MFGBILLOFOPERATIONS",
"I_MFGBILLOFOPERATIONSOPERATION",
"I_MFGBOOSEQUENCECHANGESTATE"
],
"BASE":
[
"I_BILLOFOPERATIONSSEQUENCE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/