A_CustomerReturn_2

@AccessControl:{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@EndUserText.label: 'Returns Order Header'
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
   representativeKey: 'CustomerReturn',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

@OData: {
  entityType.name: 'CustomerReturn_Type'
}

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'SDH', 
  dataSources: ['CustomerReturn'],  
  quota: {
    maximumFields: 204,
    maximumBytes: 6800
  }  
} 

define root view entity A_CustomerReturn_2
  provider contract transactional_query
  as projection on R_CustomerReturnTP as CustomerReturn
{
  key CustomerReturn.CustomerReturn,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerReturnType'
      CustomerReturn.CustomerReturnType,

      CustomerReturn.SalesOrganization,
      CustomerReturn.OrganizationDivision,
      CustomerReturn.DistributionChannel,

      CustomerReturn.SalesDistrict,
      CustomerReturn.SalesGroup,
      CustomerReturn.SalesOffice,

      CustomerReturn.SoldToParty,

      CustomerReturn.CreatedByUser,
      CustomerReturn.CreationDate,
      CustomerReturn.LastChangeDateTime,

      CustomerReturn.PurchaseOrderByCustomer,
      CustomerReturn.CustomerPurchaseOrderDate,
      CustomerReturn.PurchaseOrderByShipToParty,
      CustomerReturn.CorrespncExternalReference,
      CustomerReturn.CorrespncExtRefByShipToParty,
      CustomerReturn.CustomerGroup,
      CustomerReturn.AdditionalCustomerGroup1,
      CustomerReturn.AdditionalCustomerGroup2,
      CustomerReturn.AdditionalCustomerGroup3,
      CustomerReturn.AdditionalCustomerGroup4,
      CustomerReturn.AdditionalCustomerGroup5,
      CustomerReturn.BillingDocumentDate,
      CustomerReturn.BillingCompanyCode,
      CustomerReturn.BusinessSolutionOrder,
      CustomerReturn.ControllingArea,
      CustomerReturn.CustomerPriceGroup,
      CustomerReturn.CreationTime,
      CustomerReturn.HdrGeneralIncompletionStatus,
      CustomerReturn.OvrlItmGeneralIncompletionSts,
      CustomerReturn.OverallSDDocReferenceStatus,
      CustomerReturn.PriceListType,
      CustomerReturn.SDPricingProcedure,
      CustomerReturn.ShippingCondition,
      CustomerReturn.ServicesRenderedDate,
      CustomerReturn.TaxDepartureCountry,
      CustomerReturn.VATRegistrationCountry,
      CustomerReturn.FixedValueDate,
      
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
      CustomerReturn.CustomerPurchaseOrderType,
      CustomerReturn.CustPurOrdTypeByShipToParty,

      CustomerReturn.CustomerReturnDate,


      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      @Semantics.currencyCode: true
      CustomerReturn.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturn.TotalNetAmount,

      CustomerReturn.ReferenceSDDocument,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'ReferenceSDDocument'
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
virtual ReferenceSDDocumentIsNull           : rap_null_value_indicator,
      
      CustomerReturn.ReferenceSDDocumentCategory,
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'ReferenceSDDocumentCategory'
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
virtual ReferenceSDDocumentCatIsNull           : rap_null_value_indicator,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      CustomerReturn.SDDocumentReason,

      CustomerReturn.PricingDate,

      CustomerReturn.RequestedDeliveryDate,
      CustomerReturn.ShippingType,

      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      CustomerReturn.HeaderBillingBlockReason,
      CustomerReturn.DeliveryBlockReason,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      CustomerReturn.IncotermsClassification,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      CustomerReturn.IncotermsVersion,
      CustomerReturn.IncotermsLocation1,
      CustomerReturn.IncotermsLocation2,

      CustomerReturn.CustomerPaymentTerms,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentMethod'
      CustomerReturn.PaymentMethod,

      CustomerReturn.AccountingDocExternalReference,
      CustomerReturn.CustomerAccountAssignmentGroup,
      CustomerReturn.AssignmentReference,

      @ObjectModel.sapObjectNodeTypeReference: 'CustomerReturnApprovalReason'
      CustomerReturn.CustomerReturnApprovalReason,
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
      CustomerReturn.OverallSDDocumentRejectionSts,
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
      CustomerReturn.OverallSDProcessStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocApprovalStatus'
      CustomerReturn.SalesDocApprovalStatus,
      CustomerReturn.RetsMgmtCompnProcgStatus,
      CustomerReturn.RetsMgmtLogProcgStatus,
      CustomerReturn.RetsMgmtProcessingStatus,
      CustomerReturn.RetsMgmtProcess,


      _Item                    as _Item           : redirected to composition child A_CustomerReturnItem_2,
      _Partner                 as _Partner        : redirected to composition child A_CustomerReturnPartner_2,
      @ObjectModel.filter.enabled: false
      _PricingElement          as _PricingElement : redirected to composition child A_CustRetPricingElement_2,
      _Text                    as _Text           : redirected to composition child A_CustomerReturnText_2
}