C_ChgRecdObjPgEquipTskList

@AbapCatalog.sqlViewName: 'CCHGRECREFETL'
@EndUserText.label: 'Change Record Obj Page Equip Task List'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
   createEnabled: true,
   deleteEnabled: 'EXTERNAL_CALCULATION',
   updateEnabled,
   transactionalProcessingDelegated: true
}

@Metadata.allowExtensions: true

define view C_ChgRecdObjPgEquipTskList
  as select from I_ChgRecdRefEquipTskListTP as ChangeRecordRefEquipTskListTP

  association [1..1] to C_ChgRecdItmRelEquipTskListVH as _ChangeRecordItemRelVH   on  $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                  and $projection.ChangeRecordType          = _ChangeRecordItemRelVH.ChangeRecordType

  association [1..1] to C_ChangeRecordObjPg           as _ChangeRecordObjPg       on  $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID

  association [1..1] to C_ChgRecdEquipTskListVH       as _EquipTaskListVH         on  $projection.BillOfOperationsType    = _EquipTaskListVH.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _EquipTaskListVH.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _EquipTaskListVH.BillOfOperationsVariant
  association [1..1] to C_ChgRecordItemProcgStatusVH  as _ProcessingStatusVH      on  $projection.ChangeRecordItemProcgStatus   = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
                                                                                  and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
                                                                                  and $projection.ChangeRecordLifecycleStatus   = _ProcessingStatusVH.ChangeRecordLifecycleStatus
  association [0..*] to I_ChgRecdItemProcgStatusText  as _ProcessingStatusTxt     on  $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus

  association [1..1] to I_BillOfOperations            as _BillOfOperations        on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant

  association [1..*] to C_ChgRecdEquipTskListMatVH    as _EquipTaskListMatVH      on  $projection.BillOfOperationsType    = _EquipTaskListMatVH.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _EquipTaskListMatVH.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _EquipTaskListMatVH.BillOfOperationsVariant

  association [0..*] to I_ChangeRecordRefObjIcons     as _ChangeRecordRefObjIcons on  $projection.ChangeRecordUUID          = _ChangeRecordRefObjIcons.ChangeRecordUUID
                                                                                  and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
  association [0..*] to C_ChangeRecdDigSignStatusVH   as _DigSignStatusText       on  $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus

{
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @Semantics.imageUrl: true
          @ObjectModel.readOnly: true

          _ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,

          @Consumption.valueHelpDefinition: [
                                             { entity: {name: 'C_ChgRecdEquipTskListVH',
                                                        element: 'BillOfOperationsGroup'},
                                               additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
                                               label: 'Equipment Task List'
                                               },
                                             { entity: {name: 'C_ChgRecdEquipTskListMatVH',
                                                        element: 'BillOfOperationsGroup'},
                                               additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
                                               label: 'Equipment Task List by Material',
                                               qualifier: 'SecondaryValueHelp'
                                             }
                                             ]

          @ObjectModel.mandatory: true
          @ObjectModel.text.element:  [ 'BillOfOperationsDesc' ]
          @UI.identification: { importance: #HIGH }
          ChangeRecordRefEquipTskListTP.BillOfOperationsGroup                                  as BillOfOperationsGroup,
          @ObjectModel.readOnly: true
          _BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].BillOfOperationsDesc,

          ChangeRecordRefEquipTskListTP.BillOfOperationsType                                   as BillOfOperationsType,
          @UI.identification: { importance: #HIGH }
          ChangeRecordRefEquipTskListTP.BillOfOperationsVariant,

          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordType                                                  as ChangeRecordType,
          @ObjectModel.readOnly:true
          _ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordLifecycleStatus                                       as ChangeRecordLifecycleStatus,
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordStatus,
          ChangeRecordUUID,
          ChangeRecordReferenceType,
          ParentChangeRecordRefUUID,
          @ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
          @Consumption.valueHelp: '_ChangeRecordItemRelVH'
          @ObjectModel.mandatory: true
          ChangeRecordItemRelevance,

          ChgRecdReasonForChange,

          ExpdCompltnDte,

          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
          ChgRecdAuthznGrpText,

          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
          ChgRecdNmbrChgSts,

          @Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
          @ObjectModel.foreignKey.association: '_ProcessingStatusVH'
          ChangeRecordItemProcgStatus,
          @ObjectModel.readOnly: true
          ChgRecdCurrentItemProcgStatus,
          @ObjectModel.readOnly: true
          @Consumption.semanticObject: 'ChangeMaster'
          @UI.identification: { importance: #HIGH }
          ChangeNumber,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          CreatedByUser,
          CreationDateTime,
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
          @ObjectModel.readOnly: true
          cast( '00000000' as /plmb/created_on )                                               as CreationDate,
          @Semantics.user.lastChangedBy: true
          LastChangedByUser,
          LastChangeDateTime,
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
          @ObjectModel.readOnly: true
          cast( '00000000' as /plmb/changed_on )                                               as LastChangeDate,

          @UI.hidden: true
          @UI.lineItem:[{importance:#HIGH, hidden: true }   ]
          @EndUserText.label: 'Digital Signature Status'
          @ObjectModel.foreignKey.association: '_DigSignStatusText'
          @Consumption: { valueHelp: '_DigSignStatusText' }
          ChgRecdItmDSgntr,

          @UI.lineItem:[{
              hidden: true,
              importance:#LOW }
            ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                                                                 as DigitalSignUserIsAuthorized,

          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #LOW, position: 90 }]
          @EndUserText.label: 'Digital Signature Status'
          _DigSignStatusText.ChgRecdDigSignStatusTxt                                           as ChgRecdDigSignStatusTxt,


          @UI.lineItem:[{
          hidden: true,
          importance:#LOW }
          ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                                                                 as ChgRecdObjDgtlSgntrEnable,


          @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
          _ChangeRecordObjPg,
          _ChangeRecordItemRelVH,
          _ProcessingStatusVH,
          _EquipTaskListVH,
          _EquipTaskListMatVH,
          _ProcessingStatusTxt,
          _BillOfOperations,
          _DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDREFEQUIPTSKLISTTP"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_CHGRECDEQUIPTSKLISTMATVH",
"C_CHGRECDEQUIPTSKLISTVH",
"C_CHGRECDITMRELEQUIPTSKLISTVH",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_BILLOFOPERATIONS",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDITEMPROCGSTATUSTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/