P_CreditLimitTrend

DDL: P_CREDITLIMITTREND Type: view COMPOSITE

P_CreditLimitTrend is a Composite CDS View in SAP S/4HANA. It reads from 2 data sources (I_ChangeDocument, I_ChangeDocumentItem) and exposes 11 fields with key fields ChangeDocObject, ChangeDocObjectClass, ChangeDocument, ChangeDocTableKey. It has 1 association to related views.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
I_ChangeDocument I_ChangeDocument from
I_ChangeDocumentItem I_ChangeDocumentItem inner

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_CreditManagementSegment _CreditManagementSegment $projection.CreditSegment = _CreditManagementSegment.CreditSegment

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName PCRLIMTR view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #COMPOSITE view
VDM.private true view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY ChangeDocObject I_ChangeDocumentItem ChangeDocObject
KEY ChangeDocObjectClass I_ChangeDocumentItem ChangeDocObjectClass
KEY ChangeDocument I_ChangeDocumentItem ChangeDocument
KEY ChangeDocTableKey I_ChangeDocumentItem ChangeDocTableKey
CreationDate I_ChangeDocument CreationDate
CreationTime I_ChangeDocument CreationTime
ChangeDocNewCurrency I_ChangeDocumentItem ChangeDocNewCurrency
ChangeDocNewFieldValue I_ChangeDocumentItem ChangeDocNewFieldValue
BusinessPartner
CreditSegment
_CreditManagementSegment _CreditManagementSegment 
@AbapCatalog: { sqlViewName: 'PCRLIMTR',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #NOT_REQUIRED }
@VDM: { viewType:  #COMPOSITE,
        private:   true }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #A,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL } }
define root view P_CreditLimitTrend
  as select from I_ChangeDocument
    inner join   I_ChangeDocumentItem on  I_ChangeDocument.ChangeDocObjectClass = I_ChangeDocumentItem.ChangeDocObjectClass
                                      and I_ChangeDocument.ChangeDocObject      = I_ChangeDocumentItem.ChangeDocObject
                                      and I_ChangeDocument.ChangeDocument       = I_ChangeDocumentItem.ChangeDocument

  //VDM Associations

  //Credit Segment

  association [0..1] to I_CreditManagementSegment as _CreditManagementSegment on $projection.CreditSegment = _CreditManagementSegment.CreditSegment

{
      //VDM Fields

  key I_ChangeDocumentItem.ChangeDocObject,
  key I_ChangeDocumentItem.ChangeDocObjectClass,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocTableKey,
      I_ChangeDocument.CreationDate,
      I_ChangeDocument.CreationTime,
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      I_ChangeDocumentItem.ChangeDocNewFieldValue,

      cast( dats_tims_to_tstmp( CreationDate,
                                CreationTime,
                                abap_system_timezone( $session.client,'NULL' ),
                                $session.client,
                               'NULL' ) as ukm_create_time )                                                   as CreationDateTime,

      cast( substring( I_ChangeDocumentItem.ChangeDocTableKey, 4, 10 )  as bu_partner preserving type )        as BusinessPartner,
      cast( substring( I_ChangeDocumentItem.ChangeDocTableKey, 14, 10 )  as ukm_credit_sgmnt preserving type ) as CreditSegment,

      //Exposed Associations

      _CreditManagementSegment
}

where
      I_ChangeDocument.ChangeDocObjectClass            = 'BUPA_UKM'
  and I_ChangeDocumentItem.DatabaseTable               = 'UKMBP_CMS_SGM'
  and I_ChangeDocumentItem.ChangeDocDatabaseTableField = 'CREDIT_LIMIT'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM"
],
"ASSOCIATED":
[
"I_CREDITMANAGEMENTSEGMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More