I_EntProjectElementJVATP

@AbapCatalog.sqlViewName: 'IENTPRJELEMJVATP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel:
  {
    representativeKey: 'ProjectElementUUID',
    alternativeKey: [ { id : 'WBSElementInternalID',       element: ['WBSElementInternalID'],         uniqueness: #UNIQUE } ],
    usageType:
    {
      serviceQuality: #D,
      sizeCategory: #L,
      dataClass: #TRANSACTIONAL
    }
  }
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API 
@EndUserText.label: 'Extension fields for JVA on Task level'
define view I_EntProjectElementJVATP as select from I_PPM_ProjectTaskJVA as ProjectElementJVA
    //inner join I_EnterpriseProjectElementTP as ProjectElement on ProjectElementJVA.TaskUUID = ProjectElement.ProjectElementUUID

    association [1..1] to I_EnterpriseProjectElementTP as _ProjectElement
        on _ProjectElement.ProjectElementUUID = $projection.ProjectElementUUID
        
    association to parent I_EnterpriseProjectElementTP as  _EnterpriseProjectElement  on $projection.ProjectElementUUID = _EnterpriseProjectElement.ProjectElementUUID  
    association [1..1] to I_EnterpriseProjectTP as _EnterpriseProject on ProjectElementJVA.ProjectUUID = _EnterpriseProject.ProjectUUID
    
  // associations to authorization views

    association [0..*] to I_PPM_AuthznByUsrH as _AuthUser 
             on  _AuthUser.ReferencedObjectUUID = $projection.ProjectElementUUID
             and _AuthUser.UserID               = $session.user
             and (    _AuthUser.Activity        = 'Admin'
                  or _AuthUser.Activity         = 'Write'
                  or _AuthUser.Activity         = 'Read' )
    association [0..*] to I_PPM_AuthznBySubstitH as _AuthSubst 
             on  _AuthSubst.ReferencedObjectUUID = $projection.ProjectElementUUID
             and _AuthSubst.UserID               = $session.user
             and (   _AuthSubst.Activity         = 'Admin'
                  or _AuthSubst.Activity         = 'Write'
                  or _AuthSubst.Activity         = 'Read' )
    association [0..*] to I_PPM_AuthznByUserRoleH as _AuthRole 
             on  _AuthRole.ReferencedObjectUUID = $projection.ProjectElementUUID
             and _AuthRole.UserID               = $session.user
             and (   _AuthRole.Activity         = 'Admin'
                  or _AuthRole.Activity         = 'Write'
                  or _AuthRole.Activity         = 'Read' )
    association [0..*] to I_PPM_AuthznByUsrGrpH as _AuthGroup 
             on  _AuthGroup.ReferencedObjectUUID = $projection.ProjectElementUUID
             and _AuthGroup.UserID               = $session.user
             and (   _AuthGroup.Activity         = 'Admin'
                  or _AuthGroup.Activity         = 'Write'
                  or _AuthGroup.Activity         = 'Read' )
                           
{
//      @ObjectModel.readOnly: true  -> now set in BDEF

key TaskUUID    as ProjectElementUUID,
//      @ObjectModel.readOnly: true  -> now set in BDEF

    ProjectElementJVA.WBSElementInternalID,
//      @ObjectModel.readOnly: true  -> now set in BDEF

    ProjectElementJVA.ProjectUUID,
//      @ObjectModel.readOnly: true  -> now set in BDEF

    @Consumption.hidden: true // only for auth check

    ProjectElementJVA.ControllingArea,
//      @ObjectModel.readOnly: true  -> now set in BDEF

    @Consumption.hidden: true // only for auth check

    ProjectElementJVA.ProfitCenter,

    JointVenture, 
    JointVentureCostRecoveryCode, 
    JointVentureEquityType, 
    JntVntrProjectType, 
    JntIntrstBillgClass, 
    JntIntrstBillgSubClass,
    
    _EnterpriseProject.LastChangeDateTime as ProjectLastChangedDateTime,
        
    @Consumption.hidden: true
    _AuthUser,
    @Consumption.hidden: true
    _AuthSubst,
    @Consumption.hidden: true
    _AuthRole,
    @Consumption.hidden: true
    _AuthGroup,

    //_ProjectElement,    

    _EnterpriseProject,
    _EnterpriseProjectElement
}