I_CHANGEDOCUMENT

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'ICHANGEDOC'
@EndUserText.label: 'Change document header'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@VDM.viewType: #BASIC

define view I_ChangeDocument
  as select from cdhdr

  association [0..*] to I_ChangeDocumentItem as _ChangeDocumentItem 
                     on  $projection.ChangeDocObjectClass = _ChangeDocumentItem.ChangeDocObjectClass
                     and $projection.ChangeDocObject      = _ChangeDocumentItem.ChangeDocObject
                     and $projection.ChangeDocument       = _ChangeDocumentItem.ChangeDocument

  association [0..1] to I_Language as _ChangeDocLanguage  
                     on  $projection.ChangeDocLanguage = _ChangeDocLanguage.Language
{
  key cdhdr.objectclas as ChangeDocObjectClass,
  key cdhdr.objectid   as ChangeDocObject,
  key cdhdr.changenr   as ChangeDocument,

      cdhdr.username   as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      cdhdr.udate      as CreationDate,
      @Semantics.systemTime.createdAt: true
      cdhdr.utime      as CreationTime,
      cdhdr.tcode      as ChangeTransactionCode,
      cdhdr.change_ind as ChangeDocChangeType,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_ChangeDocLanguage'
      cdhdr.langu      as ChangeDocLanguage,
      _ChangeDocumentItem,
      _ChangeDocLanguage
}    
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"CDHDR"
],
"ASSOCIATED":
[
"I_CHANGEDOCUMENTITEM",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/