I_PPM_ProjectSummaryTask

@EndUserText.label: 'Project, Projecttemplate or snapshot'

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

@AccessControl: {
    authorizationCheck: #CHECK,
    privilegedAssociations: [ 'I_PPM_ProjectType', 'I_PPM_ProTypeText' ],
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
  }

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog: {
    sqlViewName: 'IPPMPROSUMTASK',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
   semanticKey:       [ 'Project' ],
   representativeKey: 'ProjectUUID',
   alternativeKey: [ { id : 'ProjectSummaryTaskUUID', uniqueness: #UNIQUE, element: 'ProjectSummaryTaskUUID' },
                     { id : 'ProjectInternalID'     , uniqueness: #UNIQUE, element: 'ProjectInternalID' }       ],
   usageType: {
     serviceQuality:  #B,
     dataClass:       #MASTER,
     sizeCategory:    #L
   }
}

@UI.headerInfo: {
  typeName:       'Project',
  typeNamePlural: 'Projects'
}

define view I_PPM_ProjectSummaryTask
  as select from I_PPM_Task        as SummaryTask
    inner join   I_PPM_ProjectRoot as ProjectRoot on(
      ProjectRoot.ProjectUUID = SummaryTask.ProjectUUID
    )
  // associations to authorization views

  association [0..*] to I_PPM_AuthznByUsrH      as _AuthUser        on  _AuthUser.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                    and _AuthUser.UserID               = $session.user
                                                                    and (
                                                                       _AuthUser.Activity              = 'Admin'
                                                                       or _AuthUser.Activity           = 'Write'
                                                                       or _AuthUser.Activity           = 'Read'
                                                                     )
  association [0..*] to I_PPM_AuthznBySubstitH  as _AuthSubst       on  _AuthSubst.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                    and _AuthSubst.UserID               = $session.user
                                                                    and (
                                                                       _AuthSubst.Activity              = 'Admin'
                                                                       or _AuthSubst.Activity           = 'Write'
                                                                       or _AuthSubst.Activity           = 'Read'
                                                                     )
  association [0..*] to I_PPM_AuthznByUserRoleH as _AuthRole        on  _AuthRole.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                    and _AuthRole.UserID               = $session.user
                                                                    and (
                                                                       _AuthRole.Activity              = 'Admin'
                                                                       or _AuthRole.Activity           = 'Write'
                                                                       or _AuthRole.Activity           = 'Read'
                                                                     )
  association [0..*] to I_PPM_AuthznByUsrGrpH   as _AuthGroup       on  _AuthGroup.ReferencedObjectUUID = $projection.ProjectSummaryTaskUUID
                                                                    and _AuthGroup.UserID               = $session.user
                                                                    and (
                                                                       _AuthGroup.Activity              = 'Admin'
                                                                       or _AuthGroup.Activity           = 'Write'
                                                                       or _AuthGroup.Activity           = 'Read'
                                                                     )

  // PS Root WBS Element

  association [0..1] to I_WBSElementBasicData   as _ProjObjRoot     on  (
          _ProjObjRoot.WBSElementInternalID = $projection.WBSElementInternalID
        )

  // other associations

  association [0..1] to I_PPM_ProjectType       as _ProjectType     on  (
          _ProjectType.ProjectType = $projection.ProjectType
        )
  association [0..*] to I_PPM_ProTypeText       as _ProjectTypeName on  (
      _ProjectTypeName.ProjectType = $projection.ProjectType
    )
  association [0..*] to I_PPM_Task              as _Task            on  (
                 _Task.ProjectUUID                                                        = $projection.ProjectUUID
               )
                                                                    and (
                                                                       (
                                                                         _Task.ObjectType = 'TPO'
                                                                       )
                                                                       or(
                                                                         _Task.ObjectType = 'TTO'
                                                                       )
                                                                     )
  association [0..*] to I_PPM_Task              as _Phase           on  (
                _Phase.ProjectUUID                                                       = $projection.ProjectUUID
              )
                                                                    and (
                                                                       _Phase.ObjectType = 'PPO'
                                                                     )
  association [0..1] to I_PPM_ItemInfo          as _Portfolio       on  (
            _Portfolio.ProjectUUID = $projection.ProjectUUID
          )

{
  key ProjectRoot.ProjectUUID,

/* CE2011 - Project is referred by Enterprise Project
      @Consumption.semanticObject: 'EnterpriseProject' */
      @ObjectModel.text.association: '_ProjectName'
      SummaryTask.TaskUUID             as ProjectSummaryTaskUUID,
      ProjectRoot.ProjectCategory,
       
      //    @Semantics.user.lastChangedBy: true  - This is on project level, not for this record only!


      ProjectRoot.ProjectLastChangedByUser,
      //    @Semantics.systemDateTime.lastChangedAt: true

      ProjectRoot.ProjectLastChangedDateTime,
      ProjectRoot.ProjectReasonCode,
      ProjectRoot.MasterLanguage,
      ProjectRoot.IsSummaryTaskEnabled,
      ProjectRoot.ProjectLocation,
      ProjectRoot.PlanVersion,
      ProjectRoot.OrganizationalUnitObjectType,
      ProjectRoot.OrganizationalUnit,
      ProjectRoot.ProjectEarliestOrLatest,
      ProjectRoot.EntProjectIsConfidential,
      ProjectRoot.EnterpriseProjectServiceOrg,

      ProjectRoot.ProjectTemplateUUID, // when the project was copied,this contains the UUID of the source project

      // PS Data

      ProjectRoot.ProjectInternalID,
    
      SummaryTask.WBSElementInternalID,

      @ObjectModel.text.association: '_ProjectTypeName'
      SummaryTask.TaskType             as ProjectType,
// CE2011 - Project is referred by EnterpriseProject   

      @Consumption.semanticObject: 'EnterpriseProject' 
      SummaryTask.ExternalId           as Project,
      SummaryTask.TaskName             as ProjectName,
      SummaryTask.ReleaseDateTime,

      SummaryTask.EarliestStartDateTime,
      SummaryTask.EarliestStartDate,
      SummaryTask.EarliestFinishDateTime,
      SummaryTask.EarliestFinishDate,

      SummaryTask.StartConstraintType,
      SummaryTask.StartConstraintDateTime,
      SummaryTask.StartConstraintDate,
      SummaryTask.FinishConstraintType as ProjectFinishConstraintType,
      SummaryTask.FinishConstraintDateTime,
      SummaryTask.FinishConstraintDate,

      SummaryTask.ActualStartDateTime,
      SummaryTask.ActualStartDate,
      SummaryTask.ActualFinishDateTime,
      SummaryTask.ActualFinishDate,

      SummaryTask.LatestStartDateTime,
      SummaryTask.LatestStartDate,
      SummaryTask.LatestFinishDateTime,
      SummaryTask.LatestFinishDate,

      SummaryTask.ForecastedStartDateTime,
      SummaryTask.ForecastedStartDate,
      SummaryTask.ForecastedFinishDateTime,
      SummaryTask.ForecastedFinishDate,
      SummaryTask.ForecastedFinishDate as ForecastedEndDate,

      SummaryTask.ProjectElementDuration,
      SummaryTask.DurationUnit,

      SummaryTask.ProjectVersionNumber,

      SummaryTask.TaskProcessingStatus as ProjectProcessingStatus,

      SummaryTask.PriorityCode,

      @Semantics.user.createdBy: true
      SummaryTask.CreatedByUser,
      //@Semantics.systemDateTime.createdAt: true

      SummaryTask.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      SummaryTask.LastChangedByUser,
      //@Semantics.systemDateTime.lastChangedAt: true

      SummaryTask.LastChangeDateTime,
       //2102 Ent Project Multiple SO item indicator

      SummaryTask.EntProjIsMultiSlsOrdItmsEnbld,
    // SummaryTask.TaskTemplateUUID as TaskTemplateUUID,


      @Consumption.hidden: true
      _AuthUser,
      @Consumption.hidden: true
      _AuthSubst,
      @Consumption.hidden: true
      _AuthRole,
      @Consumption.hidden: true
      _AuthGroup,

      // when using the association to _Task or _Phase via project root, we need to carry the ProjectRootUUID everywhere, for this reason, I did introduce

      // a new association to I_PPM_Task

      //    ProjectRoot.ProjectRootUUID,

      _Task,
      _Phase,



      SummaryTask._CreatedByUser,
      SummaryTask._LastChangedByUser,

      ProjectRoot._ProjectLastChangedByUser,

      SummaryTask._Text                as _ProjectName,

      _ProjectType,
      _ProjectTypeName,

      _Portfolio,

      ProjectRoot._I_Project,
      _ProjObjRoot,
      SummaryTask._Priority,
      _PriorityText

}
where
  SummaryTask.ObjectType = 'DPO'