R_ProcessOrderItemTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: [ '_PostingRule' ]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Process Order Item - TP'

define view entity R_ProcessOrderItemTP
  as select from I_ManufacturingOrderItem as Item

  // BO relation

  association        to parent R_ProcessOrderTP        as _Order                    on  $projection.ProcessOrder = _Order.ProcessOrder
  //  association [0..1] to I_ManufacturingOrderComponent  as _CoProductReservationItem   on  $projection.CoProductReservation     = _CoProductReservationItem.Reservation

  //                                                                                      and $projection.CoProductReservationItem = _CoProductReservationItem.ReservationItem

  //                                                                                      and _CoProductReservationItem.ReservationRecordType = ''

  association [0..1] to I_OrderComponent               as _CoProductReservationItem on  $projection.CoProductReservation     = _CoProductReservationItem.Reservation
                                                                                    and $projection.CoProductReservationItem = _CoProductReservationItem.ReservationItem
                                                                                    and _CoProductReservationItem.RecordType = ''
  composition [0..*] of R_ProcOrderItemSerialNumberTP  as _SerialNumber

  association [0..*] to R_EventBasedOrderPostingRuleTP as _PostingRule              on  _PostingRule.OrderID   = $projection.ProcessOrder
                                                                                    and _PostingRule.OrderItem = $projection.ProcessOrderItem
  association [0..1] to R_VariantConfigurationTP       as _VariantConfiguration     on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
                                                                                    and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey

{

      // Key

  key cast(ManufacturingOrder as vdm_manufacturingorder preserving type)             as ProcessOrder,
  key ManufacturingOrderItem                                                         as ProcessOrderItem,

      // Category and Type

      cast(ManufacturingOrderCategory as manufacturingordercategory preserving type) as ManufacturingOrderCategory,
      cast(ManufacturingOrderType as manufacturingordertype preserving type)         as ProcessOrderType,

      // Attributes

      OrderIsReleased,
      IsMarkedForDeletion,
      OrderItemIsNotRelevantForMRP,

      // Assignments

      Product,
      ProductionPlant,
      PlanningPlant,
      //      head.Reservation,

      ProductionVersion,
      cast(MRPArea as berid preserving type )                                        as MRPArea,
      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,
      WBSElementInternalID_2                                                         as WBSElementInternalID,
      QuotaArrangement,
      QuotaArrangementItem,
      SettlementReservation,
      SettlementReservationItem,
      CoProductReservation,
      CoProductReservationItem,
      MaterialProcurementCategory,
      MaterialProcurementType,
      SerialNumberAssgmtProfile                                                      as SerialNumberProfile,
      NumberOfSerialNumbers,
      MfgOrderItemReplnmtElmntType                                                   as ReplenishmentElementType,
      ProductConfiguration,
      ObjectInternalID,
      //      head.ObjectInternalID                                                    as ManufacturingObject,

      QuantityDistributionKey,
      EffectivityParameterVariant,

      // Variant Configuration

      case when ProductConfiguration is not initial
        then
          cast ('ProcessOrderItem' as sbo_node_type)
        else
          null
      end                                                                            as VarConfigurationBusObjectType,
      case when ProductConfiguration is not initial
        then
          cast ( concat(ManufacturingOrder, ManufacturingOrderItem) as ibobjkey )
        else
          null
      end                                                                            as VarConfigurationBusObjectKey,

      // Goods Receipt data

      GoodsReceiptIsExpected,
      GoodsReceiptIsNonValuated,
      IsCompletelyDelivered,
      MaterialGoodsReceiptDuration,
      UnderdelivTolrtdLmtRatioInPct,
      OverdelivTolrtdLmtRatioInPct,
      UnlimitedOverdeliveryIsAllowed,
      StorageLocation,
      Batch,
      InventoryValuationType,
      InventoryValuationCategory,
      InventoryUsabilityCode,
      InventorySpecialStockType,
      InventorySpecialStockValnType,
      ConsumptionPosting,
      @Semantics.text: true
      GoodsRecipientName,
      @Semantics.text: true
      UnloadingPointName,
      StockSegment,

      // Order Item Dates

      MfgOrderItemPlannedEndDate                                                     as PlannedEndDate,
      MfgOrderItemScheduledEndDate                                                   as ScheduledEndDate,
      MfgOrderItemPlndDeliveryDate                                                   as PlannedDeliveryDate,
      MfgOrderItemActualDeliveryDate                                                 as ActualDeliveryDate,
      MfgOrderItemTotalCmtmtDate                                                     as TotalCommitmentDate,

      // Item Quantities and UoM

      ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderItemPlannedTotalQty                                                    as PlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderItemPlannedScrapQty                                                    as PlannedScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderItemPlannedYieldQty                                                    as PlannedYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderItemGoodsReceiptQty                                                    as GoodsReceiptQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderItemActualDeviationQty                                                 as ActualDeviationQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderItemOpenYieldQty                                                       as OpenYieldQuantity,

      // Planned Order data

      PlannedOrder,
      PlndOrderPlannedStartDate,
      PlannedOrderOpeningDate,
      BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      PlndOrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      PlndOrderPlannedScrapQty,

      // Assignments FI/CO

      //      head.CompanyCode,

      BusinessArea,
      AccountAssignmentCategory,

      // Amount and Currency

      CompanyCodeCurrency,            //head ???

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      GoodsReceiptAmountInCoCodeCrcy, //item ???


      // Co-product Reservation Item

      _CoProductReservationItem.BillOfMaterialItemNumber                             as BillOfMaterialItemNumber,
      _CoProductReservationItem.MaterialComponentText                                as MaterialComponentText,
      _CoProductReservationItem.MatlCompFreeDefinedAttribute                         as MatlCompFreeDefinedAttribute,
      _CoProductReservationItem.LeadTimeOffset                                       as LeadTimeOffset,
      _CoProductReservationItem.OperationLeadTimeOffsetUnit                          as OperationLeadTimeOffsetUnit,
      _CoProductReservationItem.OperationLeadTimeOffset                              as OperationLeadTimeOffset,
      //      _CoProductReservationItem.BillOfMaterialItemCategory                           as BillOfMaterialItemCategory,

      //      _CoProductReservationItem.ManufacturingOrderOperation                          as ProcessOrderOperation,

      _CoProductReservationItem.BOMItemCategory                                      as BillOfMaterialItemCategory,
      _CoProductReservationItem.OrderOperation                                       as ProcessOrderOperation,
      _CoProductReservationItem.Plant                                                as Plant,

      _Order,
      _CoProductReservationItem,
      _SerialNumber,
      _PostingRule,
      _VariantConfiguration
}
where
  Item.ManufacturingOrderCategory = '40'; //process order