P_EngmntProjDemands

@AbapCatalog.sqlViewName: 'PENGPROJDMND'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'Engagement Project Demands'
define view P_EngmntProjDemands
  as select from I_EngmntProjAssgmtToSessionUsr as EngagementProject

    inner join   I_EngmntProjDmndHdr            as EngagementProjectDemandHdr  on EngagementProject.EngagementProject = EngagementProjectDemandHdr.EngagementProject

    inner join   I_EngmntProjectPlnDataVersion  as EngmntProjectPlnDataVersion on  EngagementProjectDemandHdr.EngagementProject  = EngmntProjectPlnDataVersion.EngagementProject
                                                                               and EngagementProjectDemandHdr.WorkPackage        = EngmntProjectPlnDataVersion.WorkPackage
                                                                               and EngagementProjectDemandHdr.ResourceDemandUUID = EngmntProjectPlnDataVersion.ResourceDemandUUID
{
  key EngmntProjectPlnDataVersion.ResourceDemandUUID,
  key FiscalYear,
  key FiscalPeriod,
  key EngmntProjPlanLineType,
  key ResourceSupply,

      EngagementProject.EngagementProjectServiceOrg,
      EngagementProjectCategory,
      ProjectProfileCode,
      EngmntProjectHeaderCompanyCode,
      EngagementProjectCostCenter,
      ProfitCenter,
      ProjectVisibility,
      IsMyProject,

      EngmntProjectPlnDataVersion.EngagementProject,
      EngagementProjectName,
      EngagementProjectStage,
      EngmntProjectPlnDataVersion.WorkPackage,
      EngagementProjectResource,
      ResourceDemand,      
      EngmntProjectPlnDataVersion.Currency,
      UnitOfMeasure,

      /*Demand Header Details*/
      DemandStartDate,
      DemandEndDate,
      DemandStaffingStatus,

      case when EngmntProjectPlnDataVersion.EngmntProjPlanLineType = 'D'
      then EngmntProjectPlnDataVersion.EngagementProjectServiceOrg
      else '' end                       as DeliveryOrganization,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      case when EngmntProjectPlnDataVersion.EngmntProjPlanLineType = 'D'
      then EngmntProjectPlnDataVersion.PlndEffortQty
      else cast(0 as megxxx) end        as DemandEffortQty,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      case when EngmntProjectPlnDataVersion.EngmntProjPlanLineType = 'S'
      then EngmntProjectPlnDataVersion.PlndEffortQty
      else cast(0 as megxxx) end        as SupplyEffortQty,

      @Semantics.amount.currencyCode: 'Currency'
      case when EngmntProjectPlnDataVersion.EngmntProjPlanLineType = 'D'
      then EngmntProjectPlnDataVersion.PlndCostAmt
      else cast(0 as /cpd/pfp_curr) end as DemandCostAmt,

      /* Associations */
      _EngagementProjectResource,
      _PlanSkillTags
}

where
      EngmntProjectPlnDataVersion.EngmntProjPlanLineType        <> 'U'
  and EngmntProjectPlnDataVersion.EngmtProjFinPlanVersion       =  '1'
  and EngmntProjectPlnDataVersion.EngagementProjectResourceType =  '0ACT'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGMNTPROJASSGMTTOSESSIONUSR",
"I_ENGMNTPROJDMNDHDR",
"I_ENGMNTPROJECTPLNDATAVERSION"
],
"ASSOCIATED":
[
"I_ENGAGEMENTPROJECTRESOURCE",
"I_PLANSKILLTAGS"
],
"BASE":
[
"I_ENGMNTPROJECTPLNDATAVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/