C_CharacteristicDocument

@AbapCatalog.sqlViewName: 'CINSPCHARDOC'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Characteristic Document of DMS'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #M,
    serviceQuality: #C
}
define view C_CharacteristicDocument
  as select from    I_DocumentInfoRecordObjectLink     as _DirObjectLinks
    left outer join I_DocumentInfoRecordAttachment     as _DirOriginals on _DirObjectLinks.DocumentInfoRecordDocType = _DirOriginals.DocumentInfoRecordDocType
                                                                 and _DirObjectLinks.DocumentInfoRecordDocNumber     = _DirOriginals.DocumentInfoRecordDocNumber
                                                                 and _DirObjectLinks.DocumentInfoRecordDocPart       = _DirOriginals.DocumentInfoRecordDocPart
                                                                 and _DirObjectLinks.DocumentInfoRecordDocVersion    = _DirOriginals.DocumentInfoRecordDocVersion
    left outer join I_DocumentInfoRecord        as _DocInfoRecd  on  _DirObjectLinks.DocumentInfoRecordDocType       = _DocInfoRecd.DocumentInfoRecordDocType
                                                                 and _DirObjectLinks.DocumentInfoRecordDocNumber     = _DocInfoRecd.DocumentInfoRecordDocNumber
                                                                 and _DirObjectLinks.DocumentInfoRecordDocPart       = _DocInfoRecd.DocumentInfoRecordDocPart
                                                                 and _DirObjectLinks.DocumentInfoRecordDocVersion    = _DocInfoRecd.DocumentInfoRecordDocVersion
    left outer join I_DocumentInfoRecordDocStatus as _DocStatus  on  _DocInfoRecd.InternalDocumentStatus             = _DocStatus.InternalDocumentStatus
                                                                 and _DocInfoRecd.DocumentInfoRecordDocType          = _DocStatus.DocumentInfoRecordDocType

{
  key _DirObjectLinks.DocumentInfoRecordDocType,
  key _DirObjectLinks.DocumentInfoRecordDocNumber,
  key _DirObjectLinks.DocumentInfoRecordDocPart,
  key _DirObjectLinks.DocumentInfoRecordDocVersion,
  key _DirObjectLinks.LinkedSAPObjectKey,
  
// linked SAP object is needed for authority check - attention, if the where clause will be extended

// to handle different linked sap objects this field should be switch to a key field

      @Consumption.hidden: true
      _DirObjectLinks.LinkedSAPObject,  
  
      _DirOriginals.FileName,
      _DirOriginals.WorkstationApplication,
      _DirOriginals.FileSize,
      _DirOriginals.StorageCategory,
      _DirOriginals.PhysicalDocument,
      _DocInfoRecd.CreatedByUser,
      _DocInfoRecd.CreationDateTime,
      _DocInfoRecd.LastChangedByUser,
      _DocInfoRecd.ChangedDateTime,
      
// internal document status is needed for authority check

      @Consumption.hidden: true
      _DocInfoRecd.InternalDocumentStatus,      
      
      _DocStatus._Text[1:Language = $session.system_language].ExternalDocumentStatus,
      _DocStatus._Text[1:Language = $session.system_language].DocumentStatusName,
      _DirObjectLinks._Text[1:Language = $session.system_language].ObjectDescription,
       
      cast ( ' ' as abap.sstring( 1333 ) ) as     DocumentURL
}
where _DirObjectLinks.LinkedSAPObject = 'QMTBDOC'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DOCUMENTINFORECORD",
"I_DOCUMENTINFORECORDATTACHMENT",
"I_DOCUMENTINFORECORDDOCSTATUS",
"I_DOCUMENTINFORECORDDOCSTATUST",
"I_DOCUMENTINFORECORDOBJECTLINK",
"I_DOCUMENTINFORECORDOBJLINKT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/