R_CustomerReturnTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
  sapObjectNodeType:{
        name: 'CustomerReturn'
   },
  semanticKey: ['CustomerReturn'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  }
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser', '_OutputRequest']
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'SDH',
  quota: {
    maximumFields: 204, 
    maximumBytes: 6800  
  }
}

@EndUserText.label: 'Returns Order - TP'
@Metadata.ignorePropagatedAnnotations: true

define root view entity R_CustomerReturnTP
  as select from           I_CustomerReturnEnhanced as CustomerReturn
    left outer to one join I_OutputRequest          as OutputRequest on  OutputRequest.OutputControlApplicationObject = CustomerReturn.CustomerReturn
                                                                     and OutputRequest.OutputControlApplObjectType    = 'SALES_DOCUMENT'
  composition [0..*] of R_CustomerReturnItemTP        as _Item
  composition [0..*] of R_CustomerReturnPartnerTP     as _Partner
  composition [0..*] of R_CustomerReturnTextTP        as _Text
  composition [0..1] of R_CustomerReturnShipToPartyTP as _ShipToParty
  composition [0..*] of R_CustomerReturnPrgElmTP      as _PricingElement

  association [0..1] to R_OutputRequestTP             as _OutputRequest             on  $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  association [0..1] to I_CustomerReturnPartner       as _SoldToParty               on  $projection.CustomerReturn   = _SoldToParty.CustomerReturn
                                                                                    and _SoldToParty.PartnerFunction = 'AG'

  association [0..1] to I_SlsOrganizationDistrChnl    as _SlsOrganizationDistrChnl  on  $projection.SalesOrganization   = _SlsOrganizationDistrChnl.SalesOrganization
                                                                                    and $projection.DistributionChannel = _SlsOrganizationDistrChnl.DistributionChannel

  association [0..1] to I_CustReturnSubsqntProcgSts   as _ReldForSubsqntProcgStatus on  $projection.CustomerReturn = _ReldForSubsqntProcgStatus.CustomerReturn

  association [0..1] to C_CustomerReturnRefundSts     as _CustRetRfndStatus         on  $projection.CustomerReturn = _CustRetRfndStatus.CustomerReturn

  association [0..1] to I_CustomerReturnType          as _CustomerReturnType        on  $projection.CustomerReturnType = _CustomerReturnType.CustomerReturnType
  association [0..1] to I_RetsMgmtCompnProcgStatus    as _RetsMgmtCompnProcgStatus  on  $projection.RetsMgmtCompnProcgStatus = _RetsMgmtCompnProcgStatus.RetsMgmtCompnProcgStatus
  //Extension Association

  association [1]    to E_SalesDocumentBasic             as _Extension              on  $projection.CustomerReturn = _Extension.SalesDocument
{
  key CustomerReturn.CustomerReturn,
      @ObjectModel.foreignKey.association: '_CustomerReturnType'
      CustomerReturn.CustomerReturnType,
      CustomerReturn.CustomerReturnDate,

      @ObjectModel.text.element: ['CustomerName']
      CustomerReturn.SoldToParty,
      @Semantics.text:true
      _SoldToParty.FullName                                                                                as CustomerName,
   
      _SoldToParty.AddressID                                                                               as SoldToPartyAddressID,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      CustomerReturn.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      CustomerReturn.DistributionChannel,

      _SlsOrganizationDistrChnl.ReferenceDistributionChannel,

      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      CustomerReturn.OrganizationDivision,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      CustomerReturn.SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      CustomerReturn.SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesDistrict'
      CustomerReturn.SalesDistrict,

      //Admin

      @Consumption.hidden: true
      CustomerReturn.CreationDate,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      CustomerReturn.CreatedByUser,
      @ObjectModel.foreignKey.association: '_LastChangedByUser'
      CustomerReturn.LastChangedByUser,

      CustomerReturn.CreationTime,
      cast( dats_tims_to_tstmp( CustomerReturn.CreationDate, CustomerReturn.CreationTime, abap_system_timezone( $session.client, 'NULL' ),
        $session.client, 'NULL' ) as creation_date_time )                                                  as SalesDocumentCreationDateTime,

      @Consumption.hidden: true
      CustomerReturn.LastChangeDate,

      //@Consumption.hidden: true

      //CustomerReturn.SenderBusinessSystemName,


      case tstmp_is_valid( cast( CustomerReturn.LastChangeDateTime as abap.dec( 15, 0 ) ) )
        when 0 then cast( dats_tims_to_tstmp( CustomerReturn.CreationDate, CustomerReturn.CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else CustomerReturn.LastChangeDateTime
      end                                                                                                  as LastChangeDateTime,

      CustomerReturn.PurchaseOrderByCustomer,
      @ObjectModel.foreignKey.association: '_CustomerPurchaseOrderType'
      CustomerReturn.CustomerPurchaseOrderType,
      @ObjectModel.foreignKey.association: '_CustPurOrdTypeByShipToParty'
      CustomerReturn.CustPurOrdTypeByShipToParty,
      CustomerReturn.CustomerPurchaseOrderDate,
      CustomerReturn.PurchaseOrderByShipToParty,
      CustomerReturn.CorrespncExternalReference,
      CustomerReturn.CorrespncExtRefByShipToParty,
      CustomerReturn.CustomerGroup,
      CustomerReturn.AdditionalCustomerGroup1,
      CustomerReturn.AdditionalCustomerGroup2,
      CustomerReturn.AdditionalCustomerGroup3,
      CustomerReturn.AdditionalCustomerGroup4,
      CustomerReturn.AdditionalCustomerGroup5,
      CustomerReturn.BillingDocumentDate,
      CustomerReturn.BusinessSolutionOrder,
      CustomerReturn.ControllingArea,
      CustomerReturn.CustomerPriceGroup,
      CustomerReturn.OverallSDDocReferenceStatus,
      CustomerReturn.PriceListType,
      CustomerReturn.ServicesRenderedDate,
      CustomerReturn.TaxDepartureCountry,
      CustomerReturn.VATRegistrationCountry,
      CustomerReturn.FixedValueDate,
      
      @ObjectModel.foreignKey.association: '_SDDocumentReason'
      //      cast(CustomerReturn.SDDocumentReason as vdm_return_order_reason preserving type) as SDDocumentReason,

      cast(CustomerReturn.SDDocumentReason as vdm_return_order_reason preserving type)                     as SDDocumentReason,
      //      CustomerReturn.SDDocumentReason,

      CustomerReturn.PricingDate,
      CustomerReturn.RequestedDeliveryDate,
      

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturn.TotalNetAmount,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      CustomerReturn.TransactionCurrency,
      @ObjectModel.foreignKey.association: '_HeaderBillingBlockReason'
      CustomerReturn.HeaderBillingBlockReason,
      @ObjectModel.foreignKey.association: '_DeliveryBlockReason'
      CustomerReturn.DeliveryBlockReason,
      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      CustomerReturn.SDPricingProcedure,
      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      CustomerReturn.IncotermsClassification,
      CustomerReturn.IncotermsTransferLocation,
      CustomerReturn.IncotermsLocation1,
      CustomerReturn.IncotermsLocation2,
      @ObjectModel.foreignKey.association: '_IncotermsVersion'
      CustomerReturn.IncotermsVersion,
      @ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
      CustomerReturn.CustomerPaymentTerms,
      CustomerReturn.PaymentMethod,
      CustomerReturn.BillingCompanyCode,
      
      CustomerReturn.CustomerTaxClassification1,
      CustomerReturn.CustomerTaxClassification2,
      CustomerReturn.CustomerTaxClassification3,
      CustomerReturn.CustomerTaxClassification4,
      CustomerReturn.CustomerTaxClassification5,
      CustomerReturn.CustomerTaxClassification6,
      CustomerReturn.CustomerTaxClassification7,
      CustomerReturn.CustomerTaxClassification8,
      CustomerReturn.CustomerTaxClassification9,
      
      CustomerReturn.AccountingDocExternalReference,
      CustomerReturn.CustomerAccountAssignmentGroup,
      CustomerReturn.AssignmentReference,
      
      CustomerReturn.ShippingType,
      

      @ObjectModel.foreignKey.association: '_ShippingCondition'
      CustomerReturn.ShippingCondition,
      @ObjectModel.foreignKey.association: '_CustRetApprovalReason'
      CustomerReturn.CustomerReturnApprovalReason,
      @ObjectModel.foreignKey.association: '_SalesDocApprovalStatus'
      CustomerReturn.SalesDocApprovalStatus,
      CustomerReturn.ReferenceSDDocument,
      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      CustomerReturn.ReferenceSDDocumentCategory,

      cast(
        case when CustomerReturn.ReferenceSDDocumentCategory = 'C'
        then CustomerReturn.ReferenceSDDocument
        else ''
        end
      as msr_ref_sales_order preserving type )                                                             as SalesDocument,

      cast(
        case when CustomerReturn.ReferenceSDDocumentCategory = 'M'
        then CustomerReturn.ReferenceSDDocument
        else ''
        end
      as msr_ref_billing_document preserving type )                                                        as BillingDocument,

      cast(
        case when CustomerReturn.ReferenceSDDocumentCategory = 'I'
        then CustomerReturn.ReferenceSDDocument
        else ''
        end
      as msr_ref_order_without_charge preserving type )                                                    as SalesOrderWithoutCharge,

      @ObjectModel.foreignKey.association: '_RetsMgmtProcess'
      CustomerReturn.RetsMgmtProcess,

      @Semantics.booleanIndicator
      _CustomerReturnType.RetsMgmtIsActive                                                                 as RetsMgmtIsActive,

      //Logistical Status

      CustomerReturn.RetsMgmtLogProcgStatus                                                                as RetsMgmtLogProcgStatus,

      //Refunding Status

      @ObjectModel.foreignKey.association: '_RetsMgmtCompnProcgStatus'
      cast(case when CustomerReturn.RetsMgmtProcess is initial
           then ''
           else CustomerReturn.RetsMgmtCompnProcgStatus
           end
           as msr_fin_status preserving type)                                                              as RetsMgmtCompnProcgStatus,

      //Processing Status

      CustomerReturn.RetsMgmtProcessingStatus                                                              as RetsMgmtProcessingStatus,

      // Release Status

      cast ( 
           _ReldForSubsqntProcgStatus.OvrlReldForSubsqntProcgSts 
           as cust_ret_rel_status preserving type )                                                        as OvrlReldForSubsqntProcgSts,

      // Refund Progress

      cast(
       _CustRetRfndStatus.CustReturnRefundStatus
      as refund_progress preserving type )                                                                 as CustReturnRefundStatus,

      //Status

      @ObjectModel.foreignKey.association: '_OverallSDProcessStatus'
      CustomerReturn.OverallSDProcessStatus,
      @ObjectModel.foreignKey.association: '_TotalCreditCheckStatus'
      CustomerReturn.TotalCreditCheckStatus,
      @ObjectModel.foreignKey.association: '_OverallSDDocumentRejectionSts'
      CustomerReturn.OverallSDDocumentRejectionSts,
      @ObjectModel.foreignKey.association: '_OverallTotalDeliveryStatus'
      CustomerReturn.OverallTotalDeliveryStatus,
      @ObjectModel.foreignKey.association: '_HdrGeneralIncompletionStatus'
      cast(CustomerReturn.HdrGeneralIncompletionStatus as hdr_general_incompltn_status preserving type )   as HdrGeneralIncompletionStatus,
      @ObjectModel.foreignKey.association: '_OvrlItmGeneralIncompletionSts'
      cast(CustomerReturn.OvrlItmGeneralIncompletionSts as itms_ovrl_incompletion_status preserving type ) as OvrlItmGeneralIncompletionSts,

      OutputRequest.OutputRequestUUID,

      //Compositions

      _Item,
      _Partner,
      _Text,
      _ShipToParty,
      _PricingElement,

      //Re-use RAP associations

      _OutputRequest,

      //Associations

      CustomerReturn._CustomerReturnType,
      CustomerReturn._SoldToParty,
      CustomerReturn._SalesOrganization,
      CustomerReturn._DistributionChannel,
      CustomerReturn._OrganizationDivision,
      CustomerReturn._SalesGroup,
      CustomerReturn._SalesOffice,
      CustomerReturn._ShippingCondition,

      CustomerReturn._SDDocumentReason,
      CustomerReturn._TransactionCurrency,
      //      _CustRetApprovalReason

      CustomerReturn._CustRetApprovalReason,

      CustomerReturn._SalesDocApprovalStatus,
      //      _ReferenceSDDocumentCategory

      CustomerReturn._ReferenceSDDocumentCategory,
      CustomerReturn._RetsMgmtProcess,
      //      CustomerReturn._RetsMgmtLogProcgStatus,

      _RetsMgmtCompnProcgStatus,
      //      CustomerReturn._RetsMgmtProcessingStatus,

      CustomerReturn._OverallSDProcessStatus,
      CustomerReturn._OverallTotalDeliveryStatus,
      //      _TotalCreditCheckStatus

      CustomerReturn._TotalCreditCheckStatus,
      //      _OverallSDDocumentRejectionSts

      CustomerReturn._OverallSDDocumentRejectionSts,

      CustomerReturn._LastChangedByUser,
      CustomerReturn._CreatedByUser,

      CustomerReturn._SDPricingProcedure,
      CustomerReturn._CustomerPurchaseOrderType,
      CustomerReturn._CustPurOrdTypeByShipToParty,

      CustomerReturn._HdrGeneralIncompletionStatus,
      CustomerReturn._OvrlItmGeneralIncompletionSts,
      CustomerReturn._HeaderBillingBlockReason,
      CustomerReturn._IncotermsClassification,
      CustomerReturn._IncotermsVersion,
      CustomerReturn._CustomerPaymentTerms,
      CustomerReturn._DeliveryBlockReason,
      CustomerReturn._SalesDistrict
}