C_GRC_CustCoCodeChangeLog

@AbapCatalog.sqlViewName: 'CGRCCUSMSTRCCCHG'
@EndUserText.label: 'Customer company code change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
define view C_GRC_CustCoCodeChangeLog
  as select from I_ChangeDocumentItem
    inner join   I_CustomerCompany on  I_ChangeDocumentItem.ChangeDocObject = I_CustomerCompany.Customer
                                   and I_CustomerCompany.CompanyCode        = right(
      I_ChangeDocumentItem.ChangeDocTableKey, 4
    )
{
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_Customer_VH',
                     element: 'Customer' }
        }]
      @ObjectModel.foreignKey.association: '_Customer'  
  key I_CustomerCompany.Customer,
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
       @ObjectModel.foreignKey.association: '_CompanyCode'
  key I_CustomerCompany.CompanyCode,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,

      I_CustomerCompany._Customer.CustomerName,
      I_CustomerCompany._Customer.CustomerAccountGroup,
      I_CustomerCompany._Customer.CreatedByUser,
      I_CustomerCompany._Customer.CreationDate,
      I_CustomerCompany._Customer.IsOneTimeAccount,
      I_CustomerCompany._Customer.IsBusinessPurposeCompleted,
      I_CustomerCompany._Customer.AuthorizationGroup,
      I_CustomerCompany._Customer.CityName,
      I_CustomerCompany._Customer.Country,
      @ObjectModel: { foreignKey.association: '_PaymentBlockValueHelp' }
      @ObjectModel.text.association: '_PaymentBlockingReasonText'
      I_CustomerCompany.PaymentBlockingReason,
      I_CustomerCompany.PaymentTerms,
      I_CustomerCompany.CustomerSupplierClearingIsUsed,
      I_CustomerCompany.PaymentMethodsList,
      I_CustomerCompany.DeletionIndicator,
      I_CustomerCompany.CreditMemoPaymentTerms,
      I_CustomerCompany.CustPreviousMasterRecordNumber,
      I_CustomerCompany.SupplierReleaseGroup,
      I_CustomerCompany.CustomerPaymentBlockingReason,
      I_CustomerCompany.DeletionIsBlocked,
      I_CustomerCompany.PaymentClearingGroup,

      I_ChangeDocumentItem.ChangeDocObjectClass,
      I_ChangeDocumentItem.DatabaseTable,

      I_CustomerCompany._Customer,
      I_CustomerCompany._CompanyCode,
      I_CustomerCompany._PaymentBlockValueHelp,
      I_CustomerCompany._PaymentBlockingReasonText

}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'DEBI'
  and I_ChangeDocumentItem.DatabaseTable        = 'KNB1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_CUSTOMER",
"I_CUSTOMERCOMPANY"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_PAYMENTBLOCKINGREASON",
"I_PAYMENTBLOCKINGREASONTEXT"
],
"BASE":
[
"I_CUSTOMERCOMPANY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/