C_EngmntProjStaffedResource

@AbapCatalog.sqlViewName: 'CENGPROJSTAFFRES'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE  
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@EndUserText.label: 'Engagement Project Staffed Resource'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: [ '_EngmntProjSuppliedDelOrgText' ]
define view C_EngmntProjStaffedResource
  as select from    I_EngmntProjectPlnDataVersion as EngmntProjectPlnDataVersion

    left outer join I_RSHProjectAssignment        as RSHProjectAssignment on  EngmntProjectPlnDataVersion.ResourceDemandUUID   = RSHProjectAssignment.ResourceDemandUUID
                                                                          and EngmntProjectPlnDataVersion.EmploymentInternalID = RSHProjectAssignment.EmploymentInternalID

  association [0..*] to I_PersnWrkAgreementDet         as _PersonWorkAgreementDet       on  $projection.EmploymentInternalID = _PersonWorkAgreementDet.PersonWorkAgreement

  association [0..1] to I_EngagementProjectSrvcOrg     as _EngagementProjectServiceOrg   on  $projection.EngmntProjectDeliveryOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg

  association [0..1] to I_User                         as _UserDetails                  on  RSHProjectAssignment.ProjAssignmentLastChangedBy = _UserDetails.UserID

  association [1..1] to I_EngagementProject            as _EngagementProject            on  $projection.EngagementProject = _EngagementProject.EngagementProject

  association [1..1] to I_EngmntProjAssgmtToSessionUsr as _MyProject                    on  $projection.EngagementProject = _MyProject.EngagementProject

  association [0..1] to I_EngagementProjectSrvcOrgText as _EngmntProjSuppliedDelOrgText on  $projection.EngmntProjectDeliveryOrg   = _EngmntProjSuppliedDelOrgText.EngagementProjectServiceOrg
                                                                                        and _EngmntProjSuppliedDelOrgText.Language = $session.system_language
{

  key EngmntProjectPlnDataVersion.ResourceDemandUUID            as ResourceDemandUUID,
  key EngmntProjectPlnDataVersion.EmploymentInternalID          as EmploymentInternalID,

      EngmntProjectPlnDataVersion.ResourceDemand                as ResourceDemand,
      EngmntProjectPlnDataVersion.ResourceSupply                as ResourceSupply,

      /* Demand Details */
      EngagementProject,
      WorkPackage,
      EngagementProjectResource,
      //--[ GENERATED:012:GlBfhyJl7kY4nRd09JNw30

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EngmntProjSrvcOrgStdVH',
                     element: 'EngagementProjectServiceOrg' }
        }]
      // ]--GENERATED

      EngagementProjectServiceOrg                               as EngmntProjectDeliveryOrg,
      //--[ GENERATED:012:GlBfhyJl7kY4nRd09JNw30

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_PersnWrkAgreementDetStdVH',
                     element: 'PersonWorkAgreement' }
        }]
      // ]--GENERATED


      EngagementProjectResourceType                             as EngagementProjectResourceType,
      WorkItem                                                  as WorkItem,
      _PersonWorkAgreementDet._WorkforcePerson.PersonExternalID as PersonExternalID,

      @Semantics.currencyCode: true
      Currency                                                  as Currency,
      @Semantics.unitOfMeasure: true
      UnitOfMeasure                                             as UnitOfMeasure,
      @Semantics.quantity.unitOfMeasure:'UnitOfMeasure'
      sum(EngmntProjectPlnDataVersion.PlndEffortQty)            as EngmntProjStaffedEffort,

      @Semantics.amount.currencyCode:'Currency'
      sum(EngmntProjectPlnDataVersion.PlndCostAmt)              as EngmntProjStaffedCost,


      /* Assignment details from RSH */
      RSHProjectAssignment.ProjAssignmentLastChangedBy          as ProjAssignmentLastChangedBy,
      _UserDetails.UserDescription                              as ResourceManager,
      RSHProjectAssignment.ProjAssignmentStartDate              as StaffedResourceStartDate,
      RSHProjectAssignment.ProjAssignmentEndDate                as StaffedResourceEndDate,


      /* Associations */
      _Currency,
      _EngagementProject,
      _EngagementProjectResource,
      _PlanSkillTags,
      _UnitOfMeasure,
      _EngagementProjectServiceOrg,
      _PersonWorkAgreementDet,
      _EngmntProjResourceType,
      _WorkItem,
      _MyProject,
      _EngmntProjSuppliedDelOrgText,
      _PersonWorkAgreement_1
}

where
      EngmntProjectPlnDataVersion.EngmntProjPlanLineType  = 'S'
  and EngmntProjectPlnDataVersion.EngmtProjFinPlanVersion = '1'
  and EngagementProjectResourceType                       = '0ACT'


group by
  EngagementProject,
  WorkPackage,
  WorkItem,
  EngagementProjectResource,
  EngagementProjectResourceType,
  EngmntProjectPlnDataVersion.ResourceDemandUUID,
  Currency,
  UnitOfMeasure,
  EngmntProjectPlnDataVersion.EmploymentInternalID,
  EngagementProjectServiceOrg,
  _UserDetails.UserDescription,
  RSHProjectAssignment.ProjAssignmentLastChangedBy,
  RSHProjectAssignment.ProjAssignmentStartDate,
  RSHProjectAssignment.ProjAssignmentEndDate,
  _PersonWorkAgreementDet._WorkforcePerson.PersonExternalID,
  ResourceDemand,
  ResourceSupply
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGMNTPROJECTPLNDATAVERSION",
"I_PERSNWRKAGREEMENTDET",
"I_RSHPROJECTASSIGNMENT",
"I_USER",
"I_WORKFORCEPERSONDET"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJECTSRVCORGTEXT",
"I_ENGMNTPROJASSGMTTOSESSIONUSR",
"I_ENGMNTPROJRESOURCETYPE",
"I_PERSNWRKAGREEMENTDET",
"I_PERSONWORKAGREEMENT_1",
"I_PLANSKILLTAGS",
"I_UNITOFMEASURE",
"I_USER",
"I_WORKPACKAGEWORKITEM"
],
"BASE":
[
"I_ENGMNTPROJECTPLNDATAVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/