I_EnterpriseProjectElementTP

@AbapCatalog: {

    sqlViewName: 'IENRPRPROELEMTP',
    compiler.compareFilter: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
    semanticKey:       [ 'ProjectElement' ],
    representativeKey: 'ProjectElementUUID',
    alternativeKey: [ { id : 'WBSElementInternalID',       element: ['WBSElementInternalID'],         uniqueness: #UNIQUE } ],
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #L
    }
}

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}
@AbapCatalog.preserveKey: true
@EndUserText.label: 'TP view for CRUD API for EPPM Workpackages and milestones'


define view I_EnterpriseProjectElementTP
  as select from I_PPM_ProjectTask     as Workpackage
//    inner join   I_EnterpriseProjectTP as Project on Workpackage.ProjectUUID = Project.ProjectUUID // reduce complexity

      inner join   I_PPM_ProjectSummaryTask as Project on Workpackage.ProjectUUID = Project.ProjectUUID
 // to make sure parent is empty in case of parent being PST                                                         

    left outer to one join I_PPM_StdTaskHierarchyData as HierarchyData 
                    on   Workpackage.TaskUUID = HierarchyData.ReferencedObjectUUID
                     and Project.ProjectSummaryTaskUUID <> HierarchyData.ParentObjectUUID

  //  association [1..1] to I_EnterpriseProjectTP as  _EnterpriseProject  on $projection.ProjectUUID = _EnterpriseProject.ProjectUUID


  association        to parent I_EnterpriseProjectTP as _EnterpriseProject       on  $projection.ProjectUUID = _EnterpriseProject.ProjectUUID

  association [0..1] to I_EnterpriseProjectElementTP as _ParentProjElement       on  $projection.ParentObjectUUID = _ParentProjElement.ProjectElementUUID

  association [1..*] to I_EnterpriseProjectElementTP as _SubProjElement          on  $projection.ProjectElementUUID = _SubProjElement.ParentObjectUUID
  // associations to authorization views

  association [0..*] to I_PPM_AuthznByUsrH           as _AuthUser                on  _AuthUser.ReferencedObjectUUID = $projection.ProjectElementUUID
                                                                                 and _AuthUser.UserID               = $session.user
                                                                                 and (
                                                                                    _AuthUser.Activity              = 'Admin'
                                                                                    or _AuthUser.Activity           = 'Write'
                                                                                    or _AuthUser.Activity           = 'Read'
                                                                                  )
  association [0..*] to I_PPM_AuthznBySubstitH       as _AuthSubst               on  _AuthSubst.ReferencedObjectUUID = $projection.ProjectElementUUID
                                                                                 and _AuthSubst.UserID               = $session.user
                                                                                 and (
                                                                                    _AuthSubst.Activity              = 'Admin'
                                                                                    or _AuthSubst.Activity           = 'Write'
                                                                                    or _AuthSubst.Activity           = 'Read'
                                                                                  )
  association [0..*] to I_PPM_AuthznByUserRoleH      as _AuthRole                on  _AuthRole.ReferencedObjectUUID = $projection.ProjectElementUUID
                                                                                 and _AuthRole.UserID               = $session.user
                                                                                 and (
                                                                                    _AuthRole.Activity              = 'Admin'
                                                                                    or _AuthRole.Activity           = 'Write'
                                                                                    or _AuthRole.Activity           = 'Read'
                                                                                  )
  association [0..*] to I_PPM_AuthznByUsrGrpH        as _AuthGroup               on  _AuthGroup.ReferencedObjectUUID = $projection.ProjectElementUUID
                                                                                 and _AuthGroup.UserID               = $session.user
                                                                                 and (
                                                                                    _AuthGroup.Activity              = 'Admin'
                                                                                    or _AuthGroup.Activity           = 'Write'
                                                                                    or _AuthGroup.Activity           = 'Read'
                                                                                  )
  ---Extension Association
  association [1..1] to E_PPM_Task                   as _ProjectElementExtension on  $projection.ProjectElementUUID = _ProjectElementExtension.TaskUUID
  composition [0..1] of I_EntProjectElementJVATP     as _EntProjectElementJVA

  //Add PSM fields on 27.06

  composition [0..1] of I_EntProjElmntPublicSectorTP as _EntProjectElmntPublicSector
  //Add PSM fields on 27.06


  composition [0..1] of R_EntProjElmntBlockFuncTP    as _EntProjElmntBlkFunc

