I_ChangeDocumentItem

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'ICHANGEDOCITEM'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Change document items'

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@VDM.viewType: #BASIC

define view I_ChangeDocumentItem
  as select from cdpos
  association [0..1] to I_ChangeDocument as _ChangeDocument 
                     on  $projection.ChangeDocObjectClass = _ChangeDocument.ChangeDocObjectClass
                     and $projection.ChangeDocObject      = _ChangeDocument.ChangeDocObject
                     and $projection.ChangeDocument       = _ChangeDocument.ChangeDocument
                     
  association [0..1] to I_ChangeDocLongTableKey as _ChangeDocLongTableKey 
                     on $projection.ChangeDocTableKey = _ChangeDocLongTableKey.ChangeDocKeyGuid
                     
  association [0..1] to I_ChangeDocumentItemExtension as _ChangeDocumentItemExtension 
                     on $projection.ChangeDocTableKey = _ChangeDocumentItemExtension.ChangeDocKeyGuid

  association [0..1] to I_ChangeDocFieldNames as _FieldTextDDIC 
                     on  $projection.DatabaseTable               = _FieldTextDDIC.DatabaseTable
                     and $projection.ChangeDocDatabaseTableField = _FieldTextDDIC.Value
                     and _FieldTextDDIC.Language                 = $session.system_language                                                                                                          

  association [0..1] to I_ChangeDocFieldText as _FieldTextView 
                     on  $projection.DatabaseTable               = _FieldTextView.DatabaseTableName
                     and $projection.ChangeDocDatabaseTableField = _FieldTextView.FieldName
                     and _FieldTextView.Language                 = $session.system_language                                                                                                          

  association [0..1] to I_ChangeDocFieldLabel as _FieldTextLabel 
                     on  $projection.DatabaseTable               = _FieldTextLabel.DatabaseTableName
                     and $projection.ChangeDocDatabaseTableField = _FieldTextLabel.FieldName
                     and _FieldTextLabel.Language                = $session.system_language                                                                                                          

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/ 
  association [0..1] to I_ChangeDocViewText as _FieldTextReplace 
                     on  $projection.ChangeDocObjectClass        = _FieldTextReplace.ObjectClass
                     and $projection.DatabaseTable               = _FieldTextReplace.DatabaseTable
                     and $projection.ChangeDocDatabaseTableField = _FieldTextReplace.Fieldname
                     and _FieldTextReplace.TextType              = 'f'
                     
  association [0..1] to I_ChangeDocTableNames as _TableTextDDIC 
                     on  $projection.DatabaseTable = _TableTextDDIC.Value
                     and _TableTextDDIC.Language   = $session.system_language        
                     
  association [0..1] to I_ChangeDocTableText as _TableTextView 
                     on  $projection.DatabaseTable = _TableTextView.CDSViewName
                     and _TableTextView.Language   = $session.system_language        
                                                                           
{

  key cdpos.objectid      as ChangeDocObject,
  key cdpos.objectclas    as ChangeDocObjectClass,

  key cdpos.changenr      as ChangeDocument,
  key cdpos.tabname       as DatabaseTable,
  key cdpos.tabkey        as ChangeDocTableKey,
  key cdpos.fname         as ChangeDocDatabaseTableField,
  key cdpos.chngind       as ChangeDocItemChangeType,

      cast ( cdpos.unit_old as cdunito preserving type ) as ChangeDocPreviousUnit,
      cast ( cdpos.unit_new as cdunitn preserving type ) as ChangeDocNewUnit,
      cast ( cdpos.cuky_old as cdcukyo preserving type ) as ChangeDocPreviousCurrency,
      cast ( cdpos.cuky_new as cdcukyn preserving type ) as ChangeDocNewCurrency,
      cdpos.value_new     as ChangeDocNewFieldValue,
      cdpos.value_old     as ChangeDocPreviousFieldValue,
//      cdpos.text_case     as ChangeDocTextIsChanged,


      case 
        when cdpos.text_case = 'X'
          then cdpos.text_case
        else cast ( ' ' as cdxfeld preserving type )
      end as ChangeDocTextIsChanged,
      _ChangeDocument,
      _ChangeDocLongTableKey,
      _ChangeDocumentItemExtension,
      _FieldTextDDIC,
      _FieldTextView,
      _FieldTextLabel,
      _TableTextView,
      _TableTextDDIC,
      _FieldTextReplace
} 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CDPOS"
],
"ASSOCIATED":
[
"I_CHANGEDOCFIELDLABEL",
"I_CHANGEDOCFIELDNAMES",
"I_CHANGEDOCFIELDTEXT",
"I_CHANGEDOCLONGTABLEKEY",
"I_CHANGEDOCTABLENAMES",
"I_CHANGEDOCTABLETEXT",
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEMEXTENSION",
"I_CHANGEDOCVIEWTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/