R_ProcessOrderPhaseCapacityTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Individual Capacity of Process Order Phase - TP'

define view entity R_ProcessOrderPhaseCapacityTP
  as select from I_ProcOrderOperationCapacity as IndividualCapacity

  // BO relation

  association        to parent R_ProcessOrderPhaseTP as _Phase     on  $projection.OrderInternalID      = _Phase.OrderInternalID
                                                                   and $projection.OrderPhaseInternalID = _Phase.OrderPhaseInternalID

  association [1..1] to R_ProcessOrderOperationTP    as _Operation on  _Operation.OrderInternalID          = $projection.OrderInternalID
                                                                   and _Operation.OrderOperationInternalID = $projection.SuperiorOperationIntIDOfPhase

  association [1..1] to R_ProcessOrderTP             as _Order     on  $projection.ProcessOrder = _Order.ProcessOrder

{
      // Key

  key CapacityRequirement,
  key CapacityRequirementItem,
      -- representative key
  key CapacityRqmtItemCapacity,

      // Order Data

      ProcessOrder,
      OrderInternalID,
      OrderOperationInternalID as OrderPhaseInternalID,
      @Consumption.hidden: true
      ManufacturingOrderCategory,
      ProcessOrderType,
      Plant,
      ProcessOrderOperation    as ProcessOrderPhase,
      SuperiorOperationIntIDOfPhase,
      WorkCenterInternalID,
      WorkCenterTypeCode,

      // Assignments

      CapacityRqmtConfirmation,
      CapacityInternalID,
      CapacityRequirementDistrKey,
      SuperiorOperationInternalID,

      // Only processing duration in process order phase / No Capacity split

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      CapacityRequirementUnit,
      ScheduledCapReqOpSegProcgDurn,
      RemainingCapReqOpSegProcgDurn,

      // Dates and Times

      OperationEarliestStartDate,
      OperationEarliestStartTime,
      OperationEarliestEndDate,
      OperationEarliestEndTime,
      OperationLatestStartDate,
      OperationLatestStartTime,
      OperationLatestEndDate,
      OperationLatestEndTime,
      ActualStartDate,
      ActualStartTime,
      ActualEndDate,
      ActualEndTime,

      // Time Events

      ErlstSchedldProcStrtDte,
      ErlstSchedldProcStrtTime,
      ErlstSchedldTrdwnStrtDte,
      ErlstSchedldTrdwnStrtTime,
      LtstSchedldProcStrtDte,
      LtstSchedldProcStrtTime,
      LtstSchedldTrdwnStrtDte,
      LtstSchedldTrdwnStrtTime,

      // Order Data

      _OrderInternalID,
      _ProcessOrderType,
      _ProcessOrderOperation,
      _Plant,
      _WorkCenter,

      // Associations

      _CapacityRequirement,
      _CapacityRequirementItem,
      _CapacityRequirementConf,
      _Capacity,
      _UnitOfMeasure,

      // BO relation

      _Order,
      _Operation,
      _Phase

}
where
  OperationIsPhase is not initial