{
  key Workpackage.TaskUUID                          as ProjectElementUUID,
      Workpackage.Task                              as ProjectElement,
      Workpackage.WBSElementInternalID              as WBSElementInternalID,

      Workpackage.ProjectUUID           as ProjectUUID,

      cast(TaskName    as text40 )      as ProjectElementDescription,

      HierarchyData.ParentObjectUUID    as ParentObjectUUID,

      // task type needed ?

      Workpackage.ProcessingStatus      as ProcessingStatus,

      Workpackage.SortingNumber                     as SortingNumber,
      Workpackage.IsProjectMilestone                as IsProjectMilestone,
      Workpackage.MilestoneApprovalStatus           as MilestoneApprovalStatus,
      Workpackage.IsMainMilestone                   as IsMainMilestone,

      //      PlannedStartDate             as TaskStartDate,

      //      PlannedEndDate               as TaskEndDate,

      Workpackage.PlannedStartDate                  as PlannedStartDate,
      Workpackage.PlannedEndDate                    as PlannedEndDate,

      Workpackage.ForecastedStartDate               as ForecastedStartDate,
      Workpackage.ForecastedEndDate                 as ForecastedEndDate,
      Workpackage.ActualStartDate                   as ActualStartDate,
      Workpackage.ActualEndDate                     as ActualEndDate,

      Workpackage.ResponsibleCostCenter as ResponsibleCostCenter,
      Workpackage.CompanyCode           as CompanyCode,
      Workpackage.ProfitCenter          as ProfitCenter,
      Workpackage.FunctionalArea        as FunctionalArea,
      Workpackage.ControllingArea       as ControllingArea,
      Workpackage.Plant                 as Plant,
      Workpackage.Location              as Location,
      //Tax Jurisdiction, Functional Location fields

      Workpackage.TaxJurisdiction       as TaxJurisdiction,
      Workpackage.FunctionalLocation    as FunctionalLocation,

      Workpackage.FactoryCalendar                   as FactoryCalendar,
      Workpackage.CostingSheet                      as CostingSheet,
      Workpackage.InvestmentProfile     as InvestmentProfile,
      Workpackage.WBSIsStatisticalWBSElement        as WBSIsStatisticalWBSElement,
      Workpackage.CostCenter                        as CostCenter,
      // S4H 2005 Billing element indicator

      Workpackage.WBSElementIsBillingElement        as WBSElementIsBillingElement,
      //admin data

      Workpackage.CreatedByUser         as CreatedByUser,
      Workpackage.CreationDateTime      as CreationDateTime,
      Workpackage.LastChangedByUser     as LastChangedByUser,
      Workpackage.LastChangeDateTime    as LastChangeDateTime,
      
      // needed for etag

      Project.LastChangeDateTime        as ProjectLastChangedDateTime,

      Workpackage._CompanyCode,
      Workpackage._ControllingArea,
      Workpackage._FunctionalArea,
      Workpackage._ProfitCenter,
      Workpackage._Plant,
      Workpackage._ResponsibleCostCenter,
      Workpackage._FactoryCalendar,
      Workpackage._CostCenter,

      //needed or not ?

      //      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]

      _EnterpriseProject,

      //needed or not ?

      //             @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]

      _ParentProjElement,

      //needed or not ?

      //            @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]

      _SubProjElement,

      //needed or not ?

      //            @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD

      _EntProjectElementJVA,
      //     @feature: 'BF:PSM_BUDGET_ACCOUNTING_CONTROL, EPPM_PUBLIC_SECTOR'

      _EntProjectElmntPublicSector,

      _AuthUser,
      _AuthSubst,
      _AuthRole,
      _AuthGroup,
      _EntProjElmntBlkFunc

}

where
  Workpackage.ObjectType <> 'DPO';