I_FiscalYearVariant

@VDM: {lifecycle.contract.type: #PUBLIC_LOCAL_API,
       viewType: #BASIC 
}
@AbapCatalog: { buffering: {status: #ACTIVE,         
                            type: #FULL,
                            numberOfKeyFields: 2},
                compiler.compareFilter: true,
                sqlViewName: 'IFIFISCYEARVAR',
                preserveKey: true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Fiscal Year Variant'
@ObjectModel: {usageType: { serviceQuality: #A,
                            sizeCategory: #S,
                            dataClass: #CUSTOMIZING },
               modelingPattern: #ANALYTICAL_DIMENSION,
               supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE,
                                     #EXTRACTION_DATA_SOURCE],
               representativeKey: 'FiscalYearVariant',
               sapObjectNodeType.name: 'FiscalYearVariant'                       
}  
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
@Consumption.ranked: true
                                    
define view I_FiscalYearVariant as select from t009

association[0..*] to I_FiscalYearVariantText  as _Text on  $projection.FiscalYearVariant = _Text.FiscalYearVariant
{ 

@Search.defaultSearchElement: true 
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@ObjectModel.text.association: '_Text'
@Semantics.fiscal.yearVariant: true 
key cast( periv as fis_periv preserving type ) as FiscalYearVariant,
cast( xkale as fis_xkale preserving type )     as FiscalPeriodIsEqualMonth,
xjabh                                          as IsYearDependent,
anzbp                                          as PostingPeriodsNumberVal,
anzsp                                          as NumberOfSpecialPeriods,
xweek                                          as FsclWeekStartIsFsclYearStart,
xweekquart                                     as FiscalCalendarIsWeekBased,

_Text

}       

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T009"
],
"ASSOCIATED":
[
"I_FISCALYEARVARIANTTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/