I_ClfnClassDEX

@AccessControl.authorizationCheck: #MANDATORY
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.delta.changeDataCapture.automatic: true
@Analytics.dataExtraction.enabled: true
@Analytics.internalName:#LOCAL
@EndUserText.label: 'Classification Class DEX'
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'ClassInternalID'
@ObjectModel.supportedCapabilities:
   [ #CDS_MODELING_DATA_SOURCE,
     #CDS_MODELING_ASSOCIATION_TARGET,
     #EXTRACTION_DATA_SOURCE,
     #ANALYTICAL_DIMENSION,
     #SQL_DATA_SOURCE ]
@ObjectModel.usageType.dataClass: #MASTER     
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API     
@VDM.viewType: #BASIC
define view entity I_ClfnClassDEX
  as select from I_ClfnClass as Class
  
    association [0..*] to I_ClfnClassDescriptionDEX as _ClassDescription              
      on $projection.ClassInternalID = _ClassDescription.ClassInternalID 
                
    association [0..*] to I_ClfnClassKeywordDEX as _ClassKeyword
      on  $projection.ClassInternalID = _ClassKeyword.ClassInternalID
    
    association [0..*] to I_ClfnClassCharacteristicDEX as _ClassCharacteristic
      on  $projection.ClassInternalID = _ClassCharacteristic.ClassInternalID
    
    association [0..1] to I_ClfnClassStatus as _ClassStatus                  
      on  $projection.ClassStatus = _ClassStatus.ClassStatus
      and $projection.ClassType   = _ClassStatus.ClassType
     
    association [0..1] to I_ClfnClassGroup as _ClassGroup 
      on  $projection.ClassGroup = _ClassGroup.ClassGroup

    association [0..1] to I_ClfnClassTypeBasic as _ClassType 
      on  _ClassType.ClassType = $projection.ClassType 
{
  key Class.ClassInternalID,
      Class.ClassType,
      Class.Class,
      Class.ClassStatus,
      Class.ClassGroup,      
      Class.ClassSearchAuthGrp,
      Class.ClassClassfctnAuthGrp,
      Class.ClassMaintAuthGrp,
      Class.CreatedByUser,
      Class.CreationDate,
      Class.LastChangedByUser,
      Class.LastChangeDate,
      Class.ValidityStartDate,
      Class.ValidityEndDate,      
      Class. SameClassfctnReaction,
      Class.ClfnOrganizationalArea,
      Class.DocumentInfoRecordDocNumber,
      Class.DocumentInfoRecordDocType,
      Class.DocumentInfoRecordDocPart,
      Class.DocumentInfoRecordDocVersion,           
      Class.ClassStandardOrgName,
      Class.ClassStandardNumber,
      Class.ClassStandardStartDate,
      Class.ClassStandardVersionStartDate,
      Class.ClassStandardVersion,
      Class.ClassStandardCharcTable,
      Class.ClassBaseUnit,
      Class.ClassIsUsableInBOM,
      Class.ClassIsLocal,
      Class.ClassLastChangedDateTime,
      
      _ClassDescription,
      _ClassKeyword,
      _ClassCharacteristic,
      _ClassStatus,
      _ClassGroup,
      _ClassType
}
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CLFNCLASS"
],
"ASSOCIATED":
[
"I_CLFNCLASSCHARACTERISTICDEX",
"I_CLFNCLASSDESCRIPTIONDEX",
"I_CLFNCLASSGROUP",
"I_CLFNCLASSKEYWORDDEX",
"I_CLFNCLASSSTATUS",
"I_CLFNCLASSTYPEBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/