I_EngSnpshtRefDoc

@AbapCatalog.sqlViewName: 'IENGSNPREFDOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #L}
@EndUserText.label: 'Engineering Snapshot Ref Obj Document'
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_EngSnpshtRefDoc
  as select from I_EngSnpshtObjRef    as EngSnpshtObjRef
    inner join   I_EngSnpshtHdr       as EngSnpshtHdr       on EngSnpshtObjRef.EngSnapshotUUID = EngSnpshtHdr.EngSnapshotUUID
    inner join   I_DocumentInfoRecord as DocumentInfoRecord on  EngSnpshtObjRef.EngSnpshtRefKey1 = DocumentInfoRecord.DocumentInfoRecordDocType
                                                            and EngSnpshtObjRef.EngSnpshtRefKey2 = DocumentInfoRecord.DocumentInfoRecordDocNumber
                                                            and EngSnpshtObjRef.EngSnpshtRefKey3 = DocumentInfoRecord.DocumentInfoRecordDocPart
                                                            and EngSnpshtObjRef.EngSnpshtRefKey4 = DocumentInfoRecord.DocumentInfoRecordDocVersion
  association [0..1] to I_DocumentInfoRecordDocStatus as _DocStatus                on  $projection.DocumentType           = _DocStatus.DocumentInfoRecordDocType
                                                                                   and $projection.InternalDocumentStatus = _DocStatus.InternalDocumentStatus
  association [0..1] to I_DocumentInfoRecordDocPrt    as _DocumentInfoRecordDocPrt on  $projection.DocumentType       = _DocumentInfoRecordDocPrt.DocumentInfoRecordDocType
                                                                                   and $projection.DocumentInfoRecord = _DocumentInfoRecordDocPrt.DocumentInfoRecordDocNumber
                                                                                   and $projection.DocumentPart       = _DocumentInfoRecordDocPrt.DocumentInfoRecordDocPart
                                                                                   and $projection.DocumentVersion    = _DocumentInfoRecordDocPrt.DocumentInfoRecordDocVersion
{
  key EngSnpshtObjRef.EngSnapshotRefUUID,
  key DocumentInfoRecord.DocumentInfoRecordDocType    as DocumentType,
  key DocumentInfoRecord.DocumentInfoRecordDocNumber  as DocumentInfoRecord,
  key DocumentInfoRecord.DocumentInfoRecordDocPart    as DocumentPart,
  key DocumentInfoRecord.DocumentInfoRecordDocVersion as DocumentVersion,
      EngSnpshtObjRef.EngSnapshotUUID,
      EngSnpshtHdr.EngSnapshotID,
      EngSnpshtHdr.EngSnpshtRevisionNumber,
      EngSnpshtObjRef.EngSnpshtRefType,
      InternalDocumentStatus,
      @Semantics.user.createdBy: true
      EngSnpshtObjRef.CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      EngSnpshtObjRef.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      EngSnpshtObjRef.LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      EngSnpshtObjRef.LastChangeDateTime,
      _DocumentInfoRecordDocPrt.DocumentDescription,
      _DocType,
      _DocNumber,
      _DocVersion,
      _DocStatus
}
where
  (
       EngSnpshtObjRef.EngSnpshtRefType                  = 'DOC'
    or EngSnpshtObjRef.EngSnpshtRefType                  = 'VDOC'
    or EngSnpshtObjRef.EngSnpshtRefType                  = 'MPD'
  )
  and  DocumentInfoRecord.DocInfoRecdIsMarkedForDeletion = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DOCUMENTINFORECORD",
"I_DOCUMENTINFORECORDDOCPRT",
"I_ENGSNPSHTHDR",
"I_ENGSNPSHTOBJREF"
],
"ASSOCIATED":
[
"I_DOCUMENTINFORECORDDOCNUMBER",
"I_DOCUMENTINFORECORDDOCPRT",
"I_DOCUMENTINFORECORDDOCSTATUS",
"I_DOCUMENTINFORECORDDOCTYPE",
"I_DOCUMENTINFORECORDDOCVERSION"
],
"BASE":
[
"I_DOCUMENTINFORECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/