R_ProcessOrderTP

@AbapCatalog.dataMaintenance: #RESTRICTED
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: [ '_PostingRule' ]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
@ObjectModel.representativeKey: 'ProcessOrder'
@ObjectModel.sapObjectNodeType.name: 'ProcessOrder'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Process Order Header - TP'

//    ************************  DO NOT USE  ************************

//    *           This RAP BO is for testing purpose only         *

//    **************************************************************


define root view entity R_ProcessOrderTP
  as select from I_ManufacturingOrder as Header

  // BO relations

  composition [1..*] of R_ProcessOrderItemTP           as _Item
  composition [0..*] of R_ProcessOrderOperationTP      as _Operation
  composition [0..*] of R_ProcessOrderComponentTP      as _Component

  association [0..*] to R_ProcessOrderPhaseTP          as _Phase                  on  $projection.ProcessOrder = _Phase.ProcessOrder
  association [0..*] to R_ProcOrderItemSerialNumberTP  as _SerialNumber           on  _SerialNumber.ProcessOrder = $projection.ProcessOrder

  association [0..*] to R_EventBasedOrderPostingRuleTP as _PostingRule            on  _PostingRule.OrderID   = $projection.ProcessOrder
                                                                                  and _PostingRule.OrderItem = '0000'
  association [0..1] to R_VariantConfigurationTP       as _VariantConfiguration   on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
                                                                                  and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey
  association [0..*] to R_ProcOrdOperationCapacityTP   as _OrderOperationCapacity on  _OrderOperationCapacity.CapacityRequirement = $projection.CapacityRequirement
  association [0..*] to R_ProcessOrderPhaseCapacityTP  as _OrderPhaseCapacity     on  _OrderPhaseCapacity.CapacityRequirement = $projection.CapacityRequirement

  // Extension

  association [1..1] to E_ProcessOrder                 as _Extension              on  $projection.ProcessOrder = _Extension.OrderID

