I_MfgBOOMaterialAssignment

@AbapCatalog.sqlViewName: 'IMFGBOOMATASGNMT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'BOOToMaterialInternalID'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER}
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Material Assignment to Manufacturing Bill of Operations'

define view I_MfgBOOMaterialAssignment
  as select from I_BOOMaterialAssignment as mapl

  -- to parent
  association [1..1] to I_MfgBillOfOperations       as _BillOfOperations       on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                               and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                               and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  -- to child
  association [1..*] to I_MfgBOOMaterialAssgmtChgSt as _BOOMaterialAssgmtChgSt on  $projection.Product                  = _BOOMaterialAssgmtChgSt.Product
                                                                               and $projection.Plant                    = _BOOMaterialAssgmtChgSt.Plant
                                                                               and $projection.BillOfOperationsType     = _BOOMaterialAssgmtChgSt.BillOfOperationsType
                                                                               and $projection.BillOfOperationsGroup    = _BOOMaterialAssgmtChgSt.BillOfOperationsGroup
                                                                               and $projection.BillOfOperationsVariant  = _BOOMaterialAssgmtChgSt.BillOfOperationsVariant
                                                                               and $projection.BOOToMaterialInternalID  = _BOOMaterialAssgmtChgSt.BOOToMaterialInternalID                                                                  
                               
  association [1..1] to I_Product                   as _Product                on  $projection.Product = _Product.Product
  association [1..1] to I_ProductPlant              as _ProductPlant           on  $projection.Product = _ProductPlant.Product
                                                                               and $projection.Plant   = _ProductPlant.Plant
  association [1..1] to I_ProductPlantBasic         as _ProductPlant2          on  $projection.Product = _ProductPlant2.Product
                                                                               and $projection.Plant   = _ProductPlant2.Plant
{
      // Key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      @ObjectModel.foreignKey.association: '_Product'
  key mapl.Material as Product,
      @ObjectModel.foreignKey.association: '_Plant'
  key mapl.Plant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key mapl.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key mapl.BillOfOperationsGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgBillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key mapl.BillOfOperationsVariant,
      -- Representative Key
  key mapl.BOOToMaterialInternalID,

      // Associations

      _Product,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_ProductPlant2'
      _ProductPlant,
      _ProductPlant2,
      _Plant,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperations,
      _BOOMaterialAssgmtChgSt
}
where mapl.BillOfOperationsType = '2'  // Recipe

   or mapl.BillOfOperationsType = 'N'  // Standard routing

   or mapl.BillOfOperationsType = 'S'; // Reference operation set

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BOOMATERIALASSIGNMENT"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_MFGBILLOFOPERATIONS",
"I_MFGBOOMATERIALASSGMTCHGST",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTPLANT",
"I_PRODUCTPLANTBASIC"
],
"BASE":
[
"I_BOOMATERIALASSIGNMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/