C_GRC_SuplrCoCodeChangeLog

@AbapCatalog.sqlViewName: 'CGRCSUPMSTRCCCHG'
@EndUserText.label: 'Supplier company code change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
define view C_GRC_SuplrCoCodeChangeLog
  as select from I_ChangeDocumentItem
    inner join   I_SupplierCompany on  I_ChangeDocumentItem.ChangeDocObject = I_SupplierCompany.Supplier
                                   and I_SupplierCompany.CompanyCode        = right(
      I_ChangeDocumentItem.ChangeDocTableKey, 4
    )
{
  key I_SupplierCompany.Supplier,
  key I_SupplierCompany.CompanyCode,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,
      
      I_SupplierCompany._Supplier.SupplierName,
      I_SupplierCompany._Supplier.SupplierAccountGroup,
      I_SupplierCompany._Supplier.CreatedByUser,
      I_SupplierCompany._Supplier.CreationDate,
      I_SupplierCompany._Supplier.IsOneTimeAccount,
      I_SupplierCompany.SupplierIsBlockedForPosting,
      I_SupplierCompany.IsBusinessPurposeCompleted,
      I_SupplierCompany._Supplier.PurchasingIsBlocked,      
      I_SupplierCompany._Supplier.CityName,
      I_SupplierCompany._Supplier.Country,
      I_SupplierCompany.AuthorizationGroup,
      I_SupplierCompany.PaymentBlockingReason,
      I_SupplierCompany.PaymentMethodsList,      
      I_SupplierCompany.ClearCustomerSupplier,
      I_SupplierCompany.IsDoubleInvoice,
      I_SupplierCompany.CustomerSupplierClearingIsUsed,
      I_SupplierCompany.ReconciliationAccount,
      I_SupplierCompany.AlternativePayee,
      I_SupplierCompany.DeletionIndicator,
      I_SupplierCompany.SupplierReleaseGroup,
      I_SupplierCompany.CreditMemoPaymentTerms,
      I_SupplierCompany.PaymentClearingGroup,      

      I_SupplierCompany._Supplier,
      I_SupplierCompany._CompanyCode,

      I_ChangeDocumentItem.ChangeDocObjectClass,
      I_ChangeDocumentItem.DatabaseTable

}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'KRED'
  and I_ChangeDocumentItem.DatabaseTable        = 'LFB1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_SUPPLIER",
"I_SUPPLIERCOMPANY"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_SUPPLIER"
],
"BASE":
[
"I_SUPPLIERCOMPANY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/