C_GLAcctInCoCodeChangeLog

@AbapCatalog.sqlViewName: 'CGRCGLACCTCCCHG'
@EndUserText.label: 'GL account in company code change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
define view C_GLAcctInCoCodeChangeLog
  as select from I_ChangeDocumentItem
    inner join   I_GLAccountInCompanyCode on  I_GLAccountInCompanyCode.GLAccount   = substring(
      I_ChangeDocumentItem.ChangeDocObject, 5, 10
    )
                                          and I_GLAccountInCompanyCode.CompanyCode = right(
      I_ChangeDocumentItem.ChangeDocObject, 4
    )
{
  key I_GLAccountInCompanyCode.GLAccount,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key I_GLAccountInCompanyCode.CompanyCode,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,

      I_GLAccountInCompanyCode.AuthorizationGroup,
      I_GLAccountInCompanyCode.AccountingClerk,
      I_GLAccountInCompanyCode.LastInterestCalcRunDate,
      I_GLAccountInCompanyCode.CreationDate,
      I_GLAccountInCompanyCode.CreatedByUser,
      I_GLAccountInCompanyCode.PlanningLevel,
      I_GLAccountInCompanyCode.HouseBank,
      I_GLAccountInCompanyCode.HouseBankAccount,
      I_GLAccountInCompanyCode.ExchRateDifferencesAccountDetn,
      @ObjectModel.foreignKey.association: '_Reconciliationaccttype'
      I_GLAccountInCompanyCode.ReconciliationAccountType,
      @ObjectModel.foreignKey.association: '_TaxCategory'
      I_GLAccountInCompanyCode.TaxCategory,
      I_GLAccountInCompanyCode.InterestCalculationCode,
      I_GLAccountInCompanyCode.GLAccountCurrency,
      I_GLAccountInCompanyCode.ReconciliationAcctIsChangeable,
      I_GLAccountInCompanyCode.IsManagedExternally,
      I_GLAccountInCompanyCode.IsAutomaticallyPosted,
      I_GLAccountInCompanyCode.LineItemDisplayIsEnabled,
      I_GLAccountInCompanyCode.SupplementIsAllowed,
      I_GLAccountInCompanyCode.IsOpenItemManaged,
      I_GLAccountInCompanyCode.InterestCalculationDate,
      I_GLAccountInCompanyCode.IntrstCalcFrequencyInMonths,
      I_GLAccountInCompanyCode.AcctgDocItmDisplaySequenceRule,
      I_GLAccountInCompanyCode.AlternativeGLAccount,
      I_GLAccountInCompanyCode.JointVentureRecoveryCode,
      I_GLAccountInCompanyCode.TaxCodeIsRequired,
      I_GLAccountInCompanyCode.BalanceHasLocalCurrency,
      I_GLAccountInCompanyCode.ValuationGroup,
      I_GLAccountInCompanyCode.APARToleranceGroup,
      I_GLAccountInCompanyCode.AccountIsBlockedForPosting,
      I_GLAccountInCompanyCode.AccountIsMarkedForDeletion,
      I_GLAccountInCompanyCode.ClearingIsLedgerGroupSpecific,
      I_GLAccountInCompanyCode.CashPlanningGroup,
      I_GLAccountInCompanyCode.IsCashFlowAccount,
      I_GLAccountInCompanyCode.GLAcctInflationKey,
      I_GLAccountInCompanyCode.FieldStatusGroup,
      I_GLAccountInCompanyCode.MultiCurrencyAccountingCode,
      I_GLAccountInCompanyCode.IsExtendedOpenItemManaged,

      I_GLAccountInCompanyCode._CompanyCode,
      I_GLAccountInCompanyCode._Reconciliationaccttype,
      I_GLAccountInCompanyCode._TaxCategory,

      I_ChangeDocumentItem.ChangeDocObjectClass,
      I_ChangeDocumentItem.DatabaseTable

}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'SACH'
  and I_ChangeDocumentItem.DatabaseTable        = 'SKB1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_GLACCOUNTINCOMPANYCODE"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_RECONCILIATIONACCTTYPE",
"I_TAXCATEGORY"
],
"BASE":
[
"I_GLACCOUNTINCOMPANYCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/