R_CENTRALRFQITEMDISTRIBUTION

@VDM.viewType : #BASIC
@EndUserText.label: 'Restricted View for Central RFQ Item Distribution'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK

@AbapCatalog.sqlViewName: 'RCNTRLRFQIDIS'
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

define view R_CentralRFQItemDistribution
  as select from ekpo_distr

  association [1..1] to R_CentralReqForQuotationItem as _CentralReqForQuotationItem on  $projection.CentralRequestForQuotation     = _CentralReqForQuotationItem.CentralRequestForQuotation
                                                                                    and $projection.CentralRequestForQuotationItem = _CentralReqForQuotationItem.CentralRequestForQuotationItem

  association [1..1] to R_CentralRequestForQuotation as _CentralRequestForQuotation on  $projection.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation

{
  key    purchasingdocument                                    as CentralRequestForQuotation,
  key    purchasingdocumentitem                                as CentralRequestForQuotationItem,
  key    ekpo_distr.distributionnumber                         as DistributionKey,
         ekpo_distr.purchasingdocumentcategory                 as PurchasingDocumentCategory,
         ekpo_distr.purchasingdocumenttype                     as PurchasingDocumentType,
         ekpo_distr.purchasingorganization                     as PurchasingOrganization,
         ekpo_distr.companycode                                as CompanyCode,
         ekpo_distr.plant                                      as Plant,
         ekpo_distr.logicalsystem                              as LogicalSystem,
         ekpo_distr.documentcurrency                           as DocumentCurrency,
         ekpo_distr.documentcurrency                           as Currency,
         ekpo_distr.purchasinggroup                            as PurchasingGroup,
         ekpo_distr.storagelocation                            as StorageLocation,
         ekpo_distr.paymentterms                               as PaymentTerms,
         ekpo_distr.cashdiscount1days                          as CashDiscount1Days,
         ekpo_distr.cashdiscount2days                          as CashDiscount2Days,
         ekpo_distr.netpaymentdays                             as NetPaymentDays,
         ekpo_distr.cashdiscount1percent                       as CashDiscount1Percent,
         ekpo_distr.cashdiscount2percent                       as CashDiscount2Percent,
         ekpo_distr.material                                   as Material,
         ekpo_distr.materialgroup                              as MaterialGroup,
         ekpo_distr.purchasingdocumentdistrpct                 as CntrlPurgDistributionInPercent,
         ekpo_distr.targetquantity                             as TargetQuantity,
         @Semantics.amount.currencyCode:'DocumentCurrency'
         ekpo_distr.targetvalue                                as TargetAmount,
         ekpo_distr.extcontractforpurg                         as ExtContractForPurg,
         ekpo_distr.extcontractitemforpurg                     as ExtContractItemForPurg,
         case
         when ekpo_distr.extcontractitemdistrstatus = '01' and ekpo_distr.extcontractforpurg <> ''
           then '04'
           else
             ekpo_distr.extcontractitemdistrstatus end         as PurgDocItemDistributionStatus,
         ekpo_distr.isdeleted                                  as PurgDocItmDistrLineDeltnCode,
         ekpo_distr.orderquantityunit                          as OrderQuantityUnit,
         ekpo_distr.distributiontype                           as DistributionType,
         ekpo_distr.responsemessageguid                        as DistrResponseMessageUUID,

         @VDM.lifecycle.status: #DEPRECATED
         @VDM.lifecycle.successor: 'PurgDocItemDistrRelevanceCode'
         ekpo_distr.itemdistributionisrelevant                 as ItemDistributionIsRelevant,
         ekpo_distr.itemdistributionisrelevant                 as PurgDocItemDistrRelevanceCode,
         ekpo_distr.referencedhdrdistrnumber                   as ReferenceHeaderDistributionKey,
         ekpo_distr.manualdeliveryaddressid                    as ManualDeliveryAddressID,
         cast ( ekpo_distr.deliveryaddresstype as bu_adrkind ) as AddressType,
         case
         when ekpo_distr.procurementhubsourcesystem is not initial
         then ekpo_distr.procurementhubsourcesystem
         else
         ekpo_distr.logicalsystem
          end                                                  as ProcurementHubSourceSystem,
         ekpo_distr.procmthubpurchaserequisition               as ProcmtHubPurchaseRequisition,
         ekpo_distr.procmthubpurrequisitionitem                as ProcmtHubPurRequisitionItem,
         ekpo_distr.purreqnreleasestatus                       as PurReqnReleaseStatus,

         _CentralReqForQuotationItem.NetPriceAmount            as NetPriceAmount,

         /* Associations */
         _CentralRequestForQuotation,
         _CentralReqForQuotationItem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_CENTRALREQFORQUOTATIONITEM",
"EKPO_DISTR"
],
"ASSOCIATED":
[
"R_CENTRALREQFORQUOTATIONITEM",
"R_CENTRALREQUESTFORQUOTATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/