C_ChgImpactMfgProcDefDet

@AbapCatalog.sqlViewName: 'CCHGIMPCTMPD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Manufacturing Process Definition Details'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}

@UI.headerInfo:
{

  title:{value:'DocumentDescription'}
}

define view C_ChgImpactMfgProcDefDet
  as select from I_DocumentInfoRecord as Document

  association [0..*] to C_DocumentInfoRecordDescTP   as _Desc             on  $projection.DocumentInfoRecordDocType    = _Desc.DocumentInfoRecordDocType
                                                                          and $projection.DocumentInfoRecordDocNumber  = _Desc.DocumentInfoRecordDocNumber
                                                                          and $projection.DocumentInfoRecordDocVersion = _Desc.DocumentInfoRecordDocVersion
                                                                          and $projection.DocumentInfoRecordDocPart    = _Desc.DocumentInfoRecordDocPart

  association [0..*] to I_DocumentInfoRecordDocTypeT as _DocumentTypeText on  $projection.DocumentInfoRecordDocType = _DocumentTypeText.DocumentInfoRecordDocType

{

      @UI.facet: [
               ----HeaderFacets
                 { type: #FIELDGROUP_REFERENCE, position: 10, targetQualifier: 'GeneralData'},
                 { type: #FIELDGROUP_REFERENCE, position: 20, targetQualifier: 'AdministrativeData'}
                 ]

      @UI.fieldGroup:[{position: 10,qualifier: 'Qualifier1', importance: #HIGH}]
  key Document.DocumentInfoRecordDocNumber                                                 as DocumentInfoRecordDocNumber,
      @UI.fieldGroup:[{position: 20,qualifier: 'Qualifier1', importance: #HIGH}]
  key Document.DocumentInfoRecordDocPart                                                   as DocumentInfoRecordDocPart,
      @UI.fieldGroup:[{position: 10,qualifier: 'Qualifier2', importance: #HIGH}]
      @ObjectModel.text.association: '_DocumentTypeText'
  key Document.DocumentInfoRecordDocType                                                   as DocumentInfoRecordDocType,
      @UI.fieldGroup:[{position: 20,qualifier: 'Qualifier2', importance: #HIGH}]
  key Document.DocumentInfoRecordDocVersion                                                as DocumentInfoRecordDocVersion,

      // General Data facet

      @UI.fieldGroup:[{position: 10,qualifier: 'GeneralData',groupLabel: 'General Data' }]
      @Semantics.text: true     
      _Desc[1: Language = $session.system_language].DocumentDescription,

      // @UI.fieldGroup:[{position: 20,qualifier: 'GeneralData',groupLabel: 'General Data' }]

      Document._DocType._Text[1: Language = $session.system_language].DocumentTypeDescription,

      @UI.hidden: true
      Document.InternalDocumentStatus                                                      as InternalDocumentStatus,

      @UI.fieldGroup:[{position: 30,qualifier: 'GeneralData',groupLabel: 'General Data' }]
      Document._DocStatus._Text[1: Language = $session.system_language].DocumentStatusName as DocumentStatusName,

      @Consumption.filter.hidden: true
      Document.DocInfoRecdIsMarkedForDeletion                                              as DocInfoRecdIsMarkedForDeletion,

      @UI.fieldGroup:[{position: 50,qualifier: 'GeneralData',groupLabel: 'General Data' }]
      cast(  Document.IsDocInfoRecdCreatedFromCAD as xfeld )                               as DocumentIsCreatedByCAD,


      @UI.fieldGroup:[{position: 70,qualifier: 'GeneralData',groupLabel: 'General Data' }]
      cast(  Document.DocInfoRecdIsMarkedForDeletion as xfeld )                            as DocInfoRecdIsDeleted,

      // Administrative Facet

      @UI.fieldGroup:[{position: 10,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
      Document.CreatedByUser                                                               as CreatedByUser,

      @UI.fieldGroup:[{position: 20,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
      @ObjectModel.text.element:  [ 'ResponsiblePersonFullName' ]
      Document.ResponsiblePersonName                                                       as ResponsiblePersonName,

      Document._UserDetails.UserDescription                                                as ResponsiblePersonFullName,

      @ObjectModel.text.element:  [ 'LastChangedByUserFullName' ]
      @UI.fieldGroup:[{position: 30,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
      Document.LastChangedByUser                                                           as LastChangedByUser,

      @ObjectModel.readOnly: true
      Document._ChangedUser.UserDescription                                                as LastChangedByUserFullName,

      @UI.fieldGroup:[{position: 40,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
      Document.CreationDateTime                                                            as CreationDateTime,

      @UI.fieldGroup:[{position: 50,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
      Document.ChangedDateTime                                                             as ChangedDateTime,

      Document.AuthorizationGroup                                                                                as AuthorizationGroup,

      Document._ChangedUser,
      Document._UserDetails,
      Document._DocType,
      Document._Indicator,
      Document._DocStatus,


      @ObjectModel.association.type:  #TO_COMPOSITION_CHILD
      _Desc,

      _DocumentTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_DOCUMENTINFORECORDDESCTP",
"I_DOCUMENTINFORECORD",
"I_DOCUMENTINFORECORDDOCSTATUS",
"I_DOCUMENTINFORECORDDOCSTATUST",
"I_DOCUMENTINFORECORDDOCTYPE",
"I_DOCUMENTINFORECORDDOCTYPET",
"I_USER"
],
"ASSOCIATED":
[
"C_DOCUMENTINFORECORDDESCTP",
"I_DOCUMENTINFORECORDDOCSTATUS",
"I_DOCUMENTINFORECORDDOCTYPE",
"I_DOCUMENTINFORECORDDOCTYPET",
"I_DOCUMENTINFORECORDINDSTS",
"I_USER"
],
"BASE":
[
"I_DOCUMENTINFORECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/