I_ChgRecdRefEquipTskListTP

@AbapCatalog.sqlViewName: 'ICRREFETLTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Chg Red Ref Obj Equip Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFETL_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
define view I_ChgRecdRefEquipTskListTP
  as select from           I_ChgRecdRefEquipTskListBsc as EquipmentTaskListReference
    left outer to one join I_BillOfOperations          as EquipmentTaskList on  EquipmentTaskListReference.ChgRecRefInternalKey1 = EquipmentTaskList.BillOfOperationsType
                                                                            and EquipmentTaskListReference.ChgRecRefInternalKey2 = EquipmentTaskList.BillOfOperationsGroup
                                                                            and EquipmentTaskListReference.ChgRecRefInternalKey3 = EquipmentTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP             on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefEquipTskListBsc as _EquipmentTaskListExtension on $projection.ChangeRecordReferenceUUID = _EquipmentTaskListExtension.ChangeRecordReferenceUUID
{
  key   EquipmentTaskListReference.ChangeRecordReferenceUUID,
        case
           when EquipmentTaskList.BillOfOperationsType is null then cast(SUBSTRING( EquipmentTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(EquipmentTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when EquipmentTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( EquipmentTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(EquipmentTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when EquipmentTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( EquipmentTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(EquipmentTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        EquipmentTaskListReference.ChangeRecordUUID,
        EquipmentTaskListReference.ChangeRecordReferenceType,
        EquipmentTaskListReference.ChangeRecordReferenceSubtype,
        EquipmentTaskListReference.ChangeRecordRefObjectUUID,
        EquipmentTaskListReference.ChangeRecordReference,
        EquipmentTaskListReference.ParentChangeRecordRefUUID,
        EquipmentTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,
          
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        EquipmentTaskListReference.CreatedByUser,
        EquipmentTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        EquipmentTaskListReference.LastChangedByUser,
        EquipmentTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        EquipmentTaskListReference.ChangeRecordItemRelevance,
        EquipmentTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        EquipmentTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        EquipmentTaskListReference.ChgRecdCurrentItemProcgStatus,
        EquipmentTaskListReference.ChangeNumber,
        @ObjectModel.readOnly: true
        EquipmentTaskListReference.ChgRecdItmTgtSts,
        @ObjectModel.readOnly: true
        EquipmentTaskListReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
     EquipmentTaskList.BillOfOperationsType = 'E'
  or EquipmentTaskList.BillOfOperationsType is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFEQUIPTSKLISTBSC"
],
"ASSOCIATED":
[
"E_CHGRECDREFEQUIPTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/