I_CNTRLPURCONTRDISTRIBUTION

CDS View

Central PC Distribution Basic View

I_CNTRLPURCONTRDISTRIBUTION is a CDS View in S/4HANA. Central PC Distribution Basic View. It contains 9 fields. 21 CDS views read from this table.

Used by 21 CDS view(s) 9 fields

CDS Views using this table (21)

ViewTypeJoinVDMDescription
A_CntrlPurContrHdrDistribution view from COMPOSITE Header Distribution
A_CntrlPurContrItmDistribution view from COMPOSITE Item Distribution
C_CntrlPurContrHdrDistr view from CONSUMPTION Central Contract Header Distribution
C_CntrlPurContrItmDistr view from CONSUMPTION Central Contract Item Distribution View
C_CntrlReqForQtnProcessFlow view inner CONSUMPTION CentralRequestForQuotation Process Flow
C_CPurConHierHdrDistrMassUpdt view from CONSUMPTION HCTR Header Distribution Mass Update
C_CPurConHierItmDistrMassUpdt view from CONSUMPTION HCTR Item Distribution Mass Update
I_CePuCoDistributedContrTP view from TRANSACTIONAL Distributed OA for Cntrl Pur Contr - TP
I_CntrlPurContrDistributionTP view from TRANSACTIONAL Central PC Distribution BO View
I_CntrlPurContrHdrDistrTP view from TRANSACTIONAL BO View for Header Distribution in Central Purchase Contract
I_CntrlPurContrHierDistrOvwTP view from TRANSACTIONAL Transactional View for CCTR Hierarchy Distribution Overview
P_Cctr_Curr_Conv_Distr view from COMPOSITE
P_CentralPurContrDistrAddress view from COMPOSITE
P_CntrlContrRelDocnValues view inner CONSUMPTION
P_CntrlPurContractItems view inner CONSUMPTION Central Purchase Contract Items
P_CntrlPurContrItemMonitor1 view inner CONSUMPTION Central Purchase Contract Items
P_ContrHierItmDistrCnsmdVal view from COMPOSITE
P_CPurConHierHdrCnsmdVal view from COMPOSITE
P_UnusedPurCentralContract view inner CONSUMPTION Unused Central Purchase Contracts
R_CntrlPurContrHdrDistrTP view_entity from TRANSACTIONAL Cntrl PC Header Distribution
R_CntrlPurContrItemDistrTP view_entity from TRANSACTIONAL CCTR Item Distribution

Fields (9)

KeyField CDS FieldsUsed in Views
KEY CentralPurchaseContract CentralPurchaseContract,SubsequentDocument 4
KEY CentralPurchaseContractItem CentralPurchaseContractItem 3
KEY DistributionKey DistributionKey 5
DocumentCurrency ReleaseOrderCurrency 1
ItemDistributionStatus ItemDistributionStatus 1
OrderQuantityUnit ReleaseOrderItemQuantityUnit 1
ProcurementHubSourceSystem LogicalSystem 1
TargetAmount DistributionTargetAmount 1
TargetQuantity DistributionTargetQty,TargetQuantity 3 
@AbapCatalog.sqlViewName: 'ICNTRLPCONDSTR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Central PC Distribution Basic View'
@VDM.viewType : #BASIC

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED

define view I_CntrlPurContrDistribution
  as select from R_CntrlPurContrDistribution

  association [1..1] to I_CentralPurchaseContract      as _CentralPurchaseContract      on  _CentralPurchaseContract.CentralPurchaseContract = $projection.CentralPurchaseContract

  association [1..1] to I_CntrlPurchaseContractItem    as _CntrlPurchaseContractItem    on  $projection.CentralPurchaseContract     = _CntrlPurchaseContractItem.CentralPurchaseContract
                                                                                        and $projection.CentralPurchaseContractItem = _CntrlPurchaseContractItem.CentralPurchaseContractItem

  association [0..*] to I_CntrlPurchaseContractPartner as _CntrlPurchaseContractPartner on  $projection.CentralPurchaseContract     = _CntrlPurchaseContractPartner.CentralPurchaseContract
                                                                                        and $projection.CentralPurchaseContractItem = _CntrlPurchaseContractPartner.CentralPurchaseContractItem
                                                                                        and $projection.DistributionKey             = _CntrlPurchaseContractPartner.DistributionKey

  association [0..1] to I_CentralPurContrDistrAddress  as _CentralPurContrDistrAddress  on  _CentralPurContrDistrAddress.CentralPurchaseContract     = $projection.CentralPurchaseContract
                                                                                        and _CentralPurContrDistrAddress.CentralPurchaseContractItem = $projection.CentralPurchaseContractItem
                                                                                        and _CentralPurContrDistrAddress.DistributionKey             = $projection.DistributionKey


