I_DocumentInfoRecord

@AbapCatalog.sqlViewName: 'ICVDOCINFOREC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedUser', '_ChangedUser', '_UserDetails' ]
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'DocumentInfoRecordDocPart'
@Analytics: { dataCategory: #DIMENSION } 
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@EndUserText.label: 'Document Info Record Details'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations:true 
@ObjectModel.supportedCapabilities:  [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET]


define view I_DocumentInfoRecord
  as select from P_DocumentInfoRecord as DocInfo

  --Get Document Type Association
  association [0..1] to I_DocumentInfoRecordDocType    as _DocType                  on  $projection.DocumentInfoRecordDocType = _DocType.DocumentInfoRecordDocType

  --Get Document Number Association
  association [1..1] to I_DocumentInfoRecordDocNumber  as _DocNumber                on  $projection.DocumentInfoRecordDocType   = _DocNumber.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocNumber = _DocNumber.DocumentInfoRecordDocNumber

  --Get Document Version Association
  association [0..1] to I_DocumentInfoRecordDocVersion as _DocVersion               on  $projection.DocumentInfoRecordDocType    = _DocVersion.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _DocVersion.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocVersion = _DocVersion.DocumentInfoRecordDocVersion

  --Get Document Part Association
  association [0..1] to I_DocumentInfoRecordDocPrt     as _DocPart                  on  $projection.DocumentInfoRecordDocType    = _DocPart.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocPart    = _DocPart.DocumentInfoRecordDocPart
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _DocPart.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocVersion = _DocPart.DocumentInfoRecordDocVersion

  --Get DocumentInfoRecord created user full name
  association [1..1] to I_User                         as _CreatedUser              on  $projection.CreatedByUser = _CreatedUser.UserID

  --Get DocumentInfoRecord changed user full name
  association [1..1] to I_User                         as _ChangedUser              on  $projection.LastChangedByUser = _ChangedUser.UserID

  --Get Responsible user full name
  association [1..1] to I_User                         as _UserDetails              on  $projection.ResponsiblePersonName = _UserDetails.UserID

  --Get DocumentInfoRecord created user value help
  association [1..1] to I_DocumentInfoRecordUserVH     as _CreatedUserVH            on  $projection.DocumentInfoRecordDocType    = _CreatedUserVH.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocPart    = _CreatedUserVH.DocumentInfoRecordDocPart
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _CreatedUserVH.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocVersion = _CreatedUserVH.DocumentInfoRecordDocVersion
                                                                                    and $projection.CreatedByUser                = _CreatedUserVH.ResponsiblePersonName

  --Get DocumentInfoRecord changed user value help
  association [1..1] to I_DocumentInfoRecordUserVH     as _ChangedUserVH            on  $projection.DocumentInfoRecordDocType    = _ChangedUserVH.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocPart    = _ChangedUserVH.DocumentInfoRecordDocPart
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _ChangedUserVH.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocVersion = _ChangedUserVH.DocumentInfoRecordDocVersion
                                                                                    and $projection.LastChangedByUser            = _ChangedUserVH.LastChangedByUser

  --Get DocumentInfoRecord Responsible user value help
  association [1..1] to I_DocumentInfoRecordUserVH     as _UserDetailsVH            on  $projection.DocumentInfoRecordDocType    = _UserDetailsVH.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocPart    = _UserDetailsVH.DocumentInfoRecordDocPart
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _UserDetailsVH.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocVersion = _UserDetailsVH.DocumentInfoRecordDocVersion
                                                                                    and $projection.ResponsiblePersonName        = _UserDetailsVH.ResponsiblePersonName

  --Get DocumentInfoRecord Description
  association [0..*] to I_DocumentInfoRecordDesc       as _DocDesc                  on  $projection.DocumentInfoRecordDocType    = _DocDesc.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _DocDesc.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocPart    = _DocDesc.DocumentInfoRecordDocPart
                                                                                    and $projection.DocumentInfoRecordDocVersion = _DocDesc.DocumentInfoRecordDocVersion

  --Get Document Status and its Description
  association [0..1] to I_DocumentInfoRecordDocStatus  as _DocStatus                on  $projection.DocumentInfoRecordDocType = _DocStatus.DocumentInfoRecordDocType
                                                                                    and $projection.InternalDocumentStatus    = _DocStatus.InternalDocumentStatus
  --Get Lab office Association
  association [1..1] to I_DocumentInfoRecordLbtryOffc  as _LabOffice                on  $projection.LaboratoryOrDesignOffice = _LabOffice.LaboratoryOrDesignOffice

  --Get Authorization Group Association
  association [1..1] to I_DocumentInfoRecordAuthznGrp  as _AuthGroup                on  $projection.AuthorizationGroup = _AuthGroup.AuthorizationGroup

  --Get CAD, Marked for Deletion and Structure Indicator
  association [1..1] to I_DocumentInfoRecordIndSts     as _Indicator                on  $projection.DocumentInfoRecordDocType    = _Indicator.DocumentInfoRecordDocType
                                                                                    and $projection.DocumentInfoRecordDocPart    = _Indicator.DocumentInfoRecordDocPart
                                                                                    and $projection.DocumentInfoRecordDocNumber  = _Indicator.DocumentInfoRecordDocNumber
                                                                                    and $projection.DocumentInfoRecordDocVersion = _Indicator.DocumentInfoRecordDocVersion

  // Access Control Management integration

  association [0..1] to I_DocumentInfoRecordAccMActv   as _LogAccMObjectTypeActive  on  _LogAccMObjectTypeActive.LogAccMObjectType = 'PLM_DIR'
  association [0..*] to I_DocInfoRecordAccMSecIDAsgt     as _LogAccMObjSecureIDAssgmt on  $projection.DocumentInfoRecord              = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                        and _LogAccMObjSecureIDAssgmt.LogAccMObjectType = 'PLM_DIR'
  association [0..*] to I_DocumentInfoRecordUAuthAccM      as _LogAccMObjectUserAuthzn  on  $projection.DocumentInfoRecord = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                      and _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_DIR'
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_DIR'
                                                                                  and (
                                                                                      _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom    = '03'
                                                                                     or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom = '*'
                                                                                  )
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField  = 'ACTVT'
                                                                                 and (
                                                                                     _LogAccMObjectUserAuthzn.LogAccMUserEntityID      = $session.user
                                                                                     or _LogAccMObjectUserAuthzn.UserID                = $session.user
                                                                              )
    
      {                                                                           
      /*  Document Info Record key Details */
      @ObjectModel.foreignKey.association: '_DocType'
  key DocInfo.DocumentInfoRecordDocType                              as  DocumentInfoRecordDocType,
      @ObjectModel.foreignKey.association: '_DocVersion' 
  key DocInfo.DocumentInfoRecordDocVersion                           as  DocumentInfoRecordDocVersion,
      //@ObjectModel.foreignKey.association: '_DocPart'


      @ObjectModel.foreignKey.association: '_DocNumber' 
  key DocInfo.DocumentInfoRecordDocNumber                            as  DocumentInfoRecordDocNumber,
  key DocInfo.DocumentInfoRecordDocPart                              as  DocumentInfoRecordDocPart,

      DocInfo.DocumentInfoRecord                                     as  DocumentInfoRecord,

      /*  Document Info Record other Details */
      DocInfo.InternalDocumentStatus                                 as  InternalDocumentStatus,
      DocInfo.LaboratoryOrDesignOffice                               as  LaboratoryOrDesignOffice,
      DocInfo.Plant                                                  as  Plant,
      DocInfo.AuthorizationGroup                                     as  AuthorizationGroup,
      DocInfo.ChangeNumber                                           as  ChangeNumber,

      /*  Document Structure, CAD and Deletion Indicator */
      DocInfo.DocInfoRecdIsMarkedForDeletion                         as  DocInfoRecdIsMarkedForDeletion,
      DocInfo.IsDocInfoRecdCreatedFromCAD                            as  IsDocInfoRecdCreatedFromCAD,
      //DocInfo.DocInfoRecdHierarchy                                   as  DocInfoRecdHierarchy,

      @Semantics.booleanIndicator: true
      DocInfo.IsDocInfoRecdStructure                                 as  IsDocInfoRecdStructure,

      /* Template of Document Info Record */
      DocInfo.DocInfoRecdSourceDocNumber                             as  DocInfoRecdSourceDocNumber,
      DocInfo.DocInfoRecdSourceDocPart                               as  DocInfoRecdSourceDocPart,
      DocInfo.DocInfoRecdSourceDocVersion                            as  DocInfoRecdSourceDocVersion,

      //@Consumption.valueHelp :'_UserDetailsVH'

      @Consumption.valueHelpDefinition.association: '_UserDetailsVH'
      DocInfo.ResponsiblePersonName                                  as  ResponsiblePersonName,

      /* DIR Administrative Data */
      //@Semantics.businessDate.at: true

      //@Semantics.businessDate.createdAt: true

      //@Semantics.systemDateTime.createdAt: true

      DocInfo.CreationDateTime                                       as  CreationDateTime,

      //@Consumption.valueHelp :'_CreatedUserVH'

      @Consumption.valueHelpDefinition.association: '_CreatedUserVH'
      @Semantics.user.createdBy: true
      DocInfo.CreatedByUser                                          as  CreatedByUser,

      //@Semantics.businessDate.at: true

      //@Semantics.businessDate.lastChangedAt: true

      //@Semantics.systemDateTime.lastChangedAt: true

      DocInfo.ChangedDateTime                                        as  ChangedDateTime,

      //@Consumption.valueHelp :'_ChangedUserVH'

      @Consumption.valueHelpDefinition.association: '_ChangedUserVH'
      @Semantics.user.lastChangedBy: true
      DocInfo.LastChangedByUser                                      as  LastChangedByUser,
      

      /* Associations */
      _DocType,
      _DocNumber,
      _DocVersion,
      _DocPart,
      _CreatedUser,
      _ChangedUser,
      _UserDetails,
      _CreatedUserVH,
      _ChangedUserVH,
      _UserDetailsVH,
      _DocDesc,
      _DocStatus,
      _LabOffice,
      _AuthGroup,
      _Indicator,
      _LogAccMObjectTypeActive,
      _LogAccMObjSecureIDAssgmt,
      _LogAccMObjectUserAuthzn

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_DOCUMENTINFORECORD"
],
"ASSOCIATED":
[
"I_DOCINFORECORDACCMSECIDASGT",
"I_DOCUMENTINFORECORDACCMACTV",
"I_DOCUMENTINFORECORDAUTHZNGRP",
"I_DOCUMENTINFORECORDDESC",
"I_DOCUMENTINFORECORDDOCNUMBER",
"I_DOCUMENTINFORECORDDOCPRT",
"I_DOCUMENTINFORECORDDOCSTATUS",
"I_DOCUMENTINFORECORDDOCTYPE",
"I_DOCUMENTINFORECORDDOCVERSION",
"I_DOCUMENTINFORECORDINDSTS",
"I_DOCUMENTINFORECORDLBTRYOFFC",
"I_DOCUMENTINFORECORDUAUTHACCM",
"I_DOCUMENTINFORECORDUSERVH",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/