I_WBSElementChangeDocuments

@AbapCatalog: {
          sqlViewName: 'IWBSCHGDOC',
          compiler.compareFilter: true,
          preserveKey: true
          }

@AccessControl: {
    authorizationCheck: #CHECK
    }
@EndUserText.label: 'Change document for WBS Element data'

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
   viewType: #BASIC,
   lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
    compositionRoot: true,

    usageType: {
        serviceQuality: #C,
        sizeCategory : #XL,
        dataClass: #TRANSACTIONAL
    },
    supportedCapabilities: [ #SQL_DATA_SOURCE, #EXTRACTION_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}

@Analytics: {
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true
    }
 }

@Metadata.ignorePropagatedAnnotations:true
define view I_WBSElementChangeDocuments
  as select from           I_WBSElementData_2                                                                              as prps
    inner join             I_ChangeDocument                                                                                as cdhdr        on  cdhdr.ChangeDocObject      = prps.ProjectInternalID
                                                                                                                                           and cdhdr.ChangeDocObjectClass = 'PROJ'
    inner join             I_ChangeDocumentItem                                                                            as cdpos        on  cdpos.ChangeDocObject      = prps.ProjectInternalID
                                                                                                                                           and cdpos.ChangeDocObjectClass = 'PROJ'
                                                                                                                                           and cdpos.ChangeDocument       = cdhdr.ChangeDocument
                                                                                                                                           and cdpos.ChangeDocTableKey    = concat(
      cast(
        $session.client                                                                                                    as char3
      ), prps.WBSElementInternalID
    )
                                                                                                                                           and (
                                                                                                                                              cdpos.DatabaseTable         = 'PRPS'
                                                                                                                                            )
    left outer to one join P_ProjectFieldMappingForChgDoc( p_tabname: 'I_WBSELEMENTDATA_2' , p_viewname:'IWBSELMNTDATA2' ) as FieldmapProj on FieldmapProj.DDICName = cdpos.ChangeDocDatabaseTableField
  // DPP Changes

  // Person in Responsible for Project

  association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson on $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  // Project Applicant

  association [0..1] to I_ProjectApplicant         as _ProjectApplicant  on $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
  // Project Data

  association [1..1] to I_ProjectData_2            as _Project           on $projection.ChangeDocObject = _Project.ProjectInternalID

{
  key cdhdr.ChangeDocObject              as ChangeDocObject,
  key cdhdr.ChangeDocObjectClass         as ChangeDocObjectClass,

  key cdpos.ChangeDocument               as ChangeDocument,
  key cdpos.DatabaseTable                as DatabaseTable,
  key cdpos.ChangeDocTableKey            as ChangeDocTableKey,

      // Field Name

  key cdpos.ChangeDocDatabaseTableField  as ChangeDocDatabaseTableField,

      // Change Indicator

  key cdpos.ChangeDocItemChangeType      as ChangeDocItemChangeType,
  key prps.WBSElementInternalID          as WBSElementInternalID,
      prps.WBSElementExternalID          as WBSElementExternalID,
      FieldmapProj.GFNName               as ChangeDocGlobalFieldName,
      @Semantics.text: true
      prps.WBSDescription                as WBSDescription,


      cdpos.ChangeDocPreviousUnit        as ChangeDocPreviousUnit,

      cdpos.ChangeDocNewUnit             as ChangeDocNewUnit,

      cdpos.ChangeDocPreviousCurrency    as ChangeDocPreviousCurrency,

      cdpos.ChangeDocNewCurrency         as ChangeDocNewCurrency,

      @EndUserText.label: 'Old Value'
      cdpos.ChangeDocPreviousFieldValue  as ChangeDocumentOldFieldValue,

      // New Value

      @EndUserText.label: 'New Value'
      cdpos.ChangeDocNewFieldValue       as ChangeDocumentNewFieldValue,
      // Changed By

      cdhdr.CreatedByUser                as LastChangedByUser,

      // Separate Date

      // LastChangedDate needed for Smart Filter Bar

      @Semantics.systemDate.createdAt: true
      cdhdr.CreationDate                 as LastChangeDate,

      // Separate Time

      // LastChangeTime needed for sorting

      @Semantics.systemTime.createdAt: true
      cdhdr.CreationTime                 as LastChangeTime,


      @Consumption.hidden: true
      prps.ControllingArea               as ControllingArea,

      @Consumption.hidden: true
      prps.ProfitCenter                  as ProfitCenter,

      @Consumption.hidden: true
      prps.ResponsiblePerson             as ResponsiblePerson,

      @Consumption.hidden: true
      prps.ApplicantCode                 as ApplicantCode,

      @Consumption.hidden: true
      prps.RespCostCenterControllingArea as RespCostCenterControllingArea,

      @Consumption.hidden: true
      prps.ResponsibleCostCenter         as ResponsibleCostCenter,

      @Consumption.hidden: true
      prps.FreeDefinedAttribute01        as FreeDefinedAttribute01,

      @Consumption.hidden: true
      prps.FreeDefinedAttribute02        as FreeDefinedAttribute02,

      @Consumption.hidden: true
      prps.FreeDefinedAttribute03        as FreeDefinedAttribute03,

      @Consumption.hidden: true
      prps.FreeDefinedAttribute04        as FreeDefinedAttribute04,

      @Consumption.hidden: true
      prps.FreeDefinedIndicator1         as FreeDefinedIndicator1,

      @Consumption.hidden: true
      prps.FreeDefinedIndicator2         as FreeDefinedIndicator2,
      @Consumption.hidden: true
      prps.ProjectType                   as ProjectType,


      //Associations

      @Consumption.hidden: true
      prps._ControllingArea              as _ControllingArea,

      @Consumption.hidden: true
      prps._ProfitCenter                 as _ProfitCenter,

      @Consumption.hidden: true
      prps._ResponsibleCostCenter        as _ResponsibleCostCenter,

      @Consumption.hidden: true
      _ResponsiblePerson,
      @Consumption.hidden: true
      _ProjectApplicant,
      @Consumption.hidden: true
      _Project
}
where
      cdhdr.ChangeDocObjectClass = 'PROJ'
  and cdpos.ChangeDocObjectClass = 'PROJ'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_WBSELEMENTDATA_2",
"P_PROJECTFIELDMAPPINGFORCHGDOC"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_PROFITCENTER",
"I_PROJECTAPPLICANT",
"I_PROJECTDATA_2",
"I_PROJECTRESPONSIBLEPERSON"
],
"BASE":
[
"I_WBSELEMENTDATA_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/