{
  key cast(ManufacturingOrder as co_bord preserving type)            as ProcessOrder,
      cast(ManufacturingOrder as manufacturingorder preserving type) as ManufacturingOrder, // kept for compatibility reasons (Events)


      // Category and Type

      @Consumption.hidden: true
      ManufacturingOrderCategory,
      cast(ManufacturingOrderType as aufart preserving type)         as ProcessOrderType,

      // Text

      @Semantics.text: true
      ManufacturingOrderText                                         as ProcessOrderText,
      ManufacturingOrderHasLongText                                  as OrderHasLongText,
      LongTextLanguageCode                                           as LongTextLanguage,

      // Attributes

      ManufacturingOrderImportance                                   as OrderImportance,
      IsMarkedForDeletion,
      IsCompletelyDelivered,
      @Semantics.booleanIndicator
      MfgOrderHasMultipleItems                                       as OrderHasMultipleItems,
      @Semantics.booleanIndicator
      MfgOrderIsPartOfCollvOrder                                     as OrderIsPartOfCollectiveOrder,
      @Semantics.booleanIndicator
      OrderIsNotCostedAutomatically,
      @Semantics.booleanIndicator
      OrdIsNotSchedldAutomatically,


      // Admin data

      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      LastChangeTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      // ETag

      @Semantics.systemDateTime.lastChangedAt: true
      case when LastChangeDate > '00000000' then
             cast( dats_tims_to_tstmp( LastChangeDate, LastChangeTime, '', $session.client, 'NULL' ) as timestampl )
           when LastChangeDate = '00000000' then
             cast( 0 as timestampl )
           end                                                       as LastChangeDateTime,

      // Header Material data

      Product,
      StorageLocation,
      Batch,
      @Semantics.text: true
      GoodsRecipientName,
      @Semantics.text: true
      UnloadingPointName,
      InventoryUsabilityCode,
      MaterialGoodsReceiptDuration,
      QuantityDistributionKey,

      // Assignments

      MfgOrderInternalID                                             as OrderInternalID,
      ReferenceOrder,
      ProductionPlant,
      PlanningPlant,
      cast(MRPArea as berid preserving type )                        as MRPArea,
      MRPController,
      ProductionSupervisor,
      ProductionSchedulingProfile,
      ResponsiblePlannerGroup,
      ProductionVersion,
      SalesOrder,
      SalesOrderItem,
      cast( WBSElementInternalID as  ps_s4_pspnr preserving type )   as WBSElementInternalID,
      Reservation,
      SettlementReservation,
      PlannedOrder,
      CapacityRequirement,
      BasicSchedulingType,
      ForecastSchedulingType,
      SchedulingIsAllowingForBreaks,
      ObjectInternalID,
      CapacityRqmtHasNotToBeCreated,

      // Variant Configuration

      case when ProductConfiguration is not initial
        then
          cast ('ProcessOrder' as sbo_node_type)
        else
          null
      end                                                            as VarConfigurationBusObjectType,
      case when ProductConfiguration is not initial
        then
          cast ( ManufacturingOrder as ibobjkey )
        else
          null
      end                                                            as VarConfigurationBusObjectKey,

      // Assignments BOO

      BillOfOperationsMaterial                                       as MasterRecipeProduct,
      BillOfOperationsType,
      BillOfOperationsGroup                                          as MasterRecipeGroup,
      BillOfOperationsVariant                                        as MasterRecipe,
      BOOInternalVersionCounter                                      as MasterRecipeInternalVersion,
      BillOfOperationsUsage                                          as MasterRecipeUsage,
      //      BillOfOperationsVersion,  // only supported in shopfloor routings - PEO

      BOOExplosionDate                                               as MasterRecipeExplosionDate,
      BOOValidityStartDate                                           as MasterRecipeValidityStartDate,

      // Assignments BOM

      BillOfMaterialCategory,
      BillOfMaterialInternalID,
      BillOfMaterialVariant,
      BillOfMaterialVariantUsage,
      BillOfMaterialVersion,
      BOMExplosionDate,
      BOMValidityStartDate,

      // Assignments FI/CO

      BusinessArea,
      cast(CompanyCode as bukrs preserving type )                    as CompanyCode,
      ControllingArea,
      ProfitCenter,
      CostCenter,
      cast(ResponsibleCostCenter as pph_kostl preserving type )      as ResponsibleCostCenter,
      CostElement,
      CostingSheet,
      GLAccount,
      ProductCostCollector,
      ActualCostsCostingVariant,
      PlannedCostsCostingVariant,
      ControllingObjectClass,
      FunctionalArea,
      OverheadCode,
      ResultAnalysisInternalID,
      VarianceKey,
      EventBasedProcessingKey,
      EventBasedPostingMethod,
      OrderSettlementTriggerType,

      // Scheduling

      SchedulingFloatProfile,
      FloatBeforeProductionInWrkDays,
      FloatAfterProductionInWorkDays,
      ReleasePeriodInWorkDays,

      // Dates and Times

      MfgOrderPlannedStartDate                                       as OrderPlannedStartDate,
      MfgOrderPlannedStartTime                                       as OrderPlannedStartTime,
      MfgOrderPlannedEndDate                                         as OrderPlannedEndDate,
      MfgOrderPlannedEndTime                                         as OrderPlannedEndTime,
      MfgOrderPlannedReleaseDate                                     as OrderPlannedReleaseDate,
      MfgOrderScheduledStartDate                                     as OrderScheduledStartDate,
      MfgOrderScheduledStartTime                                     as OrderScheduledStartTime,
      MfgOrderScheduledEndDate                                       as OrderScheduledEndDate,
      MfgOrderScheduledEndTime                                       as OrderScheduledEndTime,
      MfgOrderScheduledReleaseDate                                   as OrderScheduledReleaseDate,
      MfgOrderActualStartDate                                        as OrderActualStartDate,
      MfgOrderActualStartTime                                        as OrderActualStartTime,
      MfgOrderItemActualDeliveryDate                                 as OrderActualEndDate,
      MfgOrderActualReleaseDate                                      as OrderActualReleaseDate,
      MfgOrderConfirmedEndDate                                       as OrderConfirmedEndDate,
      MfgOrderConfirmedEndTime                                       as OrderConfirmedEndTime,
      MfgOrderTotalCommitmentDate                                    as TotalCommitmentDate,
      MfgOrderActualCompletionDate                                   as TechnicalCompletionDate,

      // Quantities and UoM

      ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedTotalQty                                        as OrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedScrapQty                                        as OrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedYieldQty                                      as OrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedScrapQty                                      as OrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      ExpectedDeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      ActualDeliveredQuantity,

      // Associations

      _Item,
      _SerialNumber,
      _Operation,
      _Phase,
      _Component,
      _PostingRule,
      _VariantConfiguration,
      _OrderOperationCapacity,
      _OrderPhaseCapacity
}
where
  ManufacturingOrderCategory = '40'