{
  key CentralPurchaseContract,
  key CentralPurchaseContractItem,
  key DistributionKey,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingOrganization,
      CompanyCode,
      Plant,
      LogicalSystem,
      DocumentCurrency,
      Currency,
      PurchasingGroup,
      StorageLocation,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      Material,
      MaterialGroup,
      CntrlPurContrDistributionPct,
      TargetQuantity,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TargetAmount,

      ExtContractForPurg,
      ExtContractItemForPurg,
      ExtContractItemDistrForPurg,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PurgDocItemDistributionStatus'
      PurgDocItemDistributionStatus                                    as ItemDistributionStatus,
       PurgDocItemDistributionStatus,
       
      //casting to bool, because of VDM checkmen.This is a known issue. Consumers should cast back to xfeld.

      cast(IsDeleted as bool)                                          as IsDeleted,
      OrderQuantityUnit,
      DistributionType,
      DistrResponseMessageUUID,
      
      //casting to bool, because of VDM checkmen.This is a known issue. Consumers should cast back to xfeld.

      cast(ItemDistributionIsRelevant as bool)                         as ItemDistributionIsRelevant, 
      ReferenceHeaderDistributionKey,
      
      //casting to bool, because of VDM checkmen.This is a known issue. Consumers should cast back to xfeld.

      cast(CntrlPurContrItmDistrIsBlocked  as mmpur_itemdistr_blocked) as CntrlPurContrItmDistrIsBlocked,
      CntrlPurContrDistributionLevel,
      ManualDeliveryAddressID,
      ProcmtHubDelivAddressTypeCode                                    as AddressType,
      ProcmtHubDelivAddressTypeCode,
      ProcurementHubSourceSystem,
      ExternalReferenceDocument,
      ExternalReferenceDocumentItem,
      ExternalRefDocCategory,
      PurchasingInfoRecordUpdateCode,
      ProcmtHubPredecessorDocument,
      ProcmtHubPredecessorDocItem,
      ProcmtHubPredecessorDocCat,
      ProcmtHubPurchaseRequisition,
      ProcmtHubPurRequisitionItem,
      SourceListIsUpdated,
      SourceListRestriction,
      SrceListResponseMsgUUID,
      SourceListChangeConfStatus,
      ProcmtHubCompanyCodeGroupingID,
      OutlineAgrmtItmIsBlocked,
      PurgDocItmBlkRsnCode,
      IncotermsClassification,
      IncotermsLocation1,
      ShippingInstruction,
      CntrlPurContrDistrTrggrDteTime,
      ProcmtHubSubcontractor,      
      ProcmtHubSuplrIsSubcontractor,
      ReferenceDeliveryAddressID,
      FormOfAddress,
      ProcmtHubBusinessPartnerName1,
      ProcmtHubBusinessPartnerName2,
      ProcmtHubBusinessPartnerName3,
      ProcmtHubBusinessPartnerName4,
      ProcmtHubStreetName,
      ProcmtHubHouseNumber,
      ProcmtHubPostalCode,
      ProcmtHubCityName,
      ProcmtHubCountry,
      ProcmtHubRegion,
      
      /* The fields with predecessor document information */
      ProcmtHubPrdcssrDocUUID, 
      ProcmtHubPrdcssrDocItemUUID,
      ProcmtHubPrdcssrDocObjType,
      ProcmtHubPrdcssrDocObjNodeType,     

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT ]
      _CentralPurchaseContract,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _CntrlPurchaseContractItem,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrlPurchaseContractPartner,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CentralPurContrDistrAddress

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_CNTRLPURCONTRDISTRIBUTION"
],
"ASSOCIATED":
[
"I_CENTRALPURCHASECONTRACT",
"I_CENTRALPURCONTRDISTRADDRESS",
"I_CNTRLPURCHASECONTRACTITEM",
"I_CNTRLPURCHASECONTRACTPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More