I_SrvcDocChgDocWithoutStatus

@AbapCatalog.sqlViewName: 'ISRVDOCCCD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Change Documents Without Status'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM: {
  viewType: #COMPOSITE
}
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_SrvcDocChgDocWithoutStatus
  as select from I_ChangeDocument
{
  key ChangeDocObject,
  key ChangeDocument                                                   as ChangeDocument,
  key _ChangeDocumentItem.DatabaseTable                                as DatabaseTable,
  key cast( coalesce( _ChangeDocumentItem._ChangeDocLongTableKey.ChangeDocLongTableKey,
                        _ChangeDocumentItem.ChangeDocTableKey )
                         as cdtabkey )                                 as ChangeDocTableKey,
  key _ChangeDocumentItem.ChangeDocDatabaseTableField                  as ChangeDocDatabaseTableField,
  key cast( _ChangeDocumentItem.ChangeDocItemChangeType as cdchngind ) as ChangeDocChangeType,
  key cast(' ' as crm_j_status)                                        as SrvcMgmtObjectStatus,
      ChangeDocObjectClass,

      case
         when  _ChangeDocumentItem._ChangeDocumentItemExtension.ChangeDocShortStringNew is not initial
         then  _ChangeDocumentItem._ChangeDocumentItemExtension.ChangeDocShortStringNew
         when  _ChangeDocumentItem.ChangeDocNewFieldValue is not initial or
               _ChangeDocumentItem.ChangeDocNewCurrency   is not initial or
               _ChangeDocumentItem.ChangeDocNewUnit       is not initial
         then  cast( concat_with_space(_ChangeDocumentItem.ChangeDocNewFieldValue,
                     concat(_ChangeDocumentItem.ChangeDocNewCurrency,
                     _ChangeDocumentItem.ChangeDocNewUnit ), 1 )   as cdfldvaln )
         else
               ' '
         end                                                           as ChangeDocNewFieldValue,

      case
         when _ChangeDocumentItem._ChangeDocumentItemExtension.ChangeDocShortStringOld is not initial
         then cast(_ChangeDocumentItem._ChangeDocumentItemExtension.ChangeDocShortStringOld as cdfldvalo)
         when _ChangeDocumentItem.ChangeDocPreviousFieldValue is not initial or
              _ChangeDocumentItem.ChangeDocPreviousCurrency   is not initial or
              _ChangeDocumentItem.ChangeDocPreviousUnit       is not initial
         then cast( concat_with_space(_ChangeDocumentItem.ChangeDocPreviousFieldValue,
                    concat(_ChangeDocumentItem.ChangeDocPreviousCurrency,
                    _ChangeDocumentItem.ChangeDocPreviousUnit ), 1 )               as cdfldvalo )
         else
              ' '
         end                                                           as ChangeDocPreviousFieldValue,
      cast(dats_tims_to_tstmp ( CreationDate,
                                  CreationTime,
                                  abap_system_timezone( $session.client,  'NULL' ),
                                  $session.client,
                                  'NULL' ) as cdcreated )              as ServiceDocChangedDateTime,

      cast('' as cdobjecttxt)                                          as ChangeDocObjectDescription,

      CreatedByUser,

      _ChangeDocumentItem

}
where
  ChangeDocObjectClass = 'CRM_ORDER'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCLONGTABLEKEY",
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_CHANGEDOCUMENTITEMEXTENSION"
],
"ASSOCIATED":
[
"I_CHANGEDOCUMENTITEM"
],
"BASE":
[
"I_CHANGEDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/