C_ChgRecdEquipTskListMatVH

@AbapCatalog.sqlViewName: 'CETLMATVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Material for Equipment Task List'

@ObjectModel.representativeKey: 'BillOfOperationsGroup'
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@Search.searchable: true
@ObjectModel.dataCategory: #VALUE_HELP
@Consumption.ranked: true

define view C_ChgRecdEquipTskListMatVH
  as select from I_BillOfOperations as _BillOfOperations

  association [0..*] to I_BOOMaterialAssgmtChangeState as _BOOMaterialAssgmtChangeState on  $projection.BillOfOperationsType    = _BOOMaterialAssgmtChangeState.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup   = _BOOMaterialAssgmtChangeState.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant = _BOOMaterialAssgmtChangeState.BillOfOperationsVariant

{
      @EndUserText.label: 'Material'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key _BOOMaterialAssgmtChangeState.Material,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
  key _BOOMaterialAssgmtChangeState.Plant,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      @EndUserText.label: 'Group'
  key cast( BillOfOperationsGroup as r_plnnr preserving type)                                         as BillOfOperationsGroup,
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.7
  key BillOfOperationsVariant,
      //      @Search.defaultSearchElement: true

      @UI.hidden: true
      //      @Search.ranking: #LOW

  key BillOfOperationsType,
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.7
      cast(_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date
      and ValidityEndDate >= $session.system_date].BillOfOperationsDesc as r_rbez preserving type)    as BillOfOperationsDesc,
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.7
      _BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date
      and ValidityEndDate >= $session.system_date].BillOfOperationsUsage,
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.7
      cast(_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date
      and ValidityEndDate >= $session.system_date].BillOfOperationsStatus as r_statu preserving type) as BillOfOperationsStatus,

      _BOOMaterialAssgmtChangeState
}
where
  BillOfOperationsType = 'E'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"ASSOCIATED":
[
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/