@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
usageType.dataClass: #MIXED,
usageType.serviceQuality: #C,
usageType.sizeCategory: #L
}
@EndUserText.label: 'CentralRequestForQuotation Process Flow'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'CCNTRLREQPROCFL'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
define view C_CntrlReqForQtnProcessFlow
as select from R_CentralRequestForQuotation
{
key cast( CentralRequestForQuotation as char40) as PrecedingDocument,
key cast(cast( PurchasingDocumentCategory as char1 ) as char4 ) as PrecedingDocumentCategory,
key cast(' ' as char40 ) as SubsequentDocument,
key cast(' ' as char4) as SubsequentDocumentCategory,
key CentralRequestForQuotation,
PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
PurchasingGroup,
PurchasingOrganization,
IsEndOfPurposeBlocked,
cast('' as purgdocnodeuniqueid) as PurchasingDocumentUniqueID
}
//Purchase Requisition
union all select distinct from R_CentralReqForQuotationItem as _CentralReqForQuotationItem
inner join R_CentralRFQItemDistribution as _CentralRFQItemDistribution on _CentralRFQItemDistribution.CentralRequestForQuotation = _CentralReqForQuotationItem.CentralRequestForQuotation and
_CentralRFQItemDistribution.CentralRequestForQuotationItem = _CentralReqForQuotationItem.CentralRequestForQuotationItem
inner join I_PrmtHbRpldPurchaseReqnItem as _PrmtHbRpldPurchaseReqnItem on _PrmtHbRpldPurchaseReqnItem.ProcmtHubPurchaseRequisition = _CentralRFQItemDistribution.ProcmtHubPurchaseRequisition and
_PrmtHbRpldPurchaseReqnItem.ProcmtHubPurRequisitionItem = _CentralRFQItemDistribution.ProcmtHubPurRequisitionItem and
_PrmtHbRpldPurchaseReqnItem.ProcurementHubSourceSystem = _CentralRFQItemDistribution.ProcurementHubSourceSystem
{
key _PrmtHbRpldPurchaseReqnItem.PurchasingDocumentUniqueID as PrecedingDocument,
key cast('B' as char4) as PrecedingDocumentCategory,
key _CentralReqForQuotationItem.CentralRequestForQuotation as SubsequentDocument,
key _CentralReqForQuotationItem._CentralRequestForQuotation.PurchasingDocumentCategory as SubsequentDocumentCategory,
key _CentralReqForQuotationItem.CentralRequestForQuotation,
_CentralReqForQuotationItem._CentralRequestForQuotation.PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
_CentralReqForQuotationItem._CentralRequestForQuotation.PurchasingGroup,
_CentralReqForQuotationItem._CentralRequestForQuotation.PurchasingOrganization,
_CentralReqForQuotationItem._CentralRequestForQuotation.IsEndOfPurposeBlocked,
cast('' as purgdocnodeuniqueid) as PurchasingDocumentUniqueID
}
// Ariba sourcing project
union all select from R_CentralRequestForQuotation as _CentralRequestForQuotation
inner join R_CntrlRFQSrcgReqExtDocLink as _CntrlRFQSrcgReqExtDocLink on _CntrlRFQSrcgReqExtDocLink.PurchasingDocumentUniqueID = _CentralRequestForQuotation.CentralRequestForQuotation
{
key _CentralRequestForQuotation.CentralRequestForQuotation as PrecedingDocument,
key cast( _CentralRequestForQuotation.PurchasingDocumentCategory as char4 ) as PrecedingDocumentCategory,
key _CntrlRFQSrcgReqExtDocLink.ExternalPurchasingDocumentID as SubsequentDocument,
key cast('Z' as bstyp) as SubsequentDocumentCategory,
key _CentralRequestForQuotation.CentralRequestForQuotation,
_CentralRequestForQuotation.PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
_CentralRequestForQuotation.PurchasingGroup,
_CentralRequestForQuotation.PurchasingOrganization,
_CentralRequestForQuotation.IsEndOfPurposeBlocked,
cast('' as purgdocnodeuniqueid) as PurchasingDocumentUniqueID
}
// Central supplier qoutation with Ariba sourcing
union all select from R_CentralRequestForQuotation as _CentralRequestForQuotation
inner join R_CntrlRFQSrcgReqExtDocLink as _CntrlRFQSrcgReqExtDocLink on _CntrlRFQSrcgReqExtDocLink.PurchasingDocumentUniqueID = _CentralRequestForQuotation.CentralRequestForQuotation
inner join R_CentralSupplierQuotation as _CentralSupplierQuotation on _CentralSupplierQuotation.CentralRequestForQuotation = _CntrlRFQSrcgReqExtDocLink.PurchasingDocumentUniqueID
{
key _CntrlRFQSrcgReqExtDocLink.ExternalPurchasingDocumentID as PrecedingDocument,
key cast('Z' as char4) as PrecedingDocumentCategory,
key _CentralSupplierQuotation.CentralSupplierQuotation as SubsequentDocument,
key _CentralSupplierQuotation.PurchasingDocumentCategory as SubsequentDocumentCategory,
key _CentralRequestForQuotation.CentralRequestForQuotation,
_CentralRequestForQuotation.PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
_CentralRequestForQuotation.PurchasingGroup,
_CentralRequestForQuotation.PurchasingOrganization,
_CentralRequestForQuotation.IsEndOfPurposeBlocked,
cast('' as purgdocnodeuniqueid) as PurchasingDocumentUniqueID
} where _CntrlRFQSrcgReqExtDocLink.ExternalPurchasingDocumentID not like 'NO_SR_ID%'
// Central Supplier qoutation without ariba sourcing
union all select from R_CentralRequestForQuotation as _CentralRequestForQuotation
inner join R_CentralSupplierQuotation as _CentralSupplierQuotation on _CentralSupplierQuotation.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation
left outer to many join R_CntrlRFQSrcgReqExtDocLink as _CntrlRFQSrcgReqExtDocLink on _CntrlRFQSrcgReqExtDocLink.PurchasingDocumentUniqueID = _CentralRequestForQuotation.CentralRequestForQuotation
{
//Key
key _CentralRequestForQuotation.CentralRequestForQuotation as PrecedingDocument,
key cast(_CentralRequestForQuotation.PurchasingDocumentCategory as char4 ) as PrecedingDocumentCategory,
key _CentralSupplierQuotation.CentralSupplierQuotation as SubsequentDocument,
key _CentralSupplierQuotation.PurchasingDocumentCategory as SubsequentDocumentCategory,
key _CentralRequestForQuotation.CentralRequestForQuotation,
_CentralRequestForQuotation.PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
_CentralRequestForQuotation.PurchasingGroup,
_CentralRequestForQuotation.PurchasingOrganization,
_CentralRequestForQuotation.IsEndOfPurposeBlocked,
_CntrlRFQSrcgReqExtDocLink.PurchasingDocumentUniqueID
} where _CntrlRFQSrcgReqExtDocLink.PurchasingDocumentUniqueID is null
//Purchase orders
union all select distinct from R_CentralRequestForQuotation as _CentralRequestForQuotation
inner join R_CentralSupplierQuotation as _CentralSupplierQuotation on _CentralSupplierQuotation.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation
inner join I_CntrlSuplrQtnExtDocumentLink as _CntrlSuplrQtnExtDocumentLink on _CntrlSuplrQtnExtDocumentLink.CentralSupplierQuotation = _CentralSupplierQuotation.CentralSupplierQuotation
{
key _CentralSupplierQuotation.CentralSupplierQuotation as PrecedingDocument,
key cast(_CentralSupplierQuotation.PurchasingDocumentCategory as char4 ) as PrecedingDocumentCategory,
key _CntrlSuplrQtnExtDocumentLink.ExternalPurchasingDocumentID as SubsequentDocument,
key cast('F' as bstyp) as SubsequentDocumentCategory,
key _CentralRequestForQuotation.CentralRequestForQuotation,
_CentralRequestForQuotation.PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
_CentralRequestForQuotation.PurchasingGroup,
_CentralRequestForQuotation.PurchasingOrganization,
_CentralRequestForQuotation.IsEndOfPurposeBlocked,
cast('' as purgdocnodeuniqueid) as PurchasingDocumentUniqueID
}
// Purchase Contract
union all select distinct from R_CentralRequestForQuotation as _CentralRequestForQuotation
inner join R_CentralSupplierQuotation as _CentralSupplierQuotation on _CentralSupplierQuotation.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation
inner join I_CntrlPurContrDistribution as _CntrlPurContrDistribution on _CntrlPurContrDistribution.ProcmtHubPredecessorDocument = _CentralSupplierQuotation.CentralSupplierQuotation
{
key _CentralSupplierQuotation.CentralSupplierQuotation as PrecedingDocument,
key cast( _CentralSupplierQuotation.PurchasingDocumentCategory as char4 ) as PrecedingDocumentCategory,
key _CntrlPurContrDistribution.CentralPurchaseContract as SubsequentDocument,
key cast('C' as bstyp) as SubsequentDocumentCategory,
key _CentralRequestForQuotation.CentralRequestForQuotation,
_CentralRequestForQuotation.PurchasingDocumentType,
cast('' as fis_bukrs) as CompanyCode,
cast('' as fis_gjahr) as FiscalYear,
_CentralRequestForQuotation.PurchasingGroup,
_CentralRequestForQuotation.PurchasingOrganization,
_CentralRequestForQuotation.IsEndOfPurposeBlocked,
cast('' as purgdocnodeuniqueid) as PurchasingDocumentUniqueID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNTRLPURCONTRDISTRIBUTION",
"I_CNTRLSUPLRQTNEXTDOCUMENTLINK",
"I_PRMTHBRPLDPURCHASEREQNITEM",
"R_CENTRALREQFORQUOTATIONITEM",
"R_CENTRALREQUESTFORQUOTATION",
"R_CENTRALRFQITEMDISTRIBUTION",
"R_CENTRALSUPPLIERQUOTATION",
"R_CNTRLRFQSRCGREQEXTDOCLINK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/