C_ConfignCharacteristic

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CVCHHLCFCSTIC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type:#NONE
@ObjectModel.modelCategory: #BUSINESS_OBJECT
@EndUserText.label: 'OBSOLETE: Configuration Characteristic'
@Search.searchable: true


@Metadata.allowExtensions: true
define view C_ConfignCharacteristic
  as select distinct from I_ClfnClassCharcBasic as CharcInClass
    inner join   I_ClfnCharacteristic           as Cstic on Cstic.CharcInternalID = CharcInClass.CharcInternalID
                                                         and Cstic.ValidityStartDate <= $session.system_date
                                                         and Cstic.ValidityEndDate   >= $session.system_date
    inner join   I_ClfnClass                    as Class on Class.ClassInternalID = CharcInClass.ClassInternalID
                                                         and Class.ValidityStartDate <= $session.system_date
                                                         and Class.ValidityEndDate   >= $session.system_date
    inner join I_ClfnClassTypeBasic as Clstype on  Clstype.ClassType = Class.ClassType 
                                               and Clstype.ClassTypeIsUsableInVarConfign = 'X' 
    association [0..*] to I_ClfnCharcDesc       as _CharcDesc on  CharcInClass.CharcInternalID = _CharcDesc.CharcInternalID
                                                              and _CharcDesc.Language                = $session.system_language
                                                              and _CharcDesc.IsDeleted     <> 'X'
                                                              and _CharcDesc.ValidityStartDate <= $session.system_date
                                                              and _CharcDesc.ValidityEndDate   >= $session.system_date
    
{
            @ObjectModel.readOnly: true
  key       CharcInClass.CharcInternalID,
  key       CharcInClass.ClassInternalID,     // additional key field to make key unique

            @ObjectModel.readOnly: true
            @Search.defaultSearchElement: true
            @Search.ranking: #HIGH
  key       CharcInClass.CharcPositionNumber, // additional key field to make key unique even with strange data

            Cstic.Characteristic,
            @ObjectModel.readOnly: true
            @Search.defaultSearchElement: true
            _CharcDesc.CharcDescription, // Cardinality is actually 1 due to selection by validity date

            @ObjectModel.readOnly: true
            @Search.defaultSearchElement: false
            Class.ClassType,
            @ObjectModel.readOnly: true
            @Search.defaultSearchElement: false
            Class.Class,
            @ObjectModel.readOnly: true
            @Search.defaultSearchElement: false
            '                                                              ' as Product // We need the length of MATNR so that 

                                                // the value is not truncated on its way from UI to backend. 

                                                // A CAST to data element MATNR might seem okay but it is not  

                                                // because no conversion exit is allowed (ATC check)  

} where CharcInClass.ValidityStartDate <= $session.system_date
    and CharcInClass.ValidityEndDate   >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCHARACTERISTIC",
"I_CLFNCHARCDESC",
"I_CLFNCLASS",
"I_CLFNCLASSCHARCBASIC",
"I_CLFNCLASSTYPEBASIC"
],
"ASSOCIATED":
[
"I_CLFNCHARCDESC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/