I_CustomerProjectPlanData

@AbapCatalog.sqlViewName: 'ICUSTPROJPLAN'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Customer Project Planning Data'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

// This view is deprecated Kindly use I_EngagementProjectPlanData


define view I_CustomerProjectPlanData
  as select from    I_EngmntProjectPlnDataVersion as PlanData
    left outer join I_CustomerProject             as CustomerProject on PlanData.EngagementProjFinPlanUUID = CustomerProject.CustProjFinancialPlanUUID


  association [0..1] to I_Currency             as _Currency             on $projection.Currency = _Currency.Currency
  association [0..1] to I_UnitOfMeasure        as _UnitOfMeasure        on $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure
  association [0..*] to I_CustProjResourceText as _CustProjResourceText on $projection.CustomerProjectResource = _CustProjResourceText.CustomerProjectResource
  association [0..1] to I_CustProjWrkPckgText  as _CustProjWrkPckgText  on $projection.CustProjWorkPackageUUID = _CustProjWrkPckgText.CustProjWorkPackageUUID

{

  key PlanLineItemUUID                                                               as PlanLineItemUUID,
  key cast(PlanData.EngagementProjFinPlanUUID   as /cpd/ss_cp_fp_uuid )              as CustProjFinancialPlanUUID,
  key cast(PlanData.WorkPackageUUID  as /cpd/ss_cp_wp_uuid )                         as CustProjWorkPackageUUID,
  key cast(PlanData.EngmtProjFinPlanVersion  as /cpd/ss_cp_fp_version )              as CustProjFinancialPlanVersion,
  key cast(PlanData.EngagementProjectResourceType as /cpd/ss_cp_res_typ )            as CustomerProjectResourceType,
  key PlanData.FiscalPeriod                                                          as FiscalPeriod,
  key PlanData.FiscalYear                                                            as FiscalYear,
  key cast(PlanData.EngagementProjectResource as /cpd/ss_cp_resource )               as CustomerProjectResource,
  key PlanData.EmploymentInternalID                                                  as PersonnelNumber,
  key PlanData.EngmtProjEmployeeIsStaffed                                            as CustProjWorkPckgEmplIsStaffed,
      CustomerProject.CustomerProject                                                as CustomerProject,
      CustomerProject.CustomerProjectType                                            as CustomerProjectType,
      CustomerProject.CustomerProjectServiceOrg                                      as CustomerProjectServiceOrg,
      @Semantics.currencyCode: true
      PlanData.Currency                                                              as Currency,
      @Semantics.amount.currencyCode: 'Currency'
      PlanData.PlndCostAmt                                                           as CustProjWrkPckgPlanCost,
      @Semantics.unitOfMeasure: true
      PlanData.UnitOfMeasure                                                         as UnitOfMeasure,
      @Semantics.quantity.unitOfMeasure:'UnitOfMeasure'      
      PlanData.PlndEffortQty                                                         as CustProjWrkPckgPlanEffortQty,
      @Semantics.amount.currencyCode: 'Currency'      
      PlanData.PlndRevnAmt                                                           as CustProjWrkPckgPlanRevenue,
      _Currency,

      _UnitOfMeasure,
      _CustProjResourceText,
      _CustProjWrkPckgText
}
where
  EngmtProjFinPlanVersion = '1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERPROJECT",
"I_ENGMNTPROJECTPLNDATAVERSION"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_CUSTPROJRESOURCETEXT",
"I_CUSTPROJWRKPCKGTEXT",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/