R_CENTRALREQUESTFORQUOTATION

CDS View

Restricted View for Central Request For Quotation Header

R_CENTRALREQUESTFORQUOTATION is a CDS View in S/4HANA. Restricted View for Central Request For Quotation Header. It contains 52 fields. 9 CDS views read from this table.

Used by 9 CDS view(s) 52 fields

CDS Views using this table (9)

ViewTypeJoinVDMDescription
C_CentralRequestForQuotationVH view from CONSUMPTION Central Request For Quotation Value Help
C_CntrlReqForQtnProcessFlow view from CONSUMPTION CentralRequestForQuotation Process Flow
C_CntrlReqForQtnProcessFlow view union_all CONSUMPTION CentralRequestForQuotation Process Flow
C_CntrlRequestForQuotationInfo view from CONSUMPTION Consumption View for Central Request for Quotation Info
ESH_N_CNTRLREQUESTFORQUOTATION view from
I_CentralRequestForQuotation view from BASIC Central Request For Quotation Header
I_CentralRequestForQuotationTP view from TRANSACTIONAL Transactional processing view for Central RFQ Header
R_CentralRequestForQuotationTP view_entity from TRANSACTIONAL Central Request for Quotation
R_CntrlReqForQtanScheduleLine view inner BASIC Restricted View for Central RFQ Item Schedule Line

Fields (52)

KeyField CDS FieldsUsed in Views
KEY CentralRequestForQuotation CentralRequestForQuotation 4
_CompanyCode _CompanyCode 1
_CreatedByUser _CreatedByUser 1
_DocumentCurrency _DocumentCurrency 1
_FollowOnDocumentCategory _FollowOnDocumentCategory 1
_FollowOnDocumentType _FollowOnDocumentType 1
_IncotermsClassification _IncotermsClassification 1
_IncotermsVersion _IncotermsVersion 1
_Language _Language 1
_PaymentTerms _PaymentTerms 1
_PurchasingDocumentCategory _PurchasingDocumentCategory 1
_PurchasingDocumentType _PurchasingDocumentType 2
_PurchasingGroup _PurchasingGroup 1
_PurchasingOrganization _PurchasingOrganization 1
_RFQLifecycleStatus _RFQLifecycleStatus 1
_RFQType _RFQType 1
BindingPeriodValidityEndDate BindingPeriodValidityEndDate 1
CashDiscount1Days CashDiscount1Days 1
CashDiscount1Percent CashDiscount1Percent 1
CashDiscount2Days CashDiscount2Days 1
CashDiscount2Percent CashDiscount2Percent 1
CompanyCode CompanyCode 1
CorrespncInternalReference CorrespncInternalReference 1
CreatedByUser CreatedByUser 2
CreationDate CreationDate 1
DocumentCurrency DocumentCurrency 1
FollowOnDocumentCategory FollowOnDocumentCategory 1
IncotermsClassification IncotermsClassification 1
IncotermsLocation1 IncotermsLocation1 1
IncotermsLocation2 IncotermsLocation2 1
IncotermsTransferLocation IncotermsTransferLocation 1
IncotermsVersion IncotermsVersion 1
IsEndOfPurposeBlocked IsEndOfPurposeBlocked 3
Language Language 1
LastChangeDateTime LastChangeDateTime 1
LatestRegistrationDate LatestRegistrationDate 1
NetPaymentDays NetPaymentDays 1
PaymentTerms PaymentTerms 1
PurchasingDocumentCategory PurchasingDocumentCategory,RFQCategory 3
PurchasingDocumentDeletionCode PurchasingDocumentDeletionCode 1
PurchasingDocumentType PurchasingDocumentType,RFQType 4
PurchasingGroup PurchasingGroup 3
PurchasingOrganization PurchasingOrganization 3
PurContrValidityEndDate PurContrValidityEndDate 1
PurContrValidityStartDate PurContrValidityStartDate 1
PurgDocFollowOnDocumentType FollowOnDocumentType 1
QuotationEarliestSubmsnDate QuotationEarliestSubmsnDate 1
QuotationLatestSubmissionDate QuotationLatestSubmissionDate 2
RequestForQuotationName RequestForQuotationName 3
RFQLifecycleStatus RFQLifecycleStatus 2
RFQPublishingDate RFQPublishingDate 2
TargetAmount TargetAmount 1 
@VDM.viewType: #BASIC
@EndUserText.label: 'Restricted View for Central Request For Quotation Header'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'RCNTRLRFQHDR'
@AccessControl.privilegedAssociations: [ '_CreatedByUser' ]

@ObjectModel:{ representativeKey: 'CentralRequestForQuotation',
               semanticKey: 'CentralRequestForQuotation',
               usageType.dataClass: #TRANSACTIONAL,
               usageType.serviceQuality: #A,
               usageType.sizeCategory: #M }

define view R_CentralRequestForQuotation
  as select from R_PurchasingDocument

  association [1..*] to R_CentralReqForQuotationItem as _CentralReqForQuotationItem on  $projection.CentralRequestForQuotation = _CentralReqForQuotationItem.CentralRequestForQuotation

  association [1..*] to R_CntrlReqForQuotationBidder as _CntrlReqForQuotationBidder on  $projection.CentralRequestForQuotation = _CntrlReqForQuotationBidder.CentralRequestForQuotation

  association [0..1] to I_PurchasingDocumentType     as _FollowOnDocumentType       on  $projection.PurchasingDocumentCategory = _FollowOnDocumentType.PurchasingDocumentCategory
                                                                                    and $projection.PurchasingDocumentType     = _FollowOnDocumentType.PurchasingDocumentType

  association [0..1] to I_RequestForQuotationType    as _RFQType                    on  $projection.PurchasingDocumentType = _RFQType.RFQType

  association [0..1] to I_PurchasingDocumentCategory as _FollowOnDocumentCategory   on  $projection.FollowOnDocumentCategory = _FollowOnDocumentCategory.PurchasingDocumentCategory

  association [0..*] to R_CentralSupplierQuotation   as _CentralSupplierQuotation   on  $projection.CentralRequestForQuotation = _CentralSupplierQuotation.CentralRequestForQuotation

  association [0..1] to I_RFQLifecycleStatus         as _RFQLifecycleStatus         on  $projection.RFQLifecycleStatus = _RFQLifecycleStatus.RFQLifecycleStatus

  association [0..1] to E_PurchasingDocument         as _CentralReqForQuotationExtn   on _CentralReqForQuotationExtn.PurchasingDocument = $projection.CentralRequestForQuotation
 
{

      @ObjectModel: { readOnly: true }
  key cast (R_PurchasingDocument.PurchasingDocument as vdm_cntrlrequestforquotation preserving type)     as CentralRequestForQuotation,

      @ObjectModel: { foreignKey.association: '_CompanyCode',
                      mandatory: true }
      R_PurchasingDocument.CompanyCode,

      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_PurchasingDocumentCategory' }
      R_PurchasingDocument.PurchasingDocumentCategory,

      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_RFQType' }
      cast(R_PurchasingDocument.PurchasingDocumentType as vdm_rfq_doc_type preserving type )             as PurchasingDocumentType,

      @ObjectModel: { readOnly: true }
      @Semantics.user.createdBy: true
      R_PurchasingDocument.CreatedByUser,

      @ObjectModel: { readOnly: true }
      @Semantics.systemDate.createdAt: true
      R_PurchasingDocument.CreationDate,

      @ObjectModel.readOnly: true
      @Semantics.systemDateTime.lastChangedAt: true
      R_PurchasingDocument.LastChangeDateTime,
      @Semantics.language: false
      R_PurchasingDocument.Language,

      @ObjectModel: { foreignKey.association: '_PurchasingOrganization',
                      mandatory: true }
      cast(R_PurchasingDocument.PurchasingOrganization as ekorg_ll preserving type )                     as PurchasingOrganization,

      @ObjectModel: { foreignKey.association: '_PurchasingGroup',
                      mandatory: true }
      R_PurchasingDocument.PurchasingGroup,

      @Semantics.currencyCode:true
      @ObjectModel: { foreignKey.association: '_DocumentCurrency'}
      R_PurchasingDocument.DocumentCurrency,

      @ObjectModel: { foreignKey.association: '_IncotermsClassification' }
      R_PurchasingDocument.IncotermsClassification,
      R_PurchasingDocument.IncotermsTransferLocation,
      @ObjectModel: {foreignKey.association: '_IncotermsVersion' }
      R_PurchasingDocument.IncotermsVersion,
      R_PurchasingDocument.IncotermsLocation1,
      R_PurchasingDocument.IncotermsLocation2,

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      R_PurchasingDocument.PaymentTerms,
      R_PurchasingDocument.CashDiscount1Days,
      R_PurchasingDocument.CashDiscount2Days,
      R_PurchasingDocument.CashDiscount1Percent,
      R_PurchasingDocument.CashDiscount2Percent,
      R_PurchasingDocument.NetPaymentDays,
      R_PurchasingDocument.ValidityStartDate,
      R_PurchasingDocument.ValidityEndDate,
      cast( R_PurchasingDocument.PurchasingDocumentOrderDate as vdm_rfq_publishing_date preserving type) as RFQPublishingDate,
      R_PurchasingDocument.QuotationLatestSubmissionDate,
      R_PurchasingDocument.BindingPeriodValidityEndDate,
      @DefaultAggregation:#NONE
      R_PurchasingDocument.TargetAmount,

      @ObjectModel: {  foreignKey.association: '_RFQLifecycleStatus'}
      cast ( R_PurchasingDocument.PurchasingProcessingStatus as vdm_rfq_lfst_cd preserving type)         as RFQLifecycleStatus,
      cast ( R_PurchasingDocument.PurchasingDocumentName as vdm_rfq_name preserving type)                as RequestForQuotationName,
      R_PurchasingDocument.QuotationEarliestSubmsnDate,
      cast (R_PurchasingDocument.LatestRegistrationDate as vdm_apply_by preserving type)                 as LatestRegistrationDate,
      R_PurchasingDocument.CorrespncInternalReference,

      @ObjectModel.foreignKey.association: '_FollowOnDocumentCategory'
      R_PurchasingDocument.FollowOnDocumentCategory,

      @ObjectModel.foreignKey.association: '_FollowOnDocumentType'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PurgDocFollowOnDocumentType'
      R_PurchasingDocument.FollowOnDocumentType,
      R_PurchasingDocument.FollowOnDocumentType                                                          as PurgDocFollowOnDocumentType,
      R_PurchasingDocument.PurchasingDocumentDeletionCode,
      R_PurchasingDocument.IsEndOfPurposeBlocked,

      R_PurchasingDocument._PurchasingDocumentType,
      R_PurchasingDocument._PurchasingDocumentCategory,
      R_PurchasingDocument._PaymentTerms,
      R_PurchasingDocument._CreatedByUser,
      R_PurchasingDocument._DocumentCurrency,
      R_PurchasingDocument._CompanyCode,
      R_PurchasingDocument._PurchasingGroup,
      R_PurchasingDocument._Language,
      R_PurchasingDocument.ValidityStartDate                                                             as PurContrValidityStartDate,
      R_PurchasingDocument.ValidityEndDate                                                               as PurContrValidityEndDate,

      // Associations //

      _CentralReqForQuotationItem,
      _CntrlReqForQuotationBidder,
      _RFQType,
      _IncotermsClassification,
      _IncotermsVersion,
      _PurchasingOrganization,
      _CentralSupplierQuotation,
      _RFQLifecycleStatus,
      _FollowOnDocumentCategory,
      _FollowOnDocumentType

}
where
  R_PurchasingDocument.PurchasingDocumentCategory = 'N'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_PURCHASINGDOCUMENT"
],
"ASSOCIATED":
[
"E_PURCHASINGDOCUMENT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_LANGUAGE",
"I_PAYMENTTERMS",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_REQUESTFORQUOTATIONTYPE",
"I_RFQLIFECYCLESTATUS",
"I_USER",
"R_CENTRALREQFORQUOTATIONITEM",
"R_CENTRALSUPPLIERQUOTATION",
"R_CNTRLREQFORQUOTATIONBIDDER"
],
"BASE":
[
"R_PURCHASINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More