I_ENGMNTPROJECTPLNDATAVERSION

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IEPROJPLNDATAVER'
@EndUserText.label: 'Engagement Project Plan Data Version'
@VDM.viewType: #BASIC
@Analytics:{dataCategory:#FACT}
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
//@AccessControl.personalData.blocking: #REQUIRED


define view I_EngmntProjectPlnDataVersion

  as select from /cpd/plandata as EngagementProjectPlanData

  association [0..1] to I_EngagementProject            as _EngagementProject           on  $projection.EngagementProject = _EngagementProject.EngagementProject

  association [0..1] to I_EngagementProjFinancialPlan  as _EngagementProjFinancialPlan on  $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID

  association [1..1] to I_WorkPackage                  as _WorkPackage                 on  $projection.WorkPackage = _WorkPackage.WorkPackage

  association [0..1] to I_EngmtProjFinPlanVersion      as _EngmtProjFinPlanVersion     on  $projection.EngagementProjFinPlanUUID = _EngmtProjFinPlanVersion.EngagementProjFinPlanUUID
                                                                                       and $projection.EngmtProjFinPlanVersion   = _EngmtProjFinPlanVersion.EngmtProjFinPlanVersion

  association [0..1] to I_EngmntProjResourceType       as _EngmntProjResourceType      on  $projection.EngagementProjectResourceType = _EngmntProjResourceType.EngagementProjectResourceType

  association [0..*] to I_EngagementProjectResource    as _EngagementProjectResource   on  $projection.EngagementProjectResource = _EngagementProjectResource.EngagementProjectResource

  association [0..1] to I_WorkPackageWorkItem          as _WorkItem                    on  $projection.WorkItem    = _WorkItem.WorkItem
                                                                                       and $projection.WorkPackage = _WorkItem.WorkPackage

  association [0..1] to I_Currency                     as _Currency                    on  $projection.Currency = _Currency.Currency

  association [0..1] to I_UnitOfMeasure                as _UnitOfMeasure               on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_BillingControlCategory       as _BillingControlCategory      on  $projection.BillingControlCategory = _BillingControlCategory.BillingControlCategory

  association [0..*] to I_PersnWrkAgreementDet         as _PersonWorkAgreementDet      on  $projection.EmploymentInternalID = _PersonWorkAgreementDet.PersonWorkAgreement

  association [0..1] to I_Employment                   as _Employment                  on  $projection.EmploymentInternalID = _Employment.EmploymentInternalID
  
  association [0..1] to I_PersonWorkAgreement_1        as _PersonWorkAgreement_1       on  $projection.EmploymentInternalID = _PersonWorkAgreement_1.PersonWorkAgreement
  
  association [0..1] to I_EngagementProjectSrvcOrg     as _EngagementProjectServiceOrg on  $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg

  association [0..1] to I_PlanSkillTags                as _PlanSkillTags               on  $projection.ResourceDemandUUID = _PlanSkillTags.ResourceDemandUUID

  association [1..1] to I_EngmntProjAssgmtToSessionUsr as _MyProject                   on  $projection.EngagementProject = _MyProject.EngagementProject

{

  key EngagementProjectPlanData.plan_line_guid                                        as PlanLineItemUUID,

  key cast(EngagementProjectPlanData.mp_id  as /cpd/eng_mp_id preserving type)        as EngagementProject,

  key EngagementProjectPlanData.wp_id                                                 as WorkPackage,

  key cast(EngagementProjectPlanData.fp_key  as /cpd/eng_pfp_db_key preserving type ) as EngagementProjFinPlanUUID,

  key cast(EngagementProjectPlanData.wp_key as /cpd/wp_db_key preserving type )       as WorkPackageUUID,

  key EngagementProjectPlanData.version                                               as EngmtProjFinPlanVersion,

      @ObjectModel.foreignKey.association: '_EngmntProjResourceType'
  key EngagementProjectPlanData.res_type                                              as EngagementProjectResourceType,
      
      @Semantics.fiscal.period: true
  key EngagementProjectPlanData.period                                                as FiscalPeriod,

      @Semantics.fiscal.year: true
  key EngagementProjectPlanData.fc_year                                               as FiscalYear,

      @ObjectModel.foreignKey.association: '_EngagementProjectResource'
  key EngagementProjectPlanData.resource_id                                           as EngagementProjectResource,

      @ObjectModel.foreignKey.association: '_PersonWorkAgreementDet'
  key EngagementProjectPlanData.employee                                              as EmploymentInternalID,
  
  key EngagementProjectPlanData.confirmed                                             as EngmtProjEmployeeIsStaffed,
  
      @ObjectModel.foreignKey.association: '_WorkItem'
  key EngagementProjectPlanData.workitem_id                                           as WorkItem,

  key EngagementProjectPlanData.demand_key                                            as ResourceDemandUUID,

      //Adding Demand External ID and Supply External ID


      EngagementProjectPlanData.resource_demand_id                                    as ResourceDemand,

      EngagementProjectPlanData.resource_supply_id                                    as ResourceSupply,

      @ObjectModel.foreignKey: {
        association: '_BillingControlCategory'
      }
      // Backword compatibility [2002]: We need to explicitly make expense BillingControlCategory indicator to Non Billable for Service Based Work Packages

      EngagementProjectPlanData.billgctrlcat                                          as BillingControlCategory,

      @ObjectModel.foreignKey.association:'_EngagementProjectServiceOrg'
      EngagementProjectPlanData.delvry_serv_org                                       as EngagementProjectServiceOrg,

      EngagementProjectPlanData.is_unit_based                                         as IsUnitBased,

      EngagementProjectPlanData.parent_unit_demand_key                                as ParentUnitDemandUUID,

      @Semantics.currencyCode: true
      EngagementProjectPlanData.currency                                              as Currency,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.cost                                                  as PlndCostAmt,

      @Semantics.unitOfMeasure: true
      EngagementProjectPlanData.uom                                                   as UnitOfMeasure,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.effort                                                as PlndEffortQty,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.revenue                                               as PlndRevnAmt,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      EngagementProjectPlanData.cost_deviation                                        as ActualPlanDeviationCost,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @DefaultAggregation: #SUM
      EngagementProjectPlanData.effort_deviation                                      as ActualPlanDeviationEffort,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      EngagementProjectPlanData.revenue_deviation                                     as ActualPlanDeviationRevenue,

      EngagementProjectPlanData.line_type                                             as EngmntProjPlanLineType,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'SupplySource'

      EngagementProjectPlanData.source_of_supply                                      as SourceOfSupply,

      EngagementProjectPlanData.source_of_supply                                      as SupplySource,
      _EngagementProject,
      _EngagementProjFinancialPlan,
      _EngmtProjFinPlanVersion,
      _WorkPackage,
      _EngmntProjResourceType,
      _WorkItem,
      _EngagementProjectResource,
      _PersonWorkAgreementDet,
      _Currency,
      _EngagementProjectServiceOrg,
      _UnitOfMeasure,
      _PlanSkillTags,
      @VDM.lifecycle: {
        successor: '_PersonWorkAgreement_1',
        status: #DEPRECATED
      }
      _Employment,
      _PersonWorkAgreement_1,
      _BillingControlCategory,
      _MyProject

}

where
      is_draft      <> 'X'
  and is_unit_based <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/CPD/PLANDATA"
],
"ASSOCIATED":
[
"I_BILLINGCONTROLCATEGORY",
"I_CURRENCY",
"I_EMPLOYMENT",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_ENGMNTPROJASSGMTTOSESSIONUSR",
"I_ENGMNTPROJRESOURCETYPE",
"I_ENGMTPROJFINPLANVERSION",
"I_PERSNWRKAGREEMENTDET",
"I_PERSONWORKAGREEMENT_1",
"I_PLANSKILLTAGS",
"I_UNITOFMEASURE",
"I_WORKPACKAGE",
"I_WORKPACKAGEWORKITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/