I_FixedAssetLineItem

@AbapCatalog: {sqlViewName: 'IFASSETLINEITEM', preserveKey: true}
@EndUserText.label: 'Fixed Asset Line Items'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { usageType.serviceQuality: #C,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #TRANSACTIONAL }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view I_FixedAssetLineItem
  as select from P_FixedAssetLineItem1

  association [0..1] to I_ChartOfDepreciation          as _ChartOfDepreciation        on  $projection.ChartOfDepreciation = _ChartOfDepreciation.ChartOfDepreciation
  association [0..1] to I_DepreciationAreaForLedger    as _DepreciationArea           on  $projection.CompanyCode           = _DepreciationArea.CompanyCode
                                                                                      and $projection.Ledger                = _DepreciationArea.Ledger
                                                                                      and $projection.AssetDepreciationArea = _DepreciationArea.AssetDepreciationArea
  association [0..1] to I_CompanyCode                  as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_FiscalYearForCompanyCode     as _FiscalYear                 on  $projection.FiscalYear  = _FiscalYear.FiscalYear
                                                                                      and $projection.CompanyCode = _FiscalYear.CompanyCode
  //Begin of deprecated associations -> Do not use any longer

  association [0..1] to I_FiscalYearPeriodForCmpnyCode as _FiscalPeriod               on  $projection.FiscalYear   = _FiscalPeriod.FiscalYear
                                                                                      and $projection.FiscalPeriod = _FiscalPeriod.FiscalPeriod
                                                                                      and $projection.CompanyCode  = _FiscalPeriod.CompanyCode
  //End of deprecated associations -> Do not use any longer

  association [0..1] to I_MasterFixedAsset             as _MasterFixedAsset           on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                      and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
  association [0..1] to I_FixedAsset                   as _FixedAsset                 on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                      and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                                      and $projection.FixedAsset       = _FixedAsset.FixedAsset
  association [0..1] to I_MasterFixedAsset             as _PartnerMasterFixedAsset    on  $projection.CompanyCode             = _PartnerMasterFixedAsset.CompanyCode
                                                                                      and $projection.PartnerMasterFixedAsset = _PartnerMasterFixedAsset.MasterFixedAsset
  association [0..1] to I_FixedAsset                   as _PartnerFixedAsset          on  $projection.CompanyCode             = _PartnerFixedAsset.CompanyCode
                                                                                      and $projection.PartnerMasterFixedAsset = _PartnerFixedAsset.MasterFixedAsset
                                                                                      and $projection.PartnerFixedAsset       = _PartnerFixedAsset.FixedAsset
  association [1]    to I_ChartOfAccounts              as _ChartOfAccounts            on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [0..1] to I_ChartOfAccounts              as _CountryChartOfAccounts     on  $projection.CountryChartOfAccounts = _CountryChartOfAccounts.ChartOfAccounts
  association [0..1] to I_GLAccountInChartOfAccounts   as _GLAccountInChartOfAccounts on  $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
                                                                                      and $projection.GLAccount       = _GLAccountInChartOfAccounts.GLAccount
  association [0..1] to I_GLAccountInChartOfAccounts   as _AlternativeGLAccount       on  $projection.CountryChartOfAccounts = _AlternativeGLAccount.ChartOfAccounts
                                                                                      and $projection.AlternativeGLAccount   = _AlternativeGLAccount.GLAccount
  association [0..1] to I_SubLedgerAccLineItemType     as _SubLedgerAccLineItemType   on  $projection.SubLedgerAcctLineItemType = _SubLedgerAccLineItemType.SubLedgerAcctLineItemType
  association [0..1] to I_LedgerGroup                  as _LedgerGroup                on  $projection.LedgerGroup = _LedgerGroup.LedgerGroup
  association [0..1] to I_JournalEntry                 as _JournalEntry               on  $projection.CompanyCode        = _JournalEntry.CompanyCode
                                                                                      and $projection.FiscalYear         = _JournalEntry.FiscalYear
                                                                                      and $projection.AccountingDocument = _JournalEntry.AccountingDocument
  association [0..1] to I_Ledger                       as _Ledger                     on  $projection.Ledger = _Ledger.Ledger
  association [0..1] to I_MovementCategory             as _AssetAcctTransClassfctn    on  $projection.AssetAcctTransClassfctn = _AssetAcctTransClassfctn.AssetAcctTransClassfctn
  association [0..1] to I_FinancialAccountType         as _FinancialAccountType       on  $projection.FinancialAccountType = _FinancialAccountType.FinancialAccountType
  association [0..1] to I_AssetTransactionType         as _AssetTransactionType       on  $projection.AssetTransactionType = _AssetTransactionType.AssetTransactionType
  association [1]    to I_DebitCreditCode              as _DebitCreditCode            on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [0..1] to I_Country                      as _Country                    on  $projection.Country = _Country.Country
  association [0..1] to I_ControllingArea              as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..*] to I_CostCenter                   as _CostCenter                 on  $projection.CostCenter      = _CostCenter.CostCenter
                                                                                      and $projection.ControllingArea = _CostCenter.ControllingArea
  association [0..1] to I_Plant                        as _Plant                      on  $projection.Plant = _Plant.Plant
  association [0..1] to I_BusinessArea                 as _BusinessArea               on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..*] to I_ProfitCenter                 as _ProfitCenter               on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                                      and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [0..1] to I_Segment                      as _Segment                    on  $projection.Segment = _Segment.Segment
  association [0..1] to I_FunctionalArea               as _FunctionalArea             on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_PurchasingDocument           as _PurchasingDocument         on  $projection.PurchasingDocument = _PurchasingDocument.PurchasingDocument
  association [0..1] to I_PurchasingDocumentItem       as _PurchasingDocumentItem     on  $projection.PurchasingDocument     = _PurchasingDocumentItem.PurchasingDocument
                                                                                      and $projection.PurchasingDocumentItem = _PurchasingDocumentItem.PurchasingDocumentItem
  association [0..1] to I_Currency                     as _CompanyCodeCurrency        on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_Currency                     as _GlobalCurrency             on  $projection.GlobalCurrency = _GlobalCurrency.Currency
  association [0..1] to I_Currency                     as _FunctionalCurrency         on  $projection.FunctionalCurrency = _FunctionalCurrency.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency1       on  $projection.FreeDefinedCurrency1 = _FreeDefinedCurrency1.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency2       on  $projection.FreeDefinedCurrency2 = _FreeDefinedCurrency2.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency3       on  $projection.FreeDefinedCurrency3 = _FreeDefinedCurrency3.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency4       on  $projection.FreeDefinedCurrency4 = _FreeDefinedCurrency4.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency5       on  $projection.FreeDefinedCurrency5 = _FreeDefinedCurrency5.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency6       on  $projection.FreeDefinedCurrency6 = _FreeDefinedCurrency6.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency7       on  $projection.FreeDefinedCurrency7 = _FreeDefinedCurrency7.Currency
  association [0..1] to I_Currency                     as _FreeDefinedCurrency8       on  $projection.FreeDefinedCurrency8 = _FreeDefinedCurrency8.Currency

  association [0..1] to I_UnitOfMeasure                as _BaseUnit                   on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure

  association [1..1] to I_FiscalYearVariant            as _FiscalYearVariant          on  $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
  association [0..1] to I_FiscalYearForVariant         as _LedgerFiscalYearForVariant on  $projection.LedgerFiscalYear  = _LedgerFiscalYearForVariant.FiscalYear
                                                                                      and $projection.FiscalYearVariant = _LedgerFiscalYearForVariant.FiscalYearVariant
  association [0..1] to I_FiscalYearPeriodForVariant   as _FiscalYearPeriodForVariant on  $projection.FiscalYearPeriod  = _FiscalYearPeriodForVariant.FiscalYearPeriod
                                                                                      and $projection.FiscalYearVariant = _FiscalYearPeriodForVariant.FiscalYearVariant
  association [0..1] to I_FiscalPeriodForVariant       as _FiscalPeriodForVariant     on  $projection.LedgerFiscalYear  = _FiscalPeriodForVariant.FiscalYear
                                                                                      and $projection.FiscalPeriod      = _FiscalPeriodForVariant.FiscalPeriod
                                                                                      and $projection.FiscalYearVariant = _FiscalPeriodForVariant.FiscalYearVariant
  association [0..1] to I_AccountingDocumentType       as _AccountingDocumentType     on  $projection.AccountingDocumentType = _AccountingDocumentType.AccountingDocumentType
  association [1]    to I_AccountingPrinciple          as _AccountingPrinciple        on  $projection.AccountingPrinciple = _AccountingPrinciple.AccountingPrinciple
  association [1]    to I_AccountingPrincipleAssgmt    as _AccountingPrincipleAssgmt  on  $projection.AccountingPrinciple = _AccountingPrincipleAssgmt.AccountingPrinciple
  association [0..1] to I_FinancialManagementArea      as _FinancialManagementArea    on  $projection.FinancialManagementArea = _FinancialManagementArea.FinancialManagementArea
  association [0..1] to I_Fund                         as _Fund                       on  $projection.FinancialManagementArea = _Fund.FinancialManagementArea
                                                                                      and $projection.Fund                    = _Fund.Fund
  association [0..1] to I_BudgetPeriod                 as _BudgetPeriod               on  $projection.BudgetPeriod = _BudgetPeriod.BudgetPeriod
{
        @ObjectModel.foreignKey.association: '_DepreciationArea'
  key   AssetDepreciationArea,
        @ObjectModel.foreignKey.association: '_CompanyCode'
  key   CompanyCode,
        @ObjectModel.foreignKey.association: '_FiscalYear'
  key   FiscalYear,
        @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key   MasterFixedAsset,
        @ObjectModel.foreignKey.association: '_FixedAsset'
  key   FixedAsset,
        @ObjectModel.foreignKey.association: '_SubledgerAccLineItemType'
  key   SubLedgerAcctLineItemType,
        //@ObjectModel.foreignKey.association: '_FiscalPeriod'

        @ObjectModel.foreignKey.association: '_FiscalPeriodForVariant'
  key   FiscalPeriod,
        @ObjectModel.foreignKey.association: '_LedgerGroup'
  key   LedgerGroup,
        @ObjectModel.foreignKey.association: '_JournalEntry'
  key   AccountingDocument,
  key   LedgerGLLineItem,
        @ObjectModel.foreignKey.association: '_Ledger'
  key   Ledger,
  key   TransactionSubitem,
        @ObjectModel.foreignKey.association: '_DebitCreditCode'
  key   DebitCreditCode,

        @ObjectModel.foreignKey.association: '_AccountingPrinciple'
        AccountingPrinciple,
        @ObjectModel.foreignKey.association: '_LedgerFiscalYearForVariant'
        @Semantics.fiscal.year: true
        LedgerFiscalYear,
        @ObjectModel.foreignKey.association: '_FiscalYearVariant'
        @Semantics.fiscal.yearVariant: true
        FiscalYearVariant,
        @ObjectModel.foreignKey.association: '_FiscalYearPeriodForVariant'
        @Semantics.fiscal.yearPeriod: true
        FiscalYearPeriod,

        @ObjectModel.foreignKey.association: '_ChartOfAccounts'
        ChartOfAccounts,
        @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
        GLAccount,
        @ObjectModel.foreignKey.association: '_CountryChartOfAccounts'
        CountryChartOfAccounts,
        @ObjectModel.foreignKey.association: '_AlternativeGLAccount'
        AlternativeGLAccount,
        IsStatisticalDocument,
        @ObjectModel.foreignKey.association: '_AssetAcctTransClassfctn'
        AssetAcctTransClassfctn,
        GroupMasterFixedAsset,
        GroupFixedAsset,
        @ObjectModel.foreignKey.association: '_FinancialAccountType'
        FinancialAccountType,
        @ObjectModel.foreignKey.association: '_ChartOfDepreciation'
        ChartOfDepreciation,

        ReferenceDocumentItem,
        ReferenceDocumentType,
        LogicalSystem,
        ReferenceDocument,
        ReferenceDocumentContext,
        ReversalReferenceDocument,
        ReversalReferenceDocumentCntxt,
        IsReversal,
        IsReversed,
        DocumentDate,
        PostingDate,
        @ObjectModel.foreignKey.association: '_AssetTransactionType'
        AssetTransactionType,
        AssetValueDate,
        @Semantics.businessDate.at: true
        AccountingDocumentCreationDate,
        CreationTime,
        DocumentItemText,
        AccountingDocCreatedByUser,
        GLBusinessTransactionType,
        AssignmentReference,
        JointVentureCostRecoveryCode,
        DepreciationFiscalPeriod,
        AccountingDocumentItem,
        ReversalTransactionSubitem,

        @ObjectModel.foreignKey.association: '_PurchasingDocument'
        PurchasingDocument,
        @ObjectModel.foreignKey.association: '_PurchasingDocumentItem'
        PurchasingDocumentItem,

        @ObjectModel.foreignKey.association: '_CostCenter'
        CostCenter,
        @ObjectModel.foreignKey.association: '_Plant'
        Plant,
        @ObjectModel.foreignKey.association: '_BusinessArea'
        BusinessArea,
        PersonnelNumber,
        @ObjectModel.foreignKey.association: '_FinancialManagementArea'
        FinancialManagementArea,
        @ObjectModel.foreignKey.association: '_Fund'
        Fund,
        GrantID,
        @ObjectModel.foreignKey.association: '_FunctionalArea'
        FunctionalArea,
        @ObjectModel.foreignKey.association: '_BudgetPeriod'
        BudgetPeriod,
        @ObjectModel.foreignKey.association: '_ProfitCenter'
        ProfitCenter,
        @ObjectModel.foreignKey.association: '_Segment'
        Segment,
        @ObjectModel.foreignKey.association: '_ControllingArea'
        ControllingArea,
        @ObjectModel.foreignKey.association: '_Country'
        Country,
        FundsCenter,
        @ObjectModel.foreignKey.association: '_AccountingDocumentType'
        AccountingDocumentType,

        @ObjectModel.foreignKey.association: '_PartnerMasterFixedAsset'
        PartnerMasterFixedAsset,
        @ObjectModel.foreignKey.association: '_PartnerFixedAsset'
        PartnerFixedAsset,
        JrnlEntryItemMigrationSource,

        //Measures

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
        CompanyCodeCurrency,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
        AmountInCompanyCodeCurrency,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_GlobalCurrency'
        GlobalCurrency,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
        AmountInGlobalCurrency,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FunctionalCurrency'
        FunctionalCurrency,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
        AmountInFunctionalCurrency,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency1'
        FreeDefinedCurrency1,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
        AmountInFreeDefinedCurrency1,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency2'
        FreeDefinedCurrency2,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
        AmountInFreeDefinedCurrency2,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency3'
        FreeDefinedCurrency3,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
        AmountInFreeDefinedCurrency3,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency4'
        FreeDefinedCurrency4,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
        AmountInFreeDefinedCurrency4,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency5'
        FreeDefinedCurrency5,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
        AmountInFreeDefinedCurrency5,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency6'
        FreeDefinedCurrency6,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
        AmountInFreeDefinedCurrency6,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency7'
        FreeDefinedCurrency7,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
        AmountInFreeDefinedCurrency7,

        @Semantics.currencyCode:true
        @ObjectModel.foreignKey.association: '_FreeDefinedCurrency8'
        FreeDefinedCurrency8,
        @DefaultAggregation: #SUM
        @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
        AmountInFreeDefinedCurrency8,

        @ObjectModel.foreignKey.association: '_BaseUnit'
        @Semantics.unitOfMeasure:true
        BaseUnit,
        @DefaultAggregation: #SUM
        @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
        Quantity,

        //Publish Associations

        _DepreciationArea,
        _CompanyCode,
        _ControllingArea,
        _Country,
        _FiscalYear,
        _FiscalPeriod,
        _MasterFixedAsset,
        _FixedAsset,
        _SubLedgerAccLineItemType,
        _ChartOfAccounts,
        _CountryChartOfAccounts,
        _GLAccountInChartOfAccounts,
        _AlternativeGLAccount,
        _LedgerGroup,
        _JournalEntry,
        _Ledger,
        _AssetAcctTransClassfctn,
        _FinancialAccountType,
        _ChartOfDepreciation,
        _AssetTransactionType,
        _DebitCreditCode,
        _PurchasingDocument,
        _PurchasingDocumentItem,
        _CostCenter,
        _Plant,
        _BusinessArea,
        _ProfitCenter,
        _Segment,
        _FunctionalArea,
        _CompanyCodeCurrency,
        _GlobalCurrency,
        _FunctionalCurrency,
        _BaseUnit,
        _FreeDefinedCurrency1,
        _FreeDefinedCurrency2,
        _FreeDefinedCurrency3,
        _FreeDefinedCurrency4,
        _FreeDefinedCurrency5,
        _FreeDefinedCurrency6,
        _FreeDefinedCurrency7,
        _FreeDefinedCurrency8,
        _FiscalYearVariant,
        _LedgerFiscalYearForVariant,
        _FiscalYearPeriodForVariant,
        _FiscalPeriodForVariant,
        _AccountingDocumentType,
        _AccountingPrinciple,
        _FinancialManagementArea,
        _Fund,
        _BudgetPeriod,
        _PartnerMasterFixedAsset,
        _PartnerFixedAsset
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_FIXEDASSETLINEITEM1"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ACCOUNTINGPRINCIPLE",
"I_ACCOUNTINGPRINCIPLEASSGMT",
"I_ASSETTRANSACTIONTYPE",
"I_BUDGETPERIOD",
"I_BUSINESSAREA",
"I_CHARTOFACCOUNTS",
"I_CHARTOFDEPRECIATION",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_COUNTRY",
"I_CURRENCY",
"I_DEBITCREDITCODE",
"I_DEPRECIATIONAREAFORLEDGER",
"I_FINANCIALACCOUNTTYPE",
"I_FINANCIALMANAGEMENTAREA",
"I_FISCALPERIODFORVARIANT",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARFORVARIANT",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_FISCALYEARPERIODFORVARIANT",
"I_FISCALYEARVARIANT",
"I_FIXEDASSET",
"I_FUNCTIONALAREA",
"I_FUND",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_JOURNALENTRY",
"I_LEDGER",
"I_LEDGERGROUP",
"I_MASTERFIXEDASSET",
"I_MOVEMENTCATEGORY",
"I_PLANT",
"I_PROFITCENTER",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_SEGMENT",
"I_SUBLEDGERACCLINEITEMTYPE